エクセルでカーソルの移動方向の変更をマウスで

Question

エクセル97ですが、カーソルの移動方向を変更することが多いので、マウスの右クリックのプルダウンメニューから行いたいのですが、どうすればいいですか？

また、他に良い方法はありませんか？

現在は

ツール
↓
オプション
↓
編集
↓
入力後にセルを移動する

で　Enter キー入力後の方向を変えていますが、単純データの入力が多いので面倒です。

以上、宜しくお願いします。

hayasi456 · Accepted Answer

入力する範囲を選択してから入力すると
選択範囲が横１列ならばEnterを押すと右横に移動していきます。

私は矢印→キーを利用してます。

okormazd · Answer

これを、Personal.xls か、適当なModuleにでも貼り付けて、適当なツールバーにマクロボタンをつくって、このマクロを登録する。このボタンをクリックするたびにカーソル移動が左右に切り替わる。

Sub cursor_leftright()

    Dim rl As Integer, cursrl As Integer, xlrl As Integer

    cursrl = Application.MoveAfterReturnDirection
    rl = (-xlToLeft + 1 + cursrl)
    rl = Not (rl)
    
    xlrl = xlToLeft + rl
    
    Application.MoveAfterReturnDirection = xlrl
    
End Sub

hige_082 · Answer

試してみて
エクセル2000で作成したので、保証は出来ませんが
---------------------------------------
Sub 右クリックメニュー作成()
    Dim ボタン親
    Dim ボタン子
    
    Set ボタン親 = Application.CommandBars("Cell").Controls.Add(Type:=msoControlPopup)
    With ボタン親
        .Caption = "カーソルの移動方向"
    End With
    
    Set ボタン子 = ボタン親.Controls.Add
    With ボタン子
        .Caption = "下"
        .OnAction = "cursor_Down"
    End With
    
    Set ボタン子 = ボタン親.Controls.Add
    With ボタン子
        .Caption = "右"
        .OnAction = "cursor_Right"
    End With
    
    Set ボタン子 = ボタン親.Controls.Add
    With ボタン子
        .Caption = "上"
        .OnAction = "cursor_Up"
    End With
    
    Set ボタン子 = ボタン親.Controls.Add
    With ボタン子
        .Caption = "左"
        .OnAction = "cursor_Left"
    End With
End Sub

Sub cursor_Down()
        Application.MoveAfterReturnDirection = xlDown
End Sub

Sub cursor_Right()
        Application.MoveAfterReturnDirection = xlToRight
End Sub

Sub cursor_Up()
        Application.MoveAfterReturnDirection = xlUp
End Sub

Sub cursor_Left()
        Application.MoveAfterReturnDirection = xlToLeft
End Sub
-----------------------------------------------
Sub 右クリックメニュー削除()
    Application.CommandBars("Cell").Controls("カーソルの移動方向").Delete
End Sub
-------------------------------------------

fujillin · Answer

マウスの右クリックに登録するのはちょいと面倒だと思いますが、エクセルのメニューやコマンド化するのなら比較的簡単にできます。
エクセルの2000で実験してみましたが、97でも同様だと思います。
No1の方がすでにマクロを作成してくれていますので、これをそのままメニュー化する方法だけ記します。

エクセルのヘルプの「ユーザー設定のツールバーを作成する」を見ていただければ、ツールバーに上記の操作（マクロ）を登録する方法が出ています。解説に従って、新しいツールバーを作成し、4つのマクロを「右移動」、「下移動」・・・などわかり易い名前にして登録します。
あとは、このツールバーをマウスでワンクリックすることで必要な方向に移動方向を切替えられるようになります。

基本的にはショートカットと同じですが、マウス操作の方が、少しだけ「マウスの右メニュー」に近いかと思いまして・・・

Masa2072 · Answer

ANo.1の補足です。
XLStartにブックを保存した後、ファイルのプロパティで読み取り専用にしてください。
読み取り専用にしないとExcelを複数起動した場合に警告が出ます。
※保存時に読み取り専用を通知でも警告がでます。

noname#79209 · Answer

Enterキーの代わりに、移動したい方向の矢印キーじゃダメなんですか？

Masa2072 · Answer

ショートカットキーでもよければマクロを作って、XLSTARTフォルダに保存することで可能です。

まずは新規ブックを開きます。
以下のマクロを作成しショートカットキーを登録します。

Sub MoveAfterRight()
　　Application.MoveAfterReturnDirection = xlToRight
End Sub
Sub MoveAfterLeft()
　　Application.MoveAfterReturnDirection = xlToLeft
End Sub
Sub MoveAfterUp()
　　Application.MoveAfterReturnDirection = xlUp
End Sub
Sub MoveAfterDown()
　　Application.MoveAfterReturnDirection = xlDown
End Sub
ショートカットキーの登録はマクロダイアログ（マクロの実行画面）のオプションで設定できます。

作成したブックをXLSTARTフォルダに適当な名前で保存します。

自分だけで使用するのであれば
　　C:\Documents and Settings\ユーザー\Application Data\Microsoft\Excel\XLSTART に
PCを使用する全てのユーザーで使用するのであれば
　　C:\Program Files\Microsoft Office\OFFICE11\XLSTART に
　　※Office2003の場合

あとは一度Excelを再起動すれば指定したショートカットでEnterキー入力後の異動方向を変更できます。

エクセルでカーソルの移動方向の変更をマウスで

入力する範囲を選択してから入力すると

これを、Personal.xls か、適当なModuleにでも貼り付けて、適当なツールバーにマクロボタンをつくって、このマクロを登録する。

試してみて

マウスの右クリックに登録するのはちょいと面倒だと思いますが、エクセルのメニューやコマンド化するのなら比較的簡単にできます。

ANo.1の補足です。

Enterキーの代わりに、移動したい方向の矢印キーじゃダメなんですか？

ショートカットキーでもよければマクロを作って、XLSTARTフォルダに保存することで可能です。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング