エクセル関数（抽出）について

解決済

質問者：yukai4779
質問日時：2005/04/08 20:54
回答数：6件

宜しくお願い致します。
Ａ列にランダムな数字が入力されている。（重複する数字はなく、空セルなし）
Ｂ列にランダムな数字が入力されている。（重複する数字があり、空セルあり）

ここで、Ｂ列に入力されているＡ列のセルの数字を全部Ｂ列降順に抽出したいのです。（以下のような場合です）

　　　Ａ　　　Ｂ
１　　７　　２００
２　　２　　１００
３　　５　
４　　３　　１００　
５　　８　　　５０
これを以下のようにする方法を教えて下さい。
２００　７
１００　２
１００　３
　５０　８

通報する

この質問への回答は締め切られました。

質問の本文を隠す

回答 (6件)

No.6

回答者： macchan1
回答日時：2005/04/09 08:24

#3の回答にはE列の参照セルに勘違いがありました

エラー処理も入れた関数なら以下のように修正してください。

D列：=IF(COUNT(B:B)>=ROW(A1),LARGE(B:B,ROW(A1)),"")

E列=IF(COUNT(B:B)>=ROW(A1),INDEX(A:B,MATCH(D1,D:D,0)+COUNTIF($D$1:D1,D1)-1,1),"")

ちなみに上記の式はどこの行に貼り付けてもOKです。

- 0
- 件

通報する

この回答へのお礼

御回答ありがとうございます。
E列が循環になったのが残念です。でも御検討下さりまして感謝致します。

通報する

お礼日時：2005/04/09 21:18

No.5ベストアンサー

回答者： maruru01
回答日時：2005/04/09 01:27

こんにちは。

maruru01です。

D、E列に抽出するとします。
D1に、

=IF(COUNT($B$1:$B$10)<ROW(A1),"",INT(LARGE(INDEX($B$1:$B$10+1/(ROW($B$1:$B$10)+1),),ROW(A1))))

E1に、

=IF(COUNT($B$1:$B$10)<ROW(A1),"",INDEX(A:A,ROUND(1/MOD(LARGE(INDEX($B$1:$B$10+1/(ROW($B$1:$B$10)+1),),ROW(A1)),1),)-1))

と入力して、D1:E1を下の行へコピーします。

なお、データ範囲は適宜変更して下さい。

- 0
- 件

通報する

この回答へのお礼

素晴らしい。まさに求めていたのはこれです。質問の内容は簡単に説明しましたが、実はとんでもなく複雑であり、ポイントは次々と行が足されるためにその都度ソートをかける手間を省きたかったのです。

通報する

お礼日時：2005/04/09 21:17

No.4

回答者： tresbien
回答日時：2005/04/09 01:16

Bに数値が重複していますから、逆のそれに対応する数値を抽出するには関数では無理になります。

どうしても自動でセルに書き出したいのであればVBA、又は、作業域を作るなら出来ると思います。

例えば、

C列に　　=IF(B1="","",B1*10+COUNTIF($B$1:B1,B1))　　などのように数値を加工したものをつくり
(整数でなかったら別に考える）

D列には　　「D1」　=IF(ISERROR(LARGE(C:C,ROW())),"",LARGE(C:C,ROW()))　　で並べ替える。

そしてE列で戻し　　=IF(ISERROR(INT(D1)/10),"",INT(D1/10))

F列で対応したAの値を書き出す。　　=IF(D1="","",INDEX(A:C,MATCH(D1,C:C,0),1))

100に対応する値がひっくり返ってしまいましたが、あとは良いと思います。