EXCELでの期間のカウント方法

EXCELのA列に日付が入っているのですが、決められた期間のセルをカウントしたいのです。

例
日付　　5月件数　6月件数　7月件数　
6/1　　　　2　　　　3　　　　1　
6/3　　　　　　
5/24　　　　　
7/16
5/1
6/30

このようにカウントしたいのですが、具体的にはどのような式を作ればよいでしょうか？
ご存知のかたがいらっしゃいましたらよろしくお願い致します。

No.2 ベストアンサー 回答者： mshr1962 回答日時： 2006/07/11 18:02

5月

=COUNTIF($A$2:$A$10,">=2006/5/1")-COUNTIF($A$2:$A$10,">=2006/6/1")
=SUMPRODUCT((MONTH($A$2:$A$10)=5)*1)
=SUMPRODUCT((TEXT($A$2:$A$10,"yymm")="0605")*1)

この回答へのお礼

ありがとうございます。無事2行目の式でやりたいことができました！ありがとうございました。

お礼日時：2006/07/11 18:49

No.4 回答者： mike_g 回答日時： 2006/07/11 18:39

》 A列に日付が入っている…

例示されているのは、6/1 のように“月/日”表示だけど、実際は 2006/6/1 のように日付形式で入力されているのでしょうか？


》 決められた期間のセルをカウントしたい…

A列には同年だけ（例えば 2006年だけ）で、かつ、「決められた期間」は複数年にまたがってはいないと考えてよろしいですか？

No.3 回答者： zap35 回答日時： 2006/07/11 18:12

１行目がタイトル行。

Ａ列にデータ、B1～D1に"5月"、"6月"、"7月"と文字列入力したとき、B2セルに

=SUM(IF(TEXT($A$2:$A$500,"m" & "月")=B$1,1,0))

と入力してShift+Ctrl+Enterで求められます。これをC2、D2にコピー。

ただしこれだと月だけしか判定しませんから、データが増えて年を越すと前年分も集計してしまいます。
B1～D1のタイトルも日付で入力して

=SUM(IF(TEXT($A$2:$A$500,"yyyymm")=text(B$1,"yyyymm"),1,0))

の方がいいかもしれません

No.1 回答者： mu2011 回答日時： 2006/07/11 17:58

次の方法は如何でしょうか。

例えば、B1:D1の書式が0"月件数"で5,6,7が設定されているとします。
B2に=SUMPRODUCT((MONTH($A$2:$A$7)=B1)*1)を設定して右方向にコピーして下さい。