エクセル初心者です。関数の使い方を教えてください。
B2列に「男」と「女」を入力してあります。
D2列には「出席」「欠席」が入力してあります。
っで、欠席者を数えるのはCOUNTIF(B2:B30,”欠席”)なのかな と思うのですが、男の子の欠席を数えるのは、どうすればいいのでしょうか?
IF関数と組み合わせるのでしょうか? それとも他にいい関数がありますか? 

このQ&Aに関連する最新のQ&A

A 回答 (2件)

おはようございます。


shkwtaさんがたぶん書き忘れたと思うのでひとつ追加

SUMPRODUCTを使うと式の確定するときに
Ctrl+Shift+Enterでなくて普通にEnterで確定できます

 =SUMPRODUCT((B2:B30="男")*(D2:D30="欠席"))

条件が増えた時には、*(E2:E30="条件3") と増やしていけばOKです。
複数条件の時に便利ですので序に覚えておきましょう。

以上です。
    • good
    • 0
この回答へのお礼

ありがとうございます。いろいろ知識が増えて、すごくうれしいです。エクセルってすごいですね。早く使いこなせるようになりたいです。

お礼日時:2005/04/16 12:02

いろいろ方法があります。



(1)作業用の列をつくる方法 その1

  E2 に、=IF(AND(B2="男",D2="欠席"),1,0) を入力。
  E2 を E3~E30 にコピー。
  E31 に、=SUM(E2:E30)

(2)作業用の列をつくる方法 その2

  E2 に、=B2&D2 を入力。
  E2 を E3~E30 にコピー。
  E31 に、=COUNTIF(E2:E30,"男欠席")

(3)データベース関数を使う方法

  B1 に 性別 と入力
  D1 に 出欠 と入力
  E1 に 性別 と入力
  F1 に 出欠 と入力
  E2 に 男 と入力
  F2 に 欠席 と入力
  E3 に、=DCOUNTA(B1:D30,1,E1:F2)

(4)配列数式を使う方法 その1

  任意のセルに、=SUM((B2:B30="男")*(D2:D30="欠席")) と入力して、《Shift + Ctrl + Enterを押す(ここがポイント)》。

(5)配列数式を使う方法 その2

  任意のセルに、=SUM(IF(B2:B30="男",IF(D2:D30="欠席",1,0),0)) と入力して、《Shift + Ctrl + Enterを押す(ここがポイント)》。
    • good
    • 0
この回答へのお礼

ありがとうございます。(5)を使わせていただくことにしました。いろいろな方法があるのですね。初心者としては、こんなふうにいろいろなやり方を教えていただけると助かります。

お礼日時:2005/04/16 11:59

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!


人気Q&Aランキング

おすすめ情報