エクセルVBAで作成した別ブックにＶＢＡを記述したい

VBAで別ファイルの作成は下記で出来ているのですが、出来上がったファイルにＶＢＡを記述する方法がわかりません。
具体的には一番下のSub TEST()を新しいブックの標準モジュールに記述したいのと、sheet1に
Private Sub Worksheet_Change(ByVal Target As Range)
MsgBox "ChangeTEST"
End Sub
を入れたいです。
また
Private Sub Workbook_Open()
MsgBox "OpenTEST"
End Sub
も入れたいのです。
どうぞご教示ください。

Sub 複製()
Dim wb As Workbook, sc As Integer
sc = Application.SheetsInNewWorkbook

Application.SheetsInNewWorkbook = 1
Set wb = Workbooks.Add
Application.SheetsInNewWorkbook = sc

wb.Sheets("Sheet1").Select
ThisWorkbook.Sheets("Sheet1").Cells.Copy
wb.Sheets("Sheet1").Select
Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, _
SkipBlanks:=False, Transpose:=False
Selection.PasteSpecial Paste:=xlFormats, Operation:=xlNone, _
SkipBlanks:=False, Transpose:=False
Application.CutCopyMode = False

ActiveSheet.Buttons.Add(123, 195, 68.25, 15).Select
Selection.OnAction = "TEST"
Selection.Characters.Text = "TEST"
ActiveWorkbook.Close
ThisWorkbook.Activate
Sheets("Sheet1").Select
End Sub

Sub TEST()
MsgBox "TEST!!"
End Sub

よろしくお願いします。

No.1 ベストアンサー 回答者： AQUALINE 回答日時： 2004/01/20 17:13

わたしも前前からやってみたいと思っていたので、ネットを検索して調べてみました。

こんな感じで出来るようです。

'マクロ挿入
With wb.VBProject.VBComponents.Item("ThisWorkbook").CodeModule
.InsertLines 1, "Private Sub Workbook_Open()"
.InsertLines 2, ""
.InsertLines 3, "　　　Msgbox""ブックが開かれましたよ！"""
.InsertLines 4, ""
.InsertLines 5, "End Sub"
End With

With wb.VBProject.VBComponents.Item("Sheet1").CodeModule

.InsertLines 1, "Private Sub Worksheet_Change(ByVal Target As Range)"
.InsertLines 2, ""
.InsertLines 3, " MsgBox ""セルの値が変更されましたよ！"""
.InsertLines 4, ""
.InsertLines 5, "End Sub"

End With

wb.VBProject.VBComponents.Add (1) 'Module1挿入
With wb.VBProject.VBComponents.Item("Module1").CodeModule

.InsertLines 1, "Sub TEST()"
.InsertLines 2, ""
.InsertLines 3, "　　　Msgbox""TESTしたよ！"""
.InsertLines 4, ""
.InsertLines 5, "End Sub"

End With

この回答へのお礼

ありがとうございました。
出来ました。

お礼日時：2004/01/25 13:27

No.2 回答者： otasukey 回答日時： 2004/01/25 13:38

もう答えは出ていますが、ひとつだけ。

マクロをボタンにはりつける　Selection.OnAction = "TEST" ですが、作成先である新しいブックの名前まで入れないと作成元のブックのマクロにリンクされてしまうようですよ。念のため。

この回答へのお礼

ご親切にありがとうございました。
ええ、ためしたところそうでした。
たすかります。

お礼日時：2004/01/25 13:44