エクセル関数（抽出）について（再）

先の質問が悪かったようですので再度質問致します。
　　　　Ａ　　Ｂ
　１　２１９　２
　２　　１３　９
　３　８２４　９
　４　１１８　６
　５　　　６　５
　６　３３３　９　
　７　　１９　６
　８　４６１　１
　９　　８３　６
１０　１７７　２

　ランダムに配列された上記表からＢ列の９と６に該当するＡ列の降順に以下のように抽出したいのです。
９　８２４
９　３３３
９　　１３
６　１１８
６　　８３
６　　１９
ちなみに９と６は自動で抽出できれば一番良いのですが、入力でも構いませんので御回答宜しくお願い致します。

No.1 回答者： 3612masa 回答日時： 2005/04/18 21:07

こんばんは、

マニュアルです。

数値を入力している状態で、Ａ列１行目にカーソルをあわせて、マウス左ボタンクック

(1)データ→オートフィルター
(2)オプションを選択
(3)１行目、左欄「6」右欄「と等しい」
(4)２行目、左欄「9」右欄「と等しい」

(5)データ→並び替え
(6)優先されるキー→Ａ列、降順

これでどうですか？

この回答への補足

すみません、関数でお願いします。

補足日時：2005/04/18 21:17

No.2 回答者： SAKURAMYLOVE 回答日時： 2005/04/18 21:09

並び替え結果で、Ａ列とＢ列が反対になっているのが気になりますが、普通の並び替えでできないでしょうか。

【手順】
(1)データをふくむセルを選択（A1:B10)
(2)メニューから、データ/並び替えで、最優先キーに列Ｂ、降順　選択
(3)２番目の優先キーに列Ａ　降順で選択しＯＫボタンクリック

Ｂ列の１～５は残りますが、下の行にきますのであとは消去すればよいでしょう。

この回答への補足

Ｂ列の任意の値に該当するＡ列全ての値を降順で抽出したいのです。

補足日時：2005/04/18 21:18

No.3 回答者： macchan1 回答日時： 2005/04/18 23:42

＞先の質問が悪かったようですので再度質問致します。

yukai4779さんの質問が無いようですが、どの質問の続きでしょうか？

＞ちなみに９と６は自動で抽出できれば一番良いのですが、入力でも構いませんので御回答宜しくお願い致します

ご希望の操作は関数だけでできそうなのですが、9とか6の数字はどのような基準で抽出するのでしょうか？（先の質問がわからないので具体的に回答のしようがありません）。

この回答への補足

No.1329344の質問です。
９と６はいわゆるコードNo.のようなものです。

補足日時：2005/04/19 21:40

No.4 回答者： macchan1 回答日時： 2005/04/18 23:53

検索条件が良く分からないのですが、例えば9を抽出したい場合は、以下の式をどこかに入力して下方向にオートフィル（コピー）します。

=IF(ROW(A1)>COUNTIF($B$1:$B$100,9),"",LARGE(($B$1:$B$100=9)*($A$1:$A$100),ROW(A1)))

必要に応じて9の部分をセル参照にして下さい。

No.5 ベストアンサー 回答者： DoragonFang 回答日時： 2005/04/19 03:22

>ちなみに９と６は自動で抽出できれば一番良いのですが

自動抽出という意味が分かりません。式に組み込んで、という意味でしょうか？　Ｂ列のどの番号を抽出するかをどこかのセルに入力して指定するのではなく、最初から９と６という風に決め打ちしているというコトでしょうか？

ともかく、一発で抽出する式を考えましたので、参考にして下さい。
とても、長いです。

=SUMPRODUCT(LARGE(($B$1:$B$10=IF(COUNTIF($B$1:$B$10,9)>=ROW(A1),9,6))*($A$1:$A$10),ROW(A1)-IF(COUNTIF($B$1:$B$10,9)>=ROW(A1),0,COUNTIF($B$1:$B$10,9))))

この式をコピーして、９と６の数の分だけ（あるいはそれ以上）下へコピーして下さい。
ご希望の数字列が出来ると思います。

範囲$B1$1:$B$10は必要に応じて変えてください。

この回答へのお礼

本当に一発ですね。素晴らしいです。ありがとうございました。

お礼日時：2005/04/19 21:43

No.6 回答者： AloneAgain 回答日時： 2005/04/19 20:58

こんばんは。

作業列を使う方法でもよろしければ、
以下の方法でできると思います。

作業列はどこでもいいのですが、
ここでは例として K列を使います。
目障りなら数式を入力後、非表示にしてください。

結果を D列とE列 に抽出します。
***
K1 に↓
------------------------------------------------------
=IF(OR(B1=9,B1=6),RANK(B1,B:B)*10000+RANK(A1,A:A),"")
------------------------------------------------------
A・B列のデータ最終行までコピーしてください。

◆B列の 9 と 6 は固定のようですので、K1 の数式で指定しています。
今後、抽出条件に変更がある場合は
他の数字に変更して 再度コピーしてください。

D1 に↓
-------------------------------------------------------
=IF(COUNT($K:$K)<ROW(A1),"",INDEX($A:$B,MATCH(SMALL($K:$K,ROW(A1)),$K:$K,0),3-COLUMN(A1)))
-------------------------------------------------------
↑の数式を右の E1にコピーして、
D1 と E1 の数式をともに、A・B列のデータ最終行までコピー
◆作業列に K列以外を使用する場合は、K をその列記号に変更してください。
***
D列に B列の、E列に A列の抽出結果が表示されると思います。

No.7 回答者： macchan1 回答日時： 2005/04/19 22:32

#4の回答の補足です。

=IF(ROW(A1)>COUNTIF($B$1:$B$100,9),"",LARGE(($B$1:$B$100=9)*($A$1:$A$100),ROW(A1)))

の数式を入力してCtrl+Shift+Enterで確定して配列数式にして下さい。