一定区間(35行)ごとの平均値を出すにはどうしたらいいでしょうか。

エクセルで、
一定区間ごとの平均値を出すにはどうしたらいいでしょうか。

35行毎で、0は含まずカウントもしない。

初級者なので解説もして頂けると幸いです。

質問者からの補足コメント

• 説明不足で申し訳ございません。
  
  3分間のデータの数値を平均します。
  3分間=35行(1-35)
  
  ex.
  10:00:00-10:02:55 (C10:C35)　
  10:03:00-10:05:55（C36:C71）
  ・・・・・
  
  C10 0.45(すべて正の数)
  C11　0.23
  C12　0.50
  C13　0.00
  C14　0.02
  
  ......
  
  0.00が35行内にあった場合、
  行数にはカウントしますが、平均値を出す分母にはカウントしません。0も分母には加えません。
  
  至らない点が多く申し訳ございませんが、
  助けて頂けると幸いです。

    補足日時：2016/02/22 07:10

No.4 ベストアンサー 回答者： mike_g 回答日時： 2016/02/22 09:39

ゴチャゴチャ説明無しで、添付図参照

D2: =SUM(OFFSET(A$1,(C2-1)*C$1,,C$1))/COUNTIF(OFFSET(A$1,(C2-1)*C$1,,C$1),">0")
【若干の補足】不明な点があれば[補足]で訊いてください。

No.6 回答者： CoalTar 回答日時： 2016/02/22 12:27

0の加算を除く必要がないからSUMIFはいらなかったですね(^^;

INDEX案
=SUM(INDEX(A:A,(C2-1)*35+1):INDEX(A:A,(C2*35)))/COUNTIF(INDEX(A:A,(C2-1)*35+1):INDEX(A:A,(C2*35)),">0")
参考まで

No.5 回答者： mike_g 回答日時： 2016/02/22 11:16

[No.4]への追加コメント、

先に挙げた数式は Excel 2002 で作成したので、それ以降のバージョンでも有効。
AVERAGEIF関数が装備されたバージョン(例:Excel 2013)なら、次式でもＯＫかと。
D2: =AVERAGEIF(OFFSET(A$1,(C2-1)*C$1,,C$1),"<>0")

No.3 回答者： mike_g 回答日時： 2016/02/22 01:19

》 35行毎で、0は含まずカウントもしない

「0は含まずカウントもしない」ってことは「行」に含まないということ？！
つまり、本当の連続35行内に 0 が５個あった場合は、 0 をカウントしない連続 40行を「一定区間」としての35行とすると？
0 が連続30個あったらどうする、どうする？

No.2 回答者： Hypnomatic 回答日時： 2016/02/22 01:01

不明点が色々ありますが、A列に数値が入力されているとすると、B35セルに以下の数式を入れることで、35行毎にB列にその区間の平均データ表示されます。

=IF(MOD(ROW(),35)=0,SUM(A1:A35)/(35-COUNTIF(A1:A35,0)),"")

解説）
求めたい平均を出す式は以下です。
平均＝指定範囲の数値合計／（指定範囲のセル個数ー０のセル個数）

では、それぞれの出し方ですが
指定範囲の合計を求める関数＝Sum(指定範囲）
指定範囲のセル個数＝35行毎なので35
指定範囲の指定条件のセルの個数をカウントする関数＝CountIF（指定範囲、指定条件）

これらで、0のセルの個数を除いた平均が求められます。

次に、35行の倍数以外は表示しないようにします。
35行毎なのかどうかは、現在の行数を35で除算をして余りが0なら35行毎ということになります。
現在が何行目なのかを取得するのはRow()
第１引数を第２引数で除算した余りを求めるのはMod(第１引数、第２引数

最後にこれらをIFを用いて余りが０の時は、平均を表示し、それ以外は""で表示しないようにして終わり

No.1 回答者： CoalTar 回答日時： 2016/02/22 00:37

結果はどこに、求めるのでしょうか？

下記の返答にもよりますが。
平均を求める範囲も説明不足
1～35行めまでの0を除く平均
次は2～36行めまでの0を除く平均?
それとも36～70行めまでの0を除く平均?
いずれにせよ、sumifとcountifは使いそうです