[Excel2003]ツールバーの拡大倍率の選択肢

Excelのツールバーに拡大表示倍率のコンボボックスがありますが、ここで選べる選択肢は25%、50%、75%、100%、200%ですよね。
私はよく130%を使うのですが、そうするにはいちいち直接入力しないといけません。
コンボボックスの選択肢に任意の倍率を追加するようなことはできませんか？

合わせてフォントサイズの選択肢への追加方法も教えてください。

No.3 ベストアンサー 回答者： Wendy02 回答日時： 2006/08/11 00:55

Wendy02です。

既存の、「拡大表示倍率のコンボボックス」とほとんど変わりません。

取り付け方：

Alt　+　 F11 (Altを押しながらF11）を押すと、Visual Basic Editor 画面が出てきます。
次に、メニューの[挿入]－[標準モジュール]と開けて、クリックすると、画面が現れますので、
そのすべてを、白い画面に貼り付けて、

Alt　+　Q で、画面を閉じます。

後は、保存して、終了します。次に、再度、そのファイルを開ければ、
メニューバーのヘルプの右隣に表示されます。

ズームの編集は、再び、Visual Basic Editor で開けて、
Module 1 というところを開いて、以下を修正して、同じように終了して、ファイルを開ければ、変化しています。

'選択リスト
　　.AddItem "200%"　'1
　　.AddItem "130%"　'2
　　.AddItem "100%"　'3
　　.AddItem "75%"　 '4
　　.AddItem "50%"　 '5

もしも、他のブックも使うようでしたら、個人用マクロブックの標準モジュールに登録してください。
個人用マクロブック(Personal.xls)は、[ツール]－[マクロ]－[新しいマクロの記録]
[マクロの保存先]－[個人用マクロブック]－[OK]
とすれば、個人用マクロブックが作られますので、何もせずに、記録マクロを終了して、

Visual Basic Editor で開けて、Personal.xls を開いて、Module1 に、先ほどのコードを貼り付けてください。そして、保存にします。

Excelを再起動すれば、メニューが出ます。

この回答へのお礼

なるほど、こんなふうに追加できるんですね。
早速試してできました。
ありがとうございました。

お礼日時：2006/08/11 09:52

No.2 回答者： Wendy02 回答日時： 2006/08/10 22:29

こんばんは。

Excelのメニューバーに拡大表示倍率のユーザー・コンボボックス（ヘルプの右隣に表示されます。)

以下の「選択リスト」のところを書き換えてください。常識的な範囲なら、設定は可能だと思います。
ただし、現在のコードでは、選択リストは、最低、３行は必要です。

.ListIndex = 3　'100% の表示

は、３番目が、デフォルト表示です。

'-----------------------------------------
'標準モジュールのみ
'-----------------------------------------

Sub Auto_Open()
　'起動時の設定
　Call CommandMenu_Add
End Sub
Sub CommandMenu_Add()
Dim myCB As CommandBar
Dim cnt As Integer
Dim myCBCtrl As CommandBarControl
　On Error Resume Next
　'二重設定の回避
　Application.CommandBars("WorkSheet Menu Bar").Controls("ユーザーズーム(&Z)").Delete
　On Error GoTo 0
　'
　Set myCB = Application.CommandBars("WorkSheet Menu Bar")
　cnt = myCB.Controls.Count
　Set myCBCtrl = myCB.Controls.Add(Type:=msoControlDropdown, Before:=cnt + 1, Temporary:=True)
　With myCBCtrl
　　.Caption = "ユーザーズーム(&Z)"
　　'--------------------------
　　'選択リスト
　　.AddItem "200%"　'1
　　.AddItem "130%"　'2
　　.AddItem "100%"　'3
　　.AddItem "75%"　 '4
　　.AddItem "50%"　 '5
　　'-------------------------
　　'仕様
　　.OnAction = "WinZoom"
　　.ListIndex = 3　'100% の表示
　　.Tag = "myZoom"
　　.TooltipText = "ズーム"
　　.DropDownWidth = 50
　　.Width = 50
　　.Visible = True
　End With
Set myCBCtrl = Nothing
Set myCB = Nothing
End Sub

Sub WinZoom()
'ズーム設定
ActiveWindow.Zoom = Val(CommandBars("WorkSheet Menu Bar").Controls("ユーザーズーム(&Z)").Text)

End Sub

'-----------------------------------------

>フォントサイズの選択肢への追加方法も教えてください。
こちらの方は、確か、すでにあるはずですから、割愛させていただきます。

この回答への補足

すみません、ご回答内容について質問です。
＞Excelのメニューバーに拡大表示倍率のユーザー・コンボボックス（ヘルプの右隣に表示されます。)
これの意味が分からないのですが。。。
このソースはどうやったら見ることができて編集できるのですか？

補足日時：2006/08/11 00:06

No.1 回答者： takuteku 回答日時： 2006/08/10 21:48

コンボボックスの選択肢に任意の倍率を追加する事は出来るのかわかりませんが、

Ctrlキー押しながら、マウスのホイール（真ん中のぐりぐり）を動かして見てください。
細かく倍率が（15％ずつ）変わりますよ。
直接入力より早く出来るかと思います。

あと、これもコンボボックスの選択肢に追加の仕方はわかりませんが、
コンボボックスに追加したいサイズは一つだけですか？
一つだけなら、
ツール→オプション→全般→標準フォント→フォントサイズ→設定したいフォントサイズを直接入力→ok
で、変えられますよ。

この回答へのお礼

ご回答ありがとうございます。
ホントだ！ホイールだと15%ずつなんですね。
まあまあ使えそうです。（というのは、Thinkpadなのでホイールではないためちょっと微妙なのです）
できればコンボボックスに追加されるのがベストなんですけどね。
あとフォントサイズは、標準サイズをそうしたいのではなく、いつでもそのサイズに変えられるようにコンボボックスに追加したいんですよね～
でも標準サイズ変更の方法も知らなかったので参考になりました。
ありがとうございました。

お礼日時：2006/08/11 00:14