人に聞けない痔の悩み、これでスッキリ >>

1つのファイルを選択後、
そのファイルを開いてある操作をし、閉じる。
その後自動的に、同一フォルダ内のファイルを開いて同様の操作をし、閉じる。
これをフォルダ内のファイル全てに対して行う、
というマクロを組みたいです。

例えば、
フォルダAに、File1.csv, File2.csv, File3.csv, File4.csv の4ファイルがある時、
File3.csvを選んで操作を実行(csvファイル内のセルA4の値を、マクロを実行したExcelファイルにコピー)。
実行完了後、File3.csvは閉じる。
続けて、File1,File2,File4についても、
開く→コピーする→閉じる、を繰り返す。
フォルダ内全てのファイルに対して実行したら終了。
ファイル名は、常にFile+数字.csvではありませんが、拡張子は常にCSVです。

素人考えでは、フォルダ内のファイルの数と名前を取得し、ループで回せばいいと思うのですが、
「フォルダ内のファイルの数と名前を取得」する関数でもあるのでしょうか?
他に何か楽な方法でもあれば、教えてください。

このQ&Aに関連する最新のQ&A

A 回答 (3件)

Dir関数でやってみました。


このマクロを記述したエクセルのBOOKと同じフォルダ内のすべてのcsvファイルを開き、A4の値を取得します。

Sub test01()

Dim MyFile As String, MyPath As String
Dim i As Long
Dim wb As Object

MyPath = ThisWorkbook.Path & "\" '自分のパスを取得
MyFile = Dir(MyPath & "*.csv", vbNormal) 'パス内のcsvファイル

Do Until MyFile = "" '対象ファイルがなくなるまで
Set wb = Workbooks.Open(MyPath & "\" & MyFile) '選択したファイルを開く
i = i + 1
ThisWorkbook.Sheets("Sheet1").Cells(i, 1).Value = wb.Sheets(1).Range("A4").Value '転記
wb.Close (False) '選択したファイルを閉じる

MyFile = Dir '次のファイルを検索
Set wb = Nothing

Loop '繰り返し

End Sub
    • good
    • 0
この回答へのお礼

回答ありがとうございます。
>Workbooks.Open(MyPath & "\" & MyFile)
など、今まで知らなかった書き方を見ることができ、大変参考になります。
目的のマクロは、無事組むことができました。

お礼日時:2007/04/06 17:41

FileSystemObjectを使うのであれば、こんな感じかな。


Microsoft Scripting Runtime を参照設定してください。

Public Sub Proc1()
Dim fso As New FileSystemObject
Dim fo As Folder
Dim fi As File
Dim wbk As Workbook

Set fo = fso.GetFolder("~フォルダ名~")

For Each fi In fo.Files

Set wbk = Workbooks.Open(fi.Name)

    (中のロジックはご自分で組み立ててください)

Set wbk = Nothing
Next fi

Set fi = Nothing
Set fo = Nothing
Set fso = Nothing
End Sub

お役に立てれば幸いです。
    • good
    • 0
この回答へのお礼

回答ありがとうございます。
無事動作しました。
しましたが、挙げていただいたコードにはまだ私にはわからない部分もあるので、
今後調べていこうと思います。

お礼日時:2007/04/06 17:39

DIR関数やFileSystemObjectなどいろいろありますが。



ブックマークしておくと良いサイトがあります。
いつも利用させてもらってる「OfficeTANAKA」さんのページ。サンプル満載です。

リンクフリーの記述があるので、リンク貼ります。
http://www.officetanaka.net/

ここらあたりか?
http://www.officetanaka.net/excel/vba/file/file0 …
    • good
    • 0
この回答へのお礼

回答ありがとうござます。
サンプルや解説のページはいくつかブックマークしておりましたが、
こちらは知りませんでした。
参考にさせていただきます。

お礼日時:2007/04/06 17:36

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

Qフォルダの中にあるファイルの数を数えたい!

宜しくお願いいたします。

サーバー上のフォルダに、ワードのファイルがたくさん
あるのですが、これを簡単に数える方法は内でしょうか?

ファイルが数百個あるので一つ一つ数えるのは時間がかかり・・・。

教えてください。

宜しくお願いします

Aベストアンサー

フォルダに分かれているならフォルダを右クリックしてプロパティを見れば分かります。
フォルダ無しでファイルだけの場合はすべてを選択すればエクスプローラのステータスバーに表示されます。
ステータスバーの表示方法は
http://121ware.com/qasearch/1007/app/nec.jsp?003539

Qexcel vbaのdir関数で正しいファイル数が取得できません

excel vbaの初心者です
現在、フォルダ内にあるファイルの数をカウントするために、dir関数を使用してプログラミングしています。
このプログラムで問題が発生していて困っています
1.マクロを起動して、指定したフォルダ内のファイル数をカウントする
2.フォルダ内のファイルを増減させる
3.再度、マクロを実行してもファイル数は1.で起動したときのファイル数のままで、2.で変更した後のファイル数になりません。
このため、マクロを再実行しても正しいファイル数が取得できずに困っています。
もしかすると、マクロ実行前にメモリのガーベージコレクションみたいなことをしないといけないのかもしれないのですが、なんせvbaは初心者のためどうすればいいのか途方にくれています。

業務で使いたいのですが、小さい会社で周りには聞くことのできる人もいないので、どなたかご回答をよろしくお願いいたします。

Aベストアンサー

下記で問題なく動作しますよ?
1.マクロの入ったExcelを起動し、マクロでファイル数確認
2.Excelを閉じずに対象フォルダにファイルを追加
3.再度マクロを実行しファイル数を確認 → 結果は変わっている。
-------
Sub test()
Dim cnt As Long: cnt = 0
Dim file As String

file = Dir("C:\foo\*")
Do While file <> ""
cnt = cnt + 1
file = Dir()
Loop
MsgBox cnt
End Sub

QEXCEL VBA で現在開いているブックのファイル名を取得する方法

EXCEL2003 VBAで業務を簡素化するために、現在開いているブックのファイル名を取得する方法が分かりません。
作業手順をマクロを使って処理していますが、オリジナルのワークブックをファイル名を変えて保存し、以後、このワークブックを読み込んで使用しています。
このときのVBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり、以後の業務に使用できません。
常にファイル名を取得出来るVBAをどなたか、教えて下さい。

Aベストアンサー

>現在開いているブックのファイル名
 ちょっと曖昧な表現かなぁという気もいたしますが、VBAが書いてあるブックのブック名は
ThisWorkbook.Name
で、現在 "アクティブにして" 操作対象になっているブックの名前は
ActiveWorkbook.Name
ですね。

 しかし、
>VBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり
というような文脈からすると、
ThisWorkbook.Name
の方ですかね。

Qエクセル マクロで指定フォルダを開く

エクセルにて
指定フォルダを開く、マクロがあれば教えて頂けないでしょうか。
よろしくお願いいたします。

Aベストアンサー

こんにちは。

こういうものですか?
開くフォルダを変えたいときは targ に与えるパスを変更します。

Sub OpenFolders()
Dim targ As String
targ = "C:\"
Shell "C:\Windows\Explorer.exe " & targ, vbNormalFocus
End Sub

Qフォルダ内の全てのBookに同じ処理を繰り返す

フォルダ内にエクセルファイルが約3,000個あります。
この全てのBookに同じ処理をしたいのですが、マクロで繰り返す方法がわからないので教えて下さい。
処理をする内容は簡単なもので、マクロで作りました。

・ 各Bookには1つのシートしか存在せず、シート名は重要ではないので全て「Sheet1」になっています。
・ 各Bookのデータの配置や表形式は同じです。
・ レコードの行数がBookによって異なります。

処理の内容をマクロで作るところまではできましたが、知識がないためタイムアウトです。

ご教示宜しくお願い致します。

Aベストアンサー

だいたいこんな流れで。

sub macro1()
 dim myPath as string
 dim myFile as string

 mypath = "C:\test\"

’指定フォルダのブックを順繰り拾う
 myfile = dir(mypath & "*.xls*")
 do until myfile = ""

 ’ブックを開いて処理を行い保存して閉じる
  workbooks.open mypath & myfile
  activesheet.range("A1") = "DONE"
  activeworkbook.close true

  myfile = dir()
 loop
end sub


必要に応じて
・画面の表示を抑制する
・再計算を手動にする
といった手管を追加して高速化を図ります。

QEXCELファイルのカレントフォルダを取得するには?

EXCELファイルのカレントフォルダを取得するには?

C:\経理\予算.xls

D:\2005年度\予算.xls

EXCEL97ファイルがあります。

VBAで
  カレントフォルダ名
(C:\経理\,D:\2005年度\)
を取得する事は可能でしょうか?

CURDIRでは上手い方法が見つかりませんでした。

Aベストアンサー

こんばんは。
Excel97 でも、同じですね。以下で試してみてください。

Sub test()
'このブックのパス
a = ThisWorkbook.Path
'アクティブブックのパス
b = ActiveWorkbook.Path
'Excelで設定されたデフォルトパス
c = Application.DefaultFilePath
'カレントディレクトリ
d = CurDir
MsgBox "このブックのパス   : " & a & Chr(13) & _
   "アクティブブックのパス: " & b & Chr(13) & _
   "デフォルトパス    : " & c & Chr(13) & _
   "カレントディレクトリ : " & d & Chr(13)
End Sub

QEXCEL VBAで計算値を四捨五入、切り上げ、切捨てする方法

ネットで探してみたのですが、計算結果を四捨五入して特定のセルを
返すにはどうしたらいいのでしょうか?

Sub hokangosa()

Dim ZPS As Double
Dim ZPOS As Double
Dim DMN As Double
MsgBox (" >>> 補間誤差自動計算 <<< ")
MsgBox (" >>> 初期値入力します <<< ")
ZPS = InputBox(">>> ステップを入力してください<<<")
ZPOS = Sheet1.Cells(22, 4).Value
DMN = ZPOS / ZPS
Sheet1.Cells(23, 6).Value = DMN
End Sub

ここでDMNの値を四捨五入したいです。

またこれとは別に切上げ、切捨ても教えていただけるとありがたいです。

Aベストアンサー

DMN = Application.WorksheetFunction.Round(ZPOS / ZPS, 0)
で、四捨五入
DMN = Application.RoundDown(ZPOS / ZPS, 0)
で切り捨て
DMN = Application.RoundUp(ZPOS / ZPS, 0)
で切り上げです。

引数で、対象桁を変更できます。

QEXCEL VBAマクロ作成で、他のEXCELからデータを取り込みたい

メインプログラム(EXCEL VBA)より、
他のフォルダーにあるEXCELの項目の内容を取り込みたいです。
たとえば他のフォルダーのEXCELのRange("A2:A3").ValueをメインプログラムのRange("C2:C3").Valueにセットしたい時です。

・コマンドボタン押したら、どこのEXCELから取り込むかのポップアップ(?)は、表示はできてます。
・作業者が選んだパスとブックもMsgBoxで表示できてるので、もらう相手の場所も取得できてます。

・となると次はOPEN,INPUTですか?
テキストデータの取り込みですと、Inputでそのバッファを定義してるのですが、なんか違うような。。。

よろしくお願いします!

Aベストアンサー

私がやる方法です。

Dim writeSheet As Worksheet ' 自分自身の書き出し先シート
Set writeSheet = ThisWorkbook.Worksheets(1) ' Sheet1 を参照

Dim readBook As Workbook ' 相手ブック
Set readBook = Workbooks.Open(filename) ' 相手ブックを開いて参照
Dim readSheet As WorkSheet ' 相手シート
Set readSheet = readBook.Worksheets("sheetName") ' 相手シートを参照
' または Set readSheet = readBook.Worksheets(sheetIndex)

' 例えば
writeSheet.Cells(1, 1).Value = readSheet.Cells(2, 2).Value ' 相手シートの B2 の値を自分自身の A1 に書き込む

readBook.Close False ' 相手ブックを閉じる
Set readSheet = Nothing
Set readBook = Nothing

私がやる方法です。

Dim writeSheet As Worksheet ' 自分自身の書き出し先シート
Set writeSheet = ThisWorkbook.Worksheets(1) ' Sheet1 を参照

Dim readBook As Workbook ' 相手ブック
Set readBook = Workbooks.Open(filename) ' 相手ブックを開いて参照
Dim readSheet As WorkSheet ' 相手シート
Set readSheet = readBook.Worksheets("sheetName") ' 相手シートを参照
' または Set readSheet = readBook.Worksheets(sheetIndex)

' 例えば
writeSheet.Cells(1, 1).Value = readSheet.Ce...続きを読む

QEXCELマクロで上書きメッセージ無しで保存する方法

EXCELマクロで上書きメッセージ無しで保存する方法をお願いします
ActiveWorkbook.SaveAs "C:\Documents andSettings\Nakatani\MyDocuments\Book1.xls"
の様にするとすでにファイルがある場合上書きメッセージが出ます
メッセージを出さずに上書きするプログラミングを教えて下さい
宜しくお願いします

Aベストアンサー

Application.DisplayAlerts = False
ActiveWorkbook.SaveAs "C:\Documents andSettings\Nakatani\MyDocuments\Book1.xls"
Application.DisplayAlerts = True

Q【Excel VBA】マクロでExcel自体を終了させたい

環境:WindowsXP、Excel2003

マクロでエクセルを終了(ブックを閉じて、アプリケーション自体も終了)させたいのですが、以下のコードではアプリケーションが閉じてくれません。

ThisWorkbook.Close
ExcObj.Quit
Application.Quit

どこか悪いところはありますでしょうか?

よろしくお願いします。

Aベストアンサー

普通に考えれば質問者のコードで上手くいきそうですが
hana-hana3さんの回答にもあるようにThisWorkBook.Closeでコード終了となりますので
Application.QuitをThisWorkBook.Closeの前にもってこないといけません。
Application.Quitはそれがあるプロシージャのコードが全て終わるまで
その実行を保留するちょと特別動作をします。

'-------------------------------------
 Application.Quit
 ThisWorkbook.Close
'-------------------------------------
 
 


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング