「夫を成功」へ導く妻の秘訣 座談会

エクセルで一致している名前があれば一番最新(上の段から入力するので下へ行くほど新しくなる)の日付を抜き出すにはどうしたらいいでしょうか?同一人物の前回日付の部分に、前回の送付日が入るようにしたいです

名前    送付日   前回日付
山田    3/2
鈴木    3/15
山田    4/5   
伊藤    4/8      
佐藤    5/11   
近藤    5/21   
山田    5/30    4/5    
村田    6/2     
土田    6/9   
伊藤    7/1
山田    7/9      5/30

A 回答 (4件)

こんにちは!



横からお邪魔します。
No.1さんと同じ疑問を持ちつつ・・・

1行目は項目行でデータは2行目以降にあるとします。
C2セルに
=IF(COUNTIF(A$2:A2,A2)>1,SMALL(IF(A$2:A2=A2,B$2:B2),COUNTIF(A$2:A2,A2)-1),"")

配列数式なので、Ctrl+Shift+Enterで確定!(←必須★)し
フィルハンドルで下へコピーしてみてください。m(_ _)m
    • good
    • 1

Excelのバージョンを書いていないので最新だと判断します。



C2:=XLOOKUP(A2,A$1:A1,B$1:B1,"",0,-1)
下にコピー
    • good
    • 1

添附圖參照


次式を入力したセル C2 を下方にズズーッとオートフィル
【御斷はり】上式は必ず配列數式として入力の事
「エクセルで一致しているデータ」の回答画像2
    • good
    • 0

こんにちは



直近の同じ名前の行の日付を表示すれば良いのだと解釈しましたが、それだけではご提示の例のようにはなりません。
何かの条件が不足しているものと考えられます。
(上記条件だけだと、4行目、11行目も日付が表示されるはず)

最も新しい送付日にだけ前回日付が表示されるルールかとも思いましたが、それだと8行目は非表示だし、11行目は表示されるはずですし・・・??


よくわからないので、単純に「前回日付に該当するものがあれば表示」と考えると、C2セルに
=IF(A2="","",IFERROR(AGGREGATE(14,6,(B$2:B2)/(A$2:A2=A2),2),""))
の式を入れて下方にフィルコピーではいかがでしょうか?
    • good
    • 0

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています


このQ&Aを見た人がよく見るQ&A