マウスでセルを２個以上範囲選択されたら、強制的にセルを選択範囲の左上に移動するには？

Question

おはようございます

マウス関連の選択範囲で使うVBAを調べました
左上は　Selection(1)
右下は　Selection(Selection.Count)
行数は　Rows.Count
列数は　Columns.Count
ここから先はVBAでどう書いたらいいでしょうか

対象の範囲はA1:C10
↓
マウスで複数セル範囲が選択された
↓
その範囲がA1:C10に複数含まれる
または
範囲がすべてA1からC10に含まれる
↓
ということは、早い話が、A1:C10内で複数セルが選択されている
Selection(Selection.Count)が２以上
↓
Selection(1)をSelect

と、ここまで考えました

GooUserラック · Accepted Answer

考え方を逆にしてみました。この方がスッキリします。
-----------------------------------------------------------------------------------------
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim 行 As Long
Dim 列 As Long
  For 行 = 1 To 10
    For 列 = 1 To 3
      If Not Intersect(Target, Cells(行, 列)) Is Nothing Then
        Application.EnableEvents = False
        Cells(行, 列).Select
        Application.EnableEvents = True
        Exit Sub
      End If
    Next
  Next
End Sub
-----------------------------------------------------------------------------------------

GooUserラック · Answer

余計なことかもしれませんが以下の２つを作っておくと、修正作業に一時的に動作を止めたり再開で来たりしますので便利ですよ。
-----------------------------------------------------------------------------------------
Sub イベント割込み再開()
Application.EnableEvents = True
End Sub
-----------------------------------------------------------------------------------------
Sub イベント割込み停止()
Application.EnableEvents = False
End Sub
-----------------------------------------------------------------------------------------
※ 修正作業を終えたら「イベント割込み再開」を行うのを忘れないように！（動作しなかったら「イベント割込み再開」マクロを実行するように言っておいても良いかもしれません）

GooUserラック · Answer

yoreyoreさんやtom04さんの物だと、例えば「B5」セルを選択している状態で[Ctrl]キーを押しながら「A3」セルを選択すると、「B5」セルの方が選択されてしまいますが良いのでしょうか？

ママチャリ · Answer

おはようございます。横から失礼します。こんな感じでどうでしょう。
確認ですが「左上」の定義は「一番左の列の一番上のセル」で合ってますか？それとも「一番上の行の一番左のセル」ですか？提示したマクロは前者として実装したつもりですが、もし後者なら100riさんの方で修正してみて下さい。
それから、左上をSelectしてしまうと選択が解除されてしまい、見た目が面白くないので、左上をActivateにしています（Activeセルが移るだけです）。

ちなみに、これって何に応用されるのでしょうか？利用シーンが想像できなかったので、できれば教えて下さい。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim sr As Range
    Dim r As Range
    Dim tr As Range
    Set sr = Intersect(Target, Range("A1:C10"))
    If sr Is Nothing Then Exit Sub
    If sr.Count <= 1 Then Exit Sub
    Set tr = sr(1)
    For Each r In sr.Areas
        If r(1).Address < tr.Address Then
            Set tr = r(1)
        End If
    Next r
    tr.Activate
End Sub

tom04 · Answer

こんにちは！

横からお邪魔します。
＞対象の範囲はA1:C10
というコトは・・・

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Intersect(Target, Range("A1:C10")) Is Nothing Then
        Target(1).Select
    End If
End Sub

こんな感じをお望みなのでしょうか？m(_ _)m

yoreyore · Answer

目的がはっきりしませんが、シートモジュールに次のようなコードを書くと、似たようなことになります。

例：Sheet1のモジュールに
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   Selection(1).Select
End Sub

GooUserラック · Answer

A1:C10の範囲では複数のセルを選択出来ないようにするだけでしたら以下のようなもので良いと思います。
-----------------------------------------------------------------------------------------
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  If Target.Row <= 10 Then
    If Target.Column <= 3 Then
      If Target.Count >= 2 Then
        Application.EnableEvents = False
        If Target.Areas.Count = 1 Then
          Target(1).Select
        Else
          If Target.Areas(1)(1).Row = Target.Areas(2)(1).Row Then
            If Target.Areas(1).Column < Target.Areas(2)(1).Column Then
              Target.Areas(1)(1).Select
            Else
              Target.Areas(2)(1).Select
            End If
          Else
            If Target.Areas(1)(1).Row < Target.Areas(2)(1).Row Then
              Target.Areas(1)(1).Select
            Else
              Target.Areas(2)(1).Select
            End If
          End If
        End If
        Application.EnableEvents = True
      End If
    End If
  End If
End Sub
-----------------------------------------------------------------------------------------
※ 後から[Ctrl]キーを押しながら範囲外が選択された場合は、範囲内の処理が優先されます。

GooUserラック · Answer

「範囲をA1:C10に絞る」ですが、この範囲外が後から選択された場合はどうするのでしょうか？
また範囲内と外を跨いだ選択が有った場合はどうするのでしょうか？例えば「B5」セルが選択された状態で [Ctrl]キーを押しながら「B2:D4」セルを選択した場合など…

GooUserラック · Answer

No.1 の訂正

すみません。No.1のコードでは [Ctrl]キーを使った複数セルの選択の場合、後から選択した方が右上でも元の方が選択されてしまいます。

GooUserラック · Answer

確認ですが、２つ以上のセルを選択したら１番右上のみの選択に変更する。つまり複数セルを選択出来ないようにすると言う事でしょうか？それでしたら
-----------------------------------------------------------------------------------------
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Count >= 2 Then
Application.EnableEvents = False
Target(1).Select
Application.EnableEvents = True
End If
End Sub
-----------------------------------------------------------------------------------------

マウスでセルを２個以上範囲選択されたら、強制的にセルを選択範囲の左上に移動するには？

考え方を逆にしてみました。

余計なことかもしれませんが以下の２つを作っておくと、修正作業に一時的に動作を止めたり再開で来たりしますので便利ですよ。

yoreyoreさんやtom04さんの物だと、例えば「B5」セルを選択している状態で[Ctrl]キーを押しながら「A3」セルを選択

おはようございます。

こんにちは！

目的がはっきりしませんが、シートモジュールに次のようなコードを書くと、似たようなことになります。

A1:C10の範囲では複数のセルを選択出来ないようにするだけでしたら以下のようなもので良いと思います。

「範囲をA1:C10に絞る」ですが、この範囲外が後から選択された場合はどうするのでしょうか？

No.1 の訂正

確認ですが、２つ以上のセルを選択したら１番右上のみの選択に変更する。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング