EXELでひとつのセルの値を任意の複数セルに振り分けたい

投稿させて頂きます。
もし、なにかわかることや参考関数があればお教え願えばと思います。

ある任意のセルA1の数値（１２３４５）を

B１～５までのセルに振り分けたいと思います。

実行後のイメージはこんな感じです

A1:１２３４５
B1：１
B2：２
B3：３
B4：４
B5：５
ただし、数値のみ入力が前提ですが、たとえば0が入るような場合

A1が１２３４　だったばあい　B5には何も入力せず空にしておきたいのです。

できるだけマクロは使いたくないので誰か、設定と関数などで出来るよ　というような方がおられましたらご教授願えませんか？
よろしくお願いいたします。

No.2 ベストアンサー 回答者： sanpin-cha 回答日時： 2004/06/10 21:08

B1=MIDB($A$1,1,1)

B2=MIDB($A$1,2,1)
B3=MIDB($A$1,3,1)
B4=MIDB($A$1,4,1)
B5=MIDB($A$1,5,1)

$A$1 :A1　を指定
次が何文字目かを指定
最後が指定した文字から何文字かを指定です。

この数式だと、半角入力で有効です。
全角だと２文字単位になると思います。

No.6 回答者： jindon 回答日時： 2004/06/10 21:52

お騒がせしております。

No.1 + No.3の訂正です。

B1セルからですね。

最後の　0　表示なし
B1: =IF(OR(ROW()>LEN(A$1),AND(ROW()=LEN(A$1),RIGHT(A$1,1)="0")),"",MID(A$1,ROW(),1)*1)

0 表示なし
B1: =IF(OR(ROW()>LEN(A$1),MID(A$1,ROW(),1)="0"),"",MID(A$1,ROW(),1)*1)

でフィルダウンです。

この回答へのお礼

たいへん参考になり助かりました。
EXEL関数は慣れていないのでこれからも少しづつ覚えていこうと思います

ありがとうございました！

Tsuka0614

お礼日時：2004/06/10 22:09

No.5 回答者： imogasi 回答日時： 2004/06/10 21:32

（１）むしろ１０桁定桁で、１２３４５を縦に△△△△△１２３４５にする方法を記します。

B1セルに=MID(REPT(" ",10-LEN($A$1))&$A$1,ROW(B1),1)をいれてB１０まで＋ハンドルを引っ張る。
（２）上詰ならC1セルに、=MID($A$1,ROW(C1),1)を
入れてC10まで＋ハンドルを引っ張る。
（３）（１）式に横に並べるならB1セルに
=MID(REPT(" ",10-LEN($A$1))&$A$1,COLUMN(B1)-1,1)
といれ、K1セルまで＋ハンドルを引っ張る。
（４）横ならB1に=MID($A$1,COLUMN(B1)-1,1)と入れて
F1まで＋ハンドルを引っ張る。

No.4 回答者： tinu2000 回答日時： 2004/06/10 21:11

こんばんは。

B1に、=MID(TEXT($A$1,REPT("0",LEN($A$1))),1,1)
B2に、=MID(TEXT($A$1,REPT("0",LEN($A$1))),2,1)
B3に、=MID(TEXT($A$1,REPT("0",LEN($A$1))),3,1)
B4に、=MID(TEXT($A$1,REPT("0",LEN($A$1))),4,1)
B5に、=MID(TEXT($A$1,REPT("0",LEN($A$1))),5,1)

で、出来ました。

No.3 回答者： jindon 回答日時： 2004/06/10 21:09

No.1の訂正です。

もちろん、両数式共に A2　に挿入です。

正↓

A2: IF(OR(ROW()-1>LEN(A$1),AND(ROW()-1=LEN(A$1),RIGHT(A$1,1)="0")),"",MID(A$1,ROW()-1,1)*1)

又は、

A2: IF(OR(ROW()-1>LEN(A$1),MID(A$1,ROW()-1,1)="0"),"",MID(A$1,ROW()-1,1)*1)

No.1 回答者： jindon 回答日時： 2004/06/10 21:04

最後の 0 だけ表示なしの場合、

B1: =IF(OR(ROW()-1>LEN(A$1),AND(ROW()-1=LEN(A$1),RIGHT(A$1,1)="0")),"",MID(A$1,ROW()-1,1)*1)

とにかく 0 を表示しない場合、

B1: =IF(OR(ROW()-1>LEN(A$1),MID(A$1,ROW()-1,1)="0"),"",MID(A$1,ROW()-1,1)*1)

として下方へコピー+ペースト