入力されたデータによって、次のアクティブセルを変更したいのですが

普通、セルA1に入力して確定すると、B2がアクティブになりますが
A1に『A』と入力すると、セルD5がアクティブになる
A1に『B』と入力すると、セルE5がアクティブになる
このような設定って、できますか？教えてください。

No.1 ベストアンサー 回答者： papayuka 回答日時： 2002/10/12 22:16

こんにちは。

ExcelのVBAを使います。新規ブックで試して下さい。
シート名のタブを右クリックして「コードの表示」
出てきた画面に貼り付けます。

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim r As Range
　For Each r In Target
　If r.Address = "$A$1" Then
　　 Select Case r.Value
　　 Case "A"
　　　r.Offset(4, 3).Select
　　 Case "B"
　　　r.Offset(4, 4).Select
　　 End Select
　　 Exit For
　End If
Next r
End Sub

この回答へのお礼

ありがとうございました。
色々と試していたので、すっかり、お礼のお返事が遅くなってしまい
申し訳ありません。
思い通りの動作に、思わず感動しました。
本当にありがとうございました。

お礼日時：2002/10/13 21:17

No.8 回答者： taisuke555 回答日時： 2002/10/13 09:23

#5から#1さんへ

＞「A」を入れてCtrlを押しながらEnterしたような場合
そんな入力方もあるんですね！
普段使わないので、頭にありませんでした。
ご指摘ありがとうございます。
そうすると、やはりFor Eachで回さないといけないみたいですね。

No.7 回答者： taisuke555 回答日時： 2002/10/13 09:22

#5から#1さんへ

＞「A」を入れてCtrlを押しながらEnterしたような場合
そんな入力方もあるんですね！
普段使わないので、頭にありませんでした。
ご指摘ありがとうございます。
そうすると、やはりFor Eachで回さないといけないみたいですね。

No.6 回答者： papayuka 回答日時： 2002/10/13 02:19

#1です。

#5さんへ

TargetはRangeなので複数のセル、複数エリアのセルが渡される事があります。

A1:F10 を選択し、ActiveCellに「A」を入れてCtrlを押しながらEnterしたような場合でも、A1を含んでいたら反応させるには、For Each で回すのが手っ取り早いと思ってます。
含んでいるかだけの判断なら Intersect で出来ますが、値の判定を伴うので、、、

仕様の問題なので、複数セル、複数エリアを選択しての操作をしないなら For Each は不要でしょうね。

No.5 回答者： taisuke555 回答日時： 2002/10/13 00:07

No.2～No.5の方の方法は、A1セルに"A"（又は"B"）が入力されていると

どのセルで入力しても、D5（又はE5）に飛んでしまうと思います。
この方法は、"A"も"a"も飛ぶようになっています。

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
If Target.Address = "$A$1" Then
Select Case UCase(Target.Value)
Case "A"
Range("D5").Activate
Case "B"
Range("E5").Activate
End Select
End If
End Sub

Targetはchangeイベントが実行された時に選択されているセルが入っています。
ちょっと試したのですが、範囲を選択してから入力しても入力セルのアドレスしか
戻ってないようなので、No.1の方のようにFor Each ... Nextを使用しないでみました。
もし、問題があれば教えてください。

この回答へのお礼

ありがとうございました。
Targetはchangeイベント・・・の文章
勉強不足の私には、意味がわからなくて
でも、そういう事がわかるようになりたい！って本気で思いました。
今までも、ちょっとだけ、VBAを勉強した事があるのですが
（本当にちょっとだけで・・・）
今回の事で、もっとがんばってみよう！って思いました。

お礼日時：2002/10/13 21:43

No.4 回答者： imogasi 回答日時： 2002/10/12 23:00

＃２のものです。

申し訳ありません。題意を少し取り違えていました。２行ほど変更させてください。
Private Sub Worksheet_Change(ByVal Target As Range)
a = Array("", "a", "b", "c", "d")
b = Array("", "$F$1", "$D$2", "$G$3", "$C$4")
For i = 1 To UBound(a)
If Cells(1, 1).Value = a(i) Then
Worksheets("sheet1").Range(b(i)).Select
Exit Sub
End If
Next i
End Sub
Cells(1,1)をTargetにするのも場合によると意味があるかもしれません。

この回答へのお礼

最初、No2の方法を試した時に
動作しなかったので、あれ？って思っていたのですが
上記の通りにやったら、動作しました。
ありがとうございました。

お礼日時：2002/10/13 21:33

No.3 回答者： imogasi 回答日時： 2002/10/12 22:41

操作による設定を目指しましたが思いつかずＶＢＡにしました。

Private Sub Worksheet_Change(ByVal Target As Range)
a = Array("", "$A$1", "$A$2", "$A$3", "$A$4")
b = Array("", "$F$1", "$D$2", "$G$3", "$C$4")
For i = 1 To UBound(a)
If Target.Address = a(i) Then
Worksheets("sheet1").Range(b(i)).Select
Exit Sub
End If
Next i
End Sub
aとbのArrayは対になっています。セルアドレス$A$1－－＞$F$1の対応です。もっと増やせます。この例では同行に飛ぶようにしていますが、異行でも差支えありません。
もう一段ＦｏｒＮｅｘｔを増やすと、$A$1－－＞$F$1－－＞$A$2のように連続でつながるように出来そうです。

この回答へのお礼

ありがとうございました。
今回の希望した動作とは、ちょっと違ったのですが
入力後にアクティブセルを移動する時に使えそうですよね。
自分でこんな風にBVAを組めるように、勉強してみようと思いました。

お礼日時：2002/10/13 21:30

No.2 回答者： kazuhiko5681 回答日時： 2002/10/12 22:38

はじめまして。

マクロを組めば、簡単にできると思います。サンプルマクロを組んでみましたので、参考にしてみて下さい。

Private Sub Worksheet_Change(ByVal Target As Range)

Select Case Range("A1").Value

case "Ａ"
Range("D5").Select
case "Ｂ"
Range("E5").Select

End Select

End sub

１.新規ブックを開き、ＡＬＴ＋Ｆ１１キーを押してＶＢＥ画面を開く
２.画面左上のVBAProject徒書いてある下のSheet1をダブルクリックし、右側の白い部分へ上のコードをコピー・ペーストする。
３.ＡＬＴ＋Ｆ１１キーを押してエクセルの画面にもどり、シート１のＡ１に適当な値を入力する

あなた様のおやりになりたいことが実現していると思います。
もし、私でよろしければ、あなた様がおやりになりたいことを自動でできるマクロを一緒に作成してみたいと思っております。ご希望の節は、お知らせ下さい。