プロが教えるわが家の防犯対策術!

VBAの初心者です。というか使ったことがありません。
4つ以上の条件付き書式はVBAが必要になるようなので困惑中です。

下記の条件付き書式をVBA作りたいと思っています。
「1」を含む値の場合セルの背景を黄色に
「2」を含む値の場合セルの背景を緑色に
「3」を含む値の場合セルの背景を水色に
「4」を含む値の場合セルの背景を赤色に
例)
1北海道 → セルの背景を黄色
2山形 → セルの背景を緑

これを実現するVBAのコードを教えてください。
また、そのコードをどこに貼付ければいいのでしょうか?
まったくの初心者で申し訳ありません。

このQ&Aに関連する最新のQ&A

A 回答 (7件)

#1,#4のmerlionXXです。



先ほどの#4では、一旦1を選んでから、2~4を選びなおしても1としてカウントされたままでした。
訂正します。

Dim a As Integer

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Column <> 1 Then Exit Sub
If Selection.Count > 1 Then Exit Sub
a = Target.Value
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column <> 1 Then Exit Sub
If Selection.Count > 1 Then Exit Sub
x = Target.Value
c = 0
If a = 1 Then
If x Like "1*" Then c = 6
If x Like "2*" Then c = 4: Range("B1").Value = Range("B1").Value - 1
If x Like "3*" Then c = 34: Range("B1").Value = Range("B1").Value - 1
If x Like "4*" Then c = 3: Range("B1").Value = Range("B1").Value - 1
Else
If x Like "1*" Then c = 6: Range("B1").Value = Range("B1").Value + 1
If x Like "2*" Then c = 4
If x Like "3*" Then c = 34
If x Like "4*" Then c = 3
End If
Target.Interior.ColorIndex = c
End Sub
    • good
    • 0
この回答へのお礼

ありがとうございます!
これで目的が達成できそうです。
最後にお伺いしたいのですが、VBAを学ぶのにmerlionXXさんがおすすめする書籍がありましたら教えていただけないでしょうか。
全くの初心者向けでお願いします。

お礼日時:2006/12/14 08:28

> エクセル97対象と書いてあったのですが、2000を使っている自分でも大丈夫でしょうか?



わたしも2000です。
99.9%大丈夫ですよ。( ̄ー ̄)v
    • good
    • 0
この回答へのお礼

了解しました。
ありがとうございました。

お礼日時:2006/12/14 19:36

ao_さん、おはようございます。


merlionXXです。うまく行きそうでよかったですね。

> 全くの初心者向けでお願いします。

それなら、本じゃなくともここ↓なんてどうでしょう?

http://www.eastwest-net.co.jp/vba/vba.htm
    • good
    • 0
この回答へのお礼

ありがとうございます
参考にさせていただきます。
ただ、エクセル97対象と書いてあったのですが、2000を使っている自分でも大丈夫でしょうか?

お礼日時:2006/12/14 12:12

#1のmerlionXXです。



> 黄色に染まったセルの数をB1に返したいのですが

Range("B1").Value = Range("B1").Value + 1 とすればいいと思います。

なお、1~4のプルダウンメニューから選択なら「1~4」を含む値の場合ではなく、「1~4」で始まる値の場合でもいいですか?万一の誤作動を防ぐため、以下は「1~4」で始まる場合としてみました。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column <> 1 Then Exit Sub
If Selection.Count > 1 Then Exit Sub
x = Target.Value
c = 0
If x Like "1*" Then c = 6: Range("B1").Value = Range("B1").Value + 1
If x Like "2*" Then c = 4
If x Like "3*" Then c = 34
If x Like "4*" Then c = 3
Target.Interior.ColorIndex = c
End Sub
    • good
    • 0

#02です。

動きが一瞬止まるのは入力されたセル以外も検査しているからです。また#01さんへの補足も読み、着色するのはA列だけとし、色の付いたセルの個数も表示できるようにしてみました。

 AdrNum = Array("C1", "C2", "", "C4")
の行に各色のセル数を格納するアドレスを記述してください。(カウント不要な色の場合は””にしておけばよいです)

Private Sub Worksheet_Change(ByVal Target As Range)
Dim idx As Integer, lenCELL, cnt(4) As Long, adr As String
Dim r As Range, trg, clr, AdrNum
Application.ScreenUpdating = False
On Error GoTo end0
trg = Array("1", "2", "3", "4") '← 検索する文字
clr = Array(27, 10, 28, 3) '← 指定色番号(黄,緑,水色,赤)
AdrNum = Array("C1", "C2", "", "C4") '← 各色のセル数を書き込む場所

For Each r In Range(Cells(1, 1), Cells(Range("a65536").End(xlUp).Row, 1))
r.Interior.ColorIndex = xlNone
If Not r.HasFormula Then
For idx = 0 To 3
If Len(r.Value) > Len(Application.Substitute(r.Value, trg(idx), "")) Then
r.Interior.ColorIndex = clr(idx)
cnt(idx) = cnt(idx) + 1
Exit For
End If
Next idx
End If
Next r

Application.EnableEvents = False
For idx = 0 To 3
If AdrNum(idx) <> "" Then
ActiveSheet.Range(AdrNum(idx)) = cnt(idx)
End If
Next idx
end0:
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub
    • good
    • 0
この回答へのお礼

ありがとうございます。
色のカウントを好きなセルに返せるのが便利です。
使わせていただきます。

>入力されたセル以外も検査しているからです。
つまり、A列以外も検証しているということでしょうか?

お礼日時:2006/12/14 08:32

どのようなシートで使用するのか分からないし、すでにデータが入力されている可能性も考慮し、少し汎用的に作ったつもりです。

検索文字、色番号、適用セル範囲を変更しやすいようにしました。(ただし大きなシートだと実用的なレスポンスが得られないかもしれません)

シート名タブを右クリック→コードの表示で開く画面に以下のマクロを貼り付けてください。シートに戻りデータを変更すれば色が着くと思います。なお式が入力されたセルは処理対象外です。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim idx As Integer, lenCELL As Long, adr As String
Dim r As Range, trg, clr
 Application.ScreenUpdating = False

 trg = Array("1", "2", "3", "4") '← 検索する文字
 clr = Array(27, 10, 28, 3) '← 指定色番号(黄,緑,水色,赤)
 adr = "A1:B100" '← 着色対象のセル範囲

 For Each r In ActiveSheet.UsedRange
  If Not Application.Intersect(r, ActiveSheet.Range(adr)) Is Nothing Then
   r.Interior.ColorIndex = xlNone
   If Not r.HasFormula Then
    For idx = 0 To 3
     If Len(r.Value) > Len(Application.Substitute(r.Value, trg(idx), "")) Then
      r.Interior.ColorIndex = clr(idx)
      Exit For
     End If
    Next idx
   End If
  End If
 Next r
 Application.ScreenUpdating = True
End Sub

この回答への補足

zap35さんありがとうございます。
確かに理想の結果に至りました。
私の質問が悪く申し訳ありません。

使い方は、A列に入力規則で1~4のプルダウンメニューを作り、その値によってセルの色を変える予定です。頂いたコードで、一瞬動作が固まるような感じは既にデータが入力されていることを考慮していただいたためでしょうか。
データはこれから新たに入力する予定です。

補足日時:2006/12/13 11:20
    • good
    • 0

条件付き書式の代わりにということであれば、設定するセルは決まっているんですね?


仮にA1セルに設定する場合の例です。

1.シートのタブを右クリックし、「コードの表示」を選択。
2.出てきたVisualBasicEditor(白い部分)に下記のコードをコピペ。

'*****ここから下をコピペ*****

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub
x = Target.Value
c = 0
If x Like "*1*" Then c = 6
If x Like "*2*" Then c = 4
If x Like "*3*" Then c = 34
If x Like "*4*" Then c = 3
Target.Interior.ColorIndex = c
End Sub

'*****ここより上までをコピペ*****

3.Alt+F11キーでワークシートへもどります。
    • good
    • 0
この回答へのお礼

merlionXXさんありがとうございます。
ちゃんと動きました。感動です。

それで設定するセルをA1でサンプルを作っていただきましたが、これをA列にするにはどうすればいいのでしょうか。
また、そのA列の中で四種類の色が存在する中、黄色に染まったセルの数をB1に返したいのですがそんなことって可能なのでしょうか?
よろしくお願いします。

お礼日時:2006/12/13 10:51

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人が検索しているワード


このカテゴリの人気Q&Aランキング