テキストファイル（tsv）を改行したい

WindowsXP環境でtsvファイルを扱いたいのですが、
このtsvファイルが改行無く出力されています。
このファイルに改行を入れたいと思っています。

【例】
（現状）
AAA　　　100　　　6　　　BBB　　　200　　　5　　　CCC　　　150　　　4　　　・・・
↓
（結果）３つめのタブを改行に変更したい。
AAA　　　100　　　6
BBB　　　200　　　5
CCC　　　150　　　4
・
・
・
新規ソフトウェアのインストールやフリーソフトを導入できない端末なので、
VBScriptで実現できないかと思っているのですが、なかなかうまくいきません。

どなたかお知恵を拝借いただけませんか？
よろしくお願いします。

No.2 ベストアンサー 回答者： nda23 回答日時： 2011/02/22 20:28

とりあえずこういうスクリプトですね。

Dim FSO
Dim InFile
Dim OutFile
Dim Text, Char, Count
Set FSO = CreateObject("Scripting.FileSystemObject")
Set InFile = FSO.OpenTextFile("C:\～", 1)
Set OutFile = FSO.CreateTextFile("C:\～", True)
Do Until InFile.AtEndOfStream
　　　　Count = 0
　　　　Text = ""
　　　　Do Until InFile.AtEndOfStream
　　　　　　　　Char = InFile.Read(1)
　　　　　　　　If Char = vbTab Then
　　　　　　　　　　　　Count = Count + 1
　　　　　　　　　　　　If Count = 3 Then Exit Do
　　　　　　　　End If
　　　　　　　　Text = Text & Char
　　　　Loop
　　　　OutFile.WriteLine Text
Loop
OutFile.Close
InFile.Close

※ファイル名は適当に変更してください。
※インデントに漢字空白を使用しています。
　コピペ注意

この回答へのお礼

実現できました！
非常に素早いご教授ありがとうございます。

お礼日時：2011/02/22 20:49

No.5 回答者： mt2008 回答日時： 2011/02/22 20:42

tsvファイルが複数行有るのか解らなかったけど、取りあえず複数行あってもいい様にしてみました。

例ではc:\test.tsvを整形した物をc:\test2.tsvに出力しています。


Set fso = CreateObject("Scripting.FileSystemObject")
Set inFile = fso.OpenTextFile("c:\test.tsv")
Set outFile = fso.CreateTextFile("c:\test2.tsv")

Do Until inFile.AtEndOfStream
　　nTab = 0
　　tempLine = inFile.ReadLine
　　For i = 1 To Len(tempLine)
　　　　one = Mid(tempLine, i, 1)
　　　　If one = vbTab Then
　　　　
　　　　　　nTab = nTab + 1
　　　　　　If nTab >= 3 Then
　　　　　　　　one = vbCrLf
　　　　　　　　nTab = 0
　　　　　　End If
　　　　End If
　　　　outFile.Write one
　　Next
　　outFile.Write vbCrLf
Loop
　　
inFile.Close
outFile.Close

この回答へのお礼

実現できました。
ありがとうございました。

お礼日時：2011/02/22 20:55

No.4 回答者： imogasi 回答日時： 2011/02/22 20:41

文字列ストリームを変数に読み込み、Ｉｎｓｔｒ（ＶＢＳｃｒｉｐｔの関数にもあり、ＶＢ（Ａ）と同じ）でＴＡＢコード（水平タブ,多分Chr(9))

を見つけ、３個目ごとにｖｂＣｒｌＬｆ　に置き換えていけば良いはず。
Ｉｎｓｔｒ関数は第１引数に開始位置を指定できるので、尺取り虫的に、開始位置をずらしては。Ｉｎｓｔｒ関数をかける。見つかった場所に次の文字が探索開始場所にする。
ＴＡＢコードは、ＶＢＳcriptでもｖｂＴａｂが使えるはず。
>、なかなかうまくいきません。
質問者が使用経験がすくないだけでは。
データ例を作っても、質問者の場合と同じかどうか判らないので、コードはここでは省略する。
１６進表示でデータの一部でも挙げれば情況がわかるが。

この回答へのお礼

> 質問者が使用経験がすくないだけでは。
お察しの通りです。この件で初めてVBScriptに触れました。
今後も勉強します。ありがとうございました。

お礼日時：2011/02/22 20:54

No.3 回答者： layy 回答日時： 2011/02/22 20:29

＞３つめのタブを

改行コードよりは悩みどころでは？。

改行はCRLF、ここではVBCRLFか。
CRとLF、CRはCHR(13)でLFはCHR(10)です。
よってCHR(13)＆CHR(10)。

TABはCHR(9)
CHR(9)を変数ｘに格納して、INSTRで３つめを見つける。

そんなところか・・・。

この回答へのお礼

参考になりました。
ご回答ありがとうございます。

お礼日時：2011/02/22 20:50

No.1 回答者： tsuduki123 回答日時： 2011/02/22 19:55

CHR関数だったかな文字コードを直接指定して改行を出してあげればいけるはずですよ

WScript.Echo "こそこそ" & CHR(13) & CHR(10) & "ごにょごにょ"

この回答へのお礼

参考になりました。
ご回答ありがとうございます。

お礼日時：2011/02/22 20:48