エクセル（マクロ）置換２ 置換用リストを1行ずつ読み込むには

おはようございます。
エクセルは使いなれてますがＶＢＡは記録を使っていて
書き換える程度なので調べてもあまり理解できず困ってます。

先程質問して、結合セルの置換に関しては解決したのですが、
もし簡単にできるのであればと質問させて頂きました。
今置換用のシートは
Ａ列に置換前の文字
Ｂ列に置換後の文字が入ってます。

そして対象のシートが置換されるようになってるのですが、
これが列ではなく
1行目に置換前の文字
2行目に置換後の文字として処理するのには
どこを書き換えればよろしいのでしょうか？
色々試しましたがうまくいきませんでした。
実は、1行目に（A1セルに学生名(1)・A2のセルに住所(1)）など20個くらい項目があります
2行目以降に5000行程、学生のデータが入ってます。
各会社の履歴書フォーマットは違うのですが、
入力欄が学生名(1)や住所(1)など入っている項目が同じなので
置換しております。

今は、1行ずつ下のデータを置換シートに貼り付けて
履歴書のシートで置換えをして
新しいファイルにコピーし保存して次のデータという
アナログな処理をしております。
同じフォーマット（履歴書）でしたらvlookupなどが使えたのですが。。。
フォーマットによって１つのセルに、学生名(1)と住所(1)が両方入っていたりするので諦めました。
対象セルの場所も形も違いますしね・・・


列で処理していたマクロを参考に下に貼り付けました。
明日の昼までにあと４０００行を処理しなければならなくて困ってます。
お手数ですがどうぞよろしくお願いいたします。

Sub 置換()
With ThisWorkbook

If ActiveSheet Is .Worksheets(1) Then Exit Sub

For i = 1 To .Worksheets(1).Range("A500").End(xlUp).Row

ActiveSheet.Range("A1:Z200").Replace _
What:=.Worksheets(1).Range("A" & i).Value, _
Replacement:=.Worksheets(1).Range("B" & i).Value, _
LookAt:=xlPart, SearchOrder:=xlByColumns
Next
End With
End Sub

No.5 回答者： Wendy02 回答日時： 2009/07/20 10:26

んにちは。

つまり、以下のように条件が変わったということでしょうか？

今置換用のシートは
>Ａ列に置換前の文字
>Ｂ列に置換後の文字が入ってます。
　　　↓
>1行目に置換前の文字
>2行目に置換後の文字として処理するのには

私は、全体が見えないですね。以下は、#3様のコードと、ほとんど変わりません、というか、こちらの解釈とズレはないという意味程度です。

なお、.Worksheets(1)　このように、インデックスを使うと、左端にあるという意味だけですから、本来は、シートの名称を使ったほうがよいです。

'-------------------------------------------
'標準モジュール

Sub ReplacingCells()
　　Dim sh1 As Worksheet
　　Dim acSh As Worksheet
　　Dim col As Long
　　Dim rw As Long
　　Dim i As Long
　　
　　Set sh1 = ThisWorkbook.Worksheets(1) '置換ソースデータ
　　Set acSh = ActiveSheet
　　'シートデータの確認
　　If acSh Is sh1 Then MsgBox "置換ソース・シートは置換できません。", 48: Exit Sub
　　If WorksheetFunction.CountA(acSh.Cells) < 2 Then MsgBox "対象データがありません。", 48: Exit Sub
　　'範囲の確定
　　With acSh
　　　　rw = .Cells(Rows.Count, 1).End(xlUp).Row
　　　　col = .Cells(.UsedRange.Cells.Count).Column
　　End With
　　'置換実行
　　Application.ScreenUpdating = False
　　With acSh
　　　　For i = 1 To sh1.Range("A65536").End(xlUp).Row Step 2
　　　　　　.Range(.Cells(1, 1), .Cells(rw, col)).Replace _
　　　　　　What:=sh1.Cells(i, 1).Value, _
　　　　　　Replacement:=sh1.Cells(i + 1, 1).Value, _
　　　　　　LookAt:=xlPart, _
　　　　　　SearchOrder:=xlByColumns, _
　　　　　　MatchCase:=True
　　　　Next i
　　End With
　　Application.ScreenUpdating = True
　　Set sh1 = Nothing
　　Set acSh = Nothing
End Sub

'-------------------------------------------

No.4 回答者： imogasi 回答日時： 2009/07/20 09:41

>For i = 1 To .Worksheets(1).Range("A500").End(xlUp).Row

データが横の方向に流れているなら
For J = 1 To .Worksheets(1).Range("IV2").End(xlToLeft).Column
処理
Next j
IV2の２は実情に合わせて変えること。
実情によりStepが必要な場合が有るかも。
＞What:=.Worksheets(1).Range("A" & i).Value, _
Replacement:=.Worksheets(1).Range("B" & i).Value, _
はセル指定にRange表現を使っているが、Cells(2,j)のような書き方が
よいだろう。列番号をA,B、・・と英字で掴むことはやりにくいから。
ーー
質問をするときは、抽象化・簡略化したシートのデータ例を小数上げておくこと。
前の質問も関連がある場合は質問番号を挙げておくほうがよいだろう。

No.3 回答者： xls88 回答日時： 2009/07/20 09:06

回答番号：No.1、回答番号：No.2 は解釈が違っていたようです。

＞実は、1行目に（A1セルに学生名(1)・A2のセルに住所(1)）など
＞20個くらい項目があります
＞2行目以降に5000行程、学生のデータが入ってます。
A列の1行目に置換前の文字、2行目に置換後の文字として、3行目以降も交互にデータがあるということですか？
2行1セットで学生データがあり、検索する文字が学生名で、置換後の文字が住所、ということですか？

よくわかりませんが、とりあえず下記でどうでしょうか。
Sub test2()
Dim i As Long
With ThisWorkbook
If ActiveSheet Is .Worksheets(1) Then Exit Sub
For i = 1 To .Worksheets(1).Range("A65536").End(xlUp).Row Step 2
ActiveSheet.Range("A1:Z200").Replace _
What:=.Worksheets(1).Range("A" & i).Value, _
Replacement:=.Worksheets(1).Range("A" & i + 1).Value, _
LookAt:=xlPart, SearchOrder:=xlByColumns
Next
End With
End Sub

No.2 回答者： xls88 回答日時： 2009/07/20 06:39

回答番号：No.1で、抜けがありました。

For i = 1 To .Worksheets(1).Range("A500").End(xlUp).Row
も
For i = 1 To .Worksheets(1).Range("IV1").End(xlToLeft).Column
に変えてください。

No.1 回答者： xls88 回答日時： 2009/07/20 06:33

Replaceの引数、WhatとReplacementのセル指定を、Cellsに変えてみてください。

What:=.Worksheets(1).Range("A" & i).Value, _
Replacement:=.Worksheets(1).Range("B" & i).Value, _
を
What:=.Worksheets(1).Cells(1, i).Value, _
Replacement:=.Worksheets(1).Cells(2, i).Value, _