バージョンアップしたらワードのマクロが使用できなくなった

お世話になります。
ワード２０００で作成したマクロがあるのですが、
パソコンの入れ替えで２００７になりました。
今まで使用していたマクロを実行したところエラーとなりました。
「このコマンドは使用できません。」という表示です。
このマクロはもう使用できないのでしょうか？
何か方法はありますでしょうか？

No.3 ベストアンサー 回答者： Wendy02 回答日時： 2008/08/05 17:54

#2です。

ここの部分を訂正してください。
×Const MYFOLDER ="C:\My Documents\My Pictures" '-gifファイルのフォルダ
　　
Const MYFOLDER ="C:\My Documents\My Pictures\"
文字の最後に、\ を入れます。

この回答へのお礼

ありがとうございます。出来ました!(^^)!今まで使っていたマクロが使用できなくて、作業時間がかかるようになってしまったのですが、助かりました。

お礼日時：2008/08/05 20:10

No.2 回答者： Wendy02 回答日時： 2008/08/05 15:25

こんにちは。

>このマクロはもう使用できないのでしょうか？
エラーの原因は、Application.FileSearch　で、2007 ではサポートされなくなりました。

前のものと変わるのは、その貼り付ける順番です。
2007で動かしたわけではありませんが、こんな風に考えました。


Sub 画像取込R()
　　Dim fn As Variant
　　Const MYFOLDER ="C:\My Documents\My Pictures" '-gifファイルのフォルダ　　
　　Selection.HomeKey Unit:=wdStory
　　fn = Dir(MYFOLDER & "*.jpg")
　　Do While fn <> ""
　　　　InsertFile MYFOLDER & fn
　　　　fn = Dir()
　　Loop
　　MsgBox "貼り付け完了"
End Sub
Private Sub InsertFile(fn As Variant)
　　Selection.TypeParagraph
　　Selection.InlineShapes.AddPicture _
　　FileName:=fn, _
　　LinkToFile:=False, _
　　SaveWithDocument:=True
　　Selection.TypeParagraph
　　Selection.TypeText _
　　Text:=Mid(fn, InStrRev(fn, "\") + 1)
　　Selection.TypeParagraph
End Sub
　　

この回答へのお礼

いろいろとありがとうございます。
「貼り付け完了」のメッセージは出ますが、実際の画像挿入が出来ないようです・・・。

お礼日時：2008/08/05 17:49

No.1 回答者： marbin 回答日時： 2008/08/04 18:46

どこでエラーになりますか？

コードをアップしてみてください。

この回答への補足

大変遅くなりました。
下記のコードです。以前、こちらのサイトで教えてもらいました。
C:\My Documents\My Picturesのjpg画像を自動で貼り付けるものです。
『実行時エラー5111
お使いのWindowsではこのコマンドは使用できません。』となります。
宜しくお願いします。

Sub 画像取込()
myFolda = "C:\My Documents\My Pictures" '-gifファイルのフォルダ
Set fs = Application.FileSearch
DoEvents
With fs
.NewSearch
.LookIn = myFolda
.SearchSubFolders = False
.FileName = "*.jpg"
If .Execute() > 0 Then
For I = 1 To .FoundFiles.Count
myfname = .FoundFiles(I)
Selection.TypeParagraph
Selection.InlineShapes.AddPicture FileName:= _
myfname, LinkToFile _
:=False, SaveWithDocument:=True
Selection.TypeParagraph
Selection.TypeText Text:= _
Right(.FoundFiles(I), _
Len(.FoundFiles(I)) - Len(myFolda) - 1)
Selection.TypeParagraph
Next I
End If
End With
MsgBox "貼り付け完了"
End Sub

補足日時：2008/08/05 11:11