エクセルを使用してＨＰの入力項目に入力する方法

初めまして。
エクセルを使用してＨＰの記入項目に文を入力する方法をご存知の方（そういったソフトでも構いません）いらっしゃいませんか？
何通りもあるのでエクセルを使用したいと思っております。

どうか、ご教授お願い致します。

No.1 ベストアンサー 回答者： venzou 回答日時： 2006/12/05 13:12

簡単なサンプルを紹介します。

サンプルはGoogleを開いて「油淋鶏」と入力して、検索（サブミット）します。

下準備
[Alt]+[F11]でVBを開き、[ツール]→[参照設定]
Microsoft Internet Controls
Microsoft HTML Object Library
この２つにチェックしましょう。

----以下サンプル----
Const URL = "http://www.google.co.jp/"
Const InputName = "q" '入力するInputの名前
Const InputValue = "油淋鶏" '入力するデータ
Const FormName = "f" '送信するFormの名前

Sub sample()
　Dim AppIE As InternetExplorer
　Dim Doc As HTMLDocument
　Dim obj As Variant
　
　'IEを起動して表示する
　Set AppIE = CreateObject("InternetExplorer.application")
　AppIE.Visible = True
　'URLを開く
　AppIE.Navigate URL
　'完了するまで待つ
　wait_ie AppIE
　'Documentを取得する
　Set Doc = AppIE.Document
　'Inputにデータを入力する
　For Each obj In Doc.getElementsByTagName("input")
　　If obj.Name = InputName Then
　　　obj.Value = InputValue
　　End If
　Next
　'Formを送信する
　For Each obj In Doc.forms
　　If obj.Name = FormName Then
　　　obj.submit
　　　Exit For
　　End If
　Next
　'完了するまで待つ
　wait_ie AppIE
　
　'IEを終了するなら下を行のコメントをはずす
　'AppIE.Quit
End Sub

'IEの処理が終了するのを待つサブルーチン
Sub wait_ie(AppIE As InternetExplorer)
　Do Until AppIE.ReadyState >= READYSTATE_COMPLETE
　　DoEvents
　Loop
　Do While AppIE.Busy
　　DoEvents
　Loop
End Sub
----以上サンプル----