エクセルでの複数条件

たとえば、100以上＆150未満の条件で該当する個数をカウントしたい場合、countif関数とif関数をどういう風に組み合わせればいいのでしょうか。よろしくお願い致します。

No.3 ベストアンサー 回答者： nishi6 回答日時： 2001/08/06 12:13

配列数式を使ってみます。

A1からA10に値が入っているとします。
　　=SUM(IF(100<=A1:A10,IF(A1:A10<150,1,0)))
として、Ctrl+Shift+Enter で登録します。

追加の質問の件は、
E1からE10に年齢が、FIからF10に人数が入っているとします。
　　10代の人数　　=SUM(IF(10<=$E$1:$E$10,IF($E$1:$E$10<20,$F$1:$F$10,0)))
として、Ctrl+Shift+Enter で登録します。

後はコピーして、条件を修正します。
　　20代の人数　　=SUM(IF(20<=$E$1:$E$10,IF($E$1:$E$10<30,$F$1:$F$10,0)))
　　30代の人数　　=SUM(IF(30<=$E$1:$E$10,IF($E$1:$E$10<40,$F$1:$F$10,0)))
として、Ctrl+Shift+Enter で登録します。

この回答への補足

回答ありがとうございます。
=SUM(IF(10<=$E$1:$E$10,IF($E$1:$E$10<20,$F$1:$F$10,0))) の式を入れて試した場合、E列の人数の合計が入ってしまうのですが、こちらのやり方に問題があるのでしょうか？

補足日時：2001/08/06 15:03

この回答へのお礼

すいません。Ctrl+Shift+Enterの使い方に問題がありました。
目的通りの表が出来ました。
ありがとうございました。

お礼日時：2001/08/06 15:12

No.2 回答者： HitomiKurose 回答日時： 2001/08/06 12:03

年齢～31がA1～A9,人数～4がB1～B9に入っているとして、

10代は
=SUM(B2:INDEX(A2:B9,MATCH(19,A2:A9),2))-SUM(B2:INDEX(A2:B9,MATCH(9,A2:A9),2))
MATCHの中の19と9を適当に調整すれば、20代30代や、10代から30代の合計もＯＫ。

No.1 回答者： HitomiKurose 回答日時： 2001/08/06 10:13

=COUNTIF(カウントしたい範囲,"<150")-COUNTIF(カウントしたい範囲,"<100")

でいかがでしょう。
150未満の数の総数から100未満の数の総数を引く。

この回答へのお礼

早速の回答ありがとうございます。
上記の質問に関しては対応出来たのですが、もう一つ同じような質問が出来てしまいました。
以下のような場合にはどうすれば集計出来るのでしょうか。
重ね重ねすいません。

10代の人数と20代の人数と30代の人数を求める場合
年齢 人数
16 1
19 3
20 3
23 1
28 5
29 3
30 3
31 4

お礼日時：2001/08/06 10:58