VBの質問です

VB6を使って開発をしています。
AとB２つのMDBがあってAの全テーブルのデータをBの全テーブルにデータをコピーしたいのですがプログラムでどうやるのかがわかりません。
どなたかわかるかた私に教えてください。お願いします。

No.6 ベストアンサー 回答者： TAGOSAKU7 回答日時： 2001/11/06 16:34

サンプルです。

データレコード１件づつやらないでもできます。
CopyTableに二つのファイルパス（元、先）を指定してください。


Private Const CONNECTCONST　　　 As String = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="

Sub Main()
　　Call CopyTable("c:\A.mdb", "c:\B.mdb")
End Sub

Sub CopyTable(inSrcDB As String, inDstDB As String)
　　Dim Cnn As ADODB.Connection
　　Dim Cat As ADOX.Catalog
　　Dim wkTbl　 As ADOX.Table
　　Dim strConnect　As String
　　
　　Dim strTblName　As String
　　
　　Dim strSQL　　　As String
　　
　　'まず初期化
　　Set Cnn = New ADODB.Connection
　　Set Cat = New ADOX.Catalog
　　
　　'DBの接続文字
　　strConnect = CONNECTCONST & inSrcDB & ";"
　　'接続
　　Cnn.Open strConnect
　　'カタログ作成
　　Cat.ActiveConnection = Cnn
　　
　　'カタログの中から、システムテーブル以外のものについて処理を行います。
　　For Each wkTbl In Cat.Tables
　　　　If wkTbl.Type = "TABLE" Then
　　　　　　'テーブル名を取得
　　　　　　strTblName = wkTbl.Name
　　　　　　
　　　　　　'コピー先のテーブルデータを削除するSQL文の実行
　　　　　　strSQL = "delete from [" & inDstDB & "]." & strTblName
　　　　　　Cnn.Execute strSQL
　　　　　　
　　　　　　'コピー元をコピー先へデータをコピーするSQL文の実行
　　　　　　strSQL = "insert into [" & inDstDB & "]." & strTblName & _
　　　　　　　　" select * from " & strTblName
　　　　　　Cnn.Execute strSQL
　　　　　　
　　　　End If
　　Next wkTbl
　　
　　Cnn.Close
　　Set Cnn = Nothing
End Sub

No.5 回答者： y_herohero 回答日時： 2001/11/06 16:20

まとめますと…。

1.デバッグ用DB(A)、本番用DB(B)があり、
　BへAのレコードをテーブル毎に移行(コピー?)したい。
　(どっちが本番用かは?です)

2.Bの帳票テーブルには削除できないレコードがある為、
　帳票テーブルについては追記を行いたい。
　⇒主キーが重なる場合は移行は行わない。

※ここで問題となるのがその他のテーブルで、
　Bの既存レコードはどうするのでしょう？
　(1)テーブルの内容をクリアしてまったくAと同じにするのでしょうか？
　(2)もしくは追記を行い主キーが重なった場合は上書きとするのでしょうか？

こんな感じでしょうか？補足お願い致します。

P.S.
VBでDBバックアップツールを開発していらっしゃるのでしょうか？

この回答への補足

Bの中にあるレコードの中味は消去します。
あるテーブルだけ残してほかのテーブルの中味を全部いれたいのです。

私は普通のＶＢでのシステムを開発しています。バックアップはやっていないです。

本当に話がわかりずらい文章ですいません。

補足日時：2001/11/06 16:28

No.4 回答者： TAGOSAKU7 回答日時： 2001/11/06 15:47

全く同意見です。

単なるMDBのバックアップなら、
Kill B.mdb
FileCopy A.mdb, B.mdb
で良いのでは？

もしかして、B.mdbは削除してはいけないテーブルも存在してるのですか？

この回答への補足

何回も補足してすいません。
Bのmdbにはけせないテーブルがあるんです。
mdbじたいもODBCでつないでいるものです。

補足日時：2001/11/06 16:00

No.3 回答者： y_herohero 回答日時： 2001/11/06 15:31

詳細な用途がわからないのでなんとも回答が難しいです。

DBのまるごとバックアップなのか、追記でもよいのか。

スピードを優先されたい様ですが、
BのDB自体を一旦削除し、
AのDBをBとしてリネーム(又はコピー)するっていうのはいかがですか？

この回答への補足

練習用のDBと本番用のDBと内容がまったく同じであるのですが、帳票を使っているため帳票用のテーブルはコピーはできないみたいなので全部で約20テーブルくらいのテーブルの中味だけをコピーしたいです。
やっぱり１レコードづつループでまわすしかないでしょうか？？

補足日時：2001/11/06 15:44

No.2 回答者： TAGOSAKU7 回答日時： 2001/11/06 14:30

必要な情報が載ってません。

１．DBの接続方式は？ADOとかDAOなどがありますよね。
２．Aに元のテーブルがあるんですよね。Bにも同じテーブルが存在してるのですか？テーブルの作成から行うのですか？
２－１．もしテーブルの作成から行うのであれば、キーとかの情報も全てコピーするのですか？
２－２．もしテーブルの作成を行わないのであれば、すでにBに入っているデータは消去するのですか？

この回答への補足

DBの接続はADOです。テーブルはまったく同じものです。しかしテーブルは複数あり全部同じです。
2　テーブルの作成はしないです。テーブルの中味のデータだけをコピーしたいです。
2-2　Bには行っているテーブルは消去します。
すいません補足させていただきます。

補足日時：2001/11/06 14:37

No.1 回答者： y_herohero 回答日時： 2001/11/06 14:19

AとBはまったく同じ構造のDBであると仮定して…。

初歩的なフローとしてはテーブル毎に、
1.AのDBから1レコード取得する。
2.BのDBに1レコード書き込む。
をAのレコード件数分ループして行う。

という感じですね。
ひょっとしてフローではなくてコーディング方法やDBの操作方法が知りたいのでしょうか？

この回答への補足

あまりにもレコード数もテーブル数も多いのでループすると処理時間がかかってしまいます。もっと早く処理する方法はありますか？？

補足日時：2001/11/06 14:42