お世話になります。 Excelの事でご質問したいです。 添付画像のように、A列にある、A2以下の数字

お世話になります。
Excelの事でご質問したいです。

添付画像のように、A列にある、A2以下の数字と文字が入った二つのセルを結合して、E列のようにしたい場合には、どんな方法がありますか？

=A2&A3でやるとその後ズレが生じオートフィルができず悩んでいます…

どうぞ、よろしくお願いいたします。

No.4 回答者： mike_g 回答日時： 2020/03/30 18:19

１．下記の各セルに夫々右側の式を入力して、範囲 G2:H2 のフィルハンドル

￣￣を下方にズズーッとドラッグ&ペースト
￣￣G2: =IF(1/A2,ROW(A2))
￣￣H2: =TEXTJOIN(" ",,A2:A3)
２．次式を入力したセル E2 を下方にズズーッとオートフィル
￣￣=IFERROR(INDEX(H:H,AGGREGATE(15,6,G$2:G$25,ROW(A1))),"")

この回答へのお礼

ご回答いただき、ありがとうございます。
お礼が遅くなり、大変申し訳ございません。

こちらでも希望する形式で表示することが出来ました。
すごいです！！

ご協力いただき、ありがとうございました。

お礼日時：2020/03/31 12:28

No.3 回答者： tom04 回答日時： 2020/03/30 16:37

No.2です。

＞セル間のスペースが必要な場合には・・・

↓の数式にしてみてください。
=OFFSET(A$2,(ROW(A1)-1)*2,,1)&" "&OFFSET(A$2,(ROW(A1)-1)*2+1,,1)

※　とりあえず半角のスペースとしています。m(_ _)m

この回答へのお礼

ご回答いただきありがとうございます。
追加で質問してしまったにも、関わらずお答え頂き感謝感謝です。

無事にスペースも入りました。

本当にありがとうございました。

お礼日時：2020/03/31 12:26

No.2 回答者： tom04 回答日時： 2020/03/30 15:00

こんにちは！

一例です。
=OFFSET(A$2,(ROW(A1)-1)*2,,1)&OFFSET(A$2,(ROW(A1)-1)*2+1,,1)

という数式を入れフィルハンドルで下へコピーしてみてください。

※　セル間のスペースは必要なのですかね？
そうであれば数式にスペースを追加してみてください。m(_ _)m

この回答へのお礼

ご回答いただきありがとうございます！！

すごい！！
こちらのやり方も希望する形式で出すことができました！！

大変申し訳ないのですが、セル間のスペースが必要な場合には、数式のどちらにスペースを追加すればよろしいでしょうか…
ご教示頂けますと幸いです…
よろしくお願いいたします。

お礼日時：2020/03/30 16:30

No.1 回答者： zongai 回答日時： 2020/03/30 14:56

2行目　Ａ列2行目と3行目

3行目　Ａ列4行目と5行目
4行目　Ａ列6行目と7行目
・・・という具合に行数を基準にして参照先の数値が増えていくことに着目します。

ｘ行数に対して、参照されるのは
①　【〔ｘー1〕×２】行目
②　【①+1】行目
なので、式が存在する行数を参照する関数「ROW()」を使って式をつくります。

①の式を作っていきます。
=(ROW()-1)*2
これで、参照する行数の数値が出ます。
例：4行目に式を入れれば、（4-1）＊2＝6　ですね。

参照先のアドレスを作ります。
=ADDRESS((ROW()-1)*2,1)
ADDRESS(【行】,【列】)という書き方になるので、
4行目だと、上に書いたとおり行は「6」なにるので
=ADDRESS(6,1)
は6行目の1列目で、「A6」セルとなります。

セルの値を直接取得するので
=INDIRECT(【セルアドレス】)
を使います。
全てをまとめて

=INDIRECT(ADDRESS((ROW()-1)*2,1))

となります。
2行目なら、A2セルの値を取得します。
3行目なら、A4セルの値を取得します。
4行目なら、A6セルの値を取得します。

②は①のセルの①行下の値なので、①の行の部分に「＋１」してやります。
=INDIRECT(ADDRESS((ROW()-1)*2+1,1))

質問で求める答えは、①と②を繋げたものなので、「&」でつないで、

=INDIRECT(ADDRESS((ROW()-1)*2,1))&INDIRECT(ADDRESS((ROW()-1)*2+1,1))

これでいかがでしょうか。

この回答へのお礼

ご回答いただきありがとうございます！！

すごい！！
希望する形式で出せました！！

ありがとうございます。

お礼日時：2020/03/30 16:27