エクセルで、勤務表から 日付別に勤務者と勤務形態を抽出して、別シートに抽出したい

勤務表
no 氏名　　配置　始業　　終業　　遅刻早退　業務内容
１　山田　〇〇　10:00　19：00　　　　　　〇〇
２　鈴木　●●　10:00　19：00　　　　　　××応援
３　佐藤　△△　10:00　19：00　　　　　　△△
４　上田　〇〇　10:00　19：00　　　　　　□□応援
上記のような表があるのですがこの中から、応援者の氏名と始業・終業時間と業務内容から応援だけを別シートに抽出できる関数を教えていただきたいです。

質問者からの補足コメント

• やはり関数では、難しいですか・・・
  
  はい、それでお願い致します。

  No.1の回答に寄せられた補足コメントです。 補足日時：2018/10/07 16:23

No.4 ベストアンサー 回答者： mike_g 回答日時： 2018/10/07 17:36

添付図参照

１．Sheet1 に勤務表があるとします。
２．シート名 Sheet2 を「応援」という名前に変更して、このブックに
￣￣[名前を付けて保存]。
３．シート「応援」において、次式を入力したセル A2 を右および下に
￣￣ズズーッとオートフィル
￣￣ =IFERROR(INDEX(Sheet1!A$1:A$1000,SMALL(IF(Sheet1!$G$2:$G$1000=MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,99),ROW(A$2:A$1000)),ROW(A1))),"")
￣￣【お断り】上式は必ず配列数式として入力のこと

No.6 回答者： mike_g 回答日時： 2018/10/08 11:25

列F、G のデータ内容を間違えていたので、[No.4]は無視して仕切り直しです。

シート「応援」の作成手順は[No.5]に全く同じだけど、ステップ２の数式を次式に置き替えて読んでください。
=IFERROR(INDEX(INDIRECT(A$1),SMALL(IF(RIGHT(INDIRECT($G$1),2)=MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,99),ROW(INDIRECT(A$1))-1),ROW(A1))),"")
【お断り】
ａ．上式は必ず配列数式として入力のこと
ｂ．セル F2 の式のみ次のように修正する
￣￣=IFERROR(INDEX(INDIRECT(F$1),SMALL(IF(RIGHT(INDIRECT($G$1),2)=MID(CELL("filename",F1),FIND("]",CELL("filename",F1))+1,99),ROW(INDIRECT(F$1))-1),ROW(F1)))&"","")
￣￣末尾の方に「&""」を追加してます。

No.5 回答者： mike_g 回答日時： 2018/10/07 18:04

添付図参照

範囲に名前を付けてそれを利用するテもあります。
１．Sheet1 において、範囲 A1:F1000 を選択 ⇒ Alt+MC ⇒ “上端行”だけに
￣￣チェック残し ⇒ [OK]
２．シート「応援」において、次式を入力したセル A2 を右および下に
￣￣ズズーッとオートフィル
￣￣ =IFERROR(INDEX(INDIRECT(A$1),SMALL(IF(INDIRECT($G$1)=MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,99),ROW(INDIRECT(A$1))-1),ROW(A1))),"")
￣￣【お断り】上式は必ず配列数式として入力のこと

No.3 回答者： tom04 回答日時： 2018/10/07 17:10

こんにちは！

一例です。
↓の画像のように元データはSheet1にあり、Sheet2に表示するとします。
尚、Sheet2の1行目は表示したい項目名を入力しておきます。

Sheet2のA2セルに
=IFERROR(INDEX(Sheet1!$A$1:$G$1000,SMALL(IF(ISNUMBER(FIND("応援",Sheet1!$G$1:$G$1000)),ROW($A$1:$A$1000)),ROW(A1)),MATCH(A$1,Sheet1!$A$1:$G$1,0)),"")

配列数式なので、Ctrl＋Shift＋Enterで確定！（←必須★）しフィルハンドルで右へコピー！
B2・C2セルの表示形式を時刻（好みの表示形式）にしておき
A2～D2セルを範囲指定　→　D2セルのフィルハンドルで下へコピーすると
画像のような感じになります。m(_ _)m

No.2 回答者： chonami 回答日時： 2018/10/07 17:05

>「業務内容」に　「応援」という言葉が含まれていたら　別シートに書き出す

という条件なら数式でももちろん対応可能です。
ですが、いまいち条件がはっきりしないので、希望する結果も書いてもらえますか？

No.1 回答者： amerikaumare 回答日時： 2018/10/07 16:19

関数ではむずかしいので　マクロ　ではどうでしょうか　

「業務内容」に　「応援」という言葉が含まれていたら　別シートに書き出す　
というようなロジックでよいでしょうか？