外出自粛中でも楽しく過ごす!QAまとめ>>

他のブックからシートを取込む(シート名を変更して)VBAがわからないのですが、どなたか詳しい方がいましたら、ご教授下さいませ。

以下を例として、ご回答いただけると幸いです。
よろしくお願いします。

----------------------------------
次の3つのブックが存在するとします。
a.xls
b.xls
c.xls

a.xlsにはシートが1つだけあり、シート名は"sheet1"です。
b.xlsにはシートが1つだけあり、シート名は"sheet1"です。
c.xlsにはシートが3つあり、シート名は"sheet1"、"sheet2"、"sheet3"です。

a.xlsにVBAマクロを作り、a.xls上で実行させて、
a.xlsの"sheet1"は残したまま、
b.xlsの"sheet1"のシート名を"sheet1-b"に変更して、
a.xlsのシートとして取込み、
同様に今度は、
a.xlsの"sheet1"、"sheet1-b"は残したまま、
c.xlsの"sheet1"のシート名を"sheet1-c"に変更し、
c.xlsの"sheet2"のシート名を"sheet2-c"に変更し、
c.xlsの"sheet3"のシート名を"sheet3-c"に変更し、
a.xlsのシートとして取込み、
最終的に、a.xlsには、
"sheet1"、"sheet1-b"、"sheet1-c"、"sheet2-c"、"sheet3-c"
の、5つのシートが存在するようにしたいのです。
(各シート上のデータは、a.xlsの各シートとしてすべて移行されている)
----------------------------------

このQ&Aに関連する最新のQ&A

A 回答 (3件)

#1です。



お問合せの内容は複雑な処理で、ある程度のスキルを要求されると思います。
下記サンプルはマクロを含む A.xls と同じフォルダ内のExcelファイルに対して処理を行い、オープン判定とコピー判定をする例です。
最低限のエラー処理しかしていません。
マクロで開いたブックを実行後に閉じる処理等もしていませんし、先の質問にあったシート名変更コピーとも組み合わせてはいませんので、必要ならばご自身で考えて見て下さい。

'-------------------------------------------------------------
Sub Test()
Dim myPath As String, myName As String
Dim twb As Workbook, ws As Worksheet
With ThisWorkbook
myPath = .Path & "\"
myName = Dir(myPath & "*.xls", vbNormal)
Do While myName <> ""
 If myName <> .Name Then
   Set twb = OpenBook(myPath & myName)
   If Not twb Is Nothing Then
    For Each ws In twb.Worksheets
      If SheetCopyFLG(ws) Then
       ws.Copy after:=.Worksheets(.Worksheets.Count)
      End If
    Next ws
   End If
 End If
 myName = Dir
Loop
End With
End Sub

'-------------------------------------------------------------
Function OpenBook(myName As String) As Workbook
Dim wb As Workbook
 Set OpenBook = Nothing
 For Each wb In Workbooks
   If LCase(wb.FullName) = LCase(myName) Then
     Set OpenBook = wb
     Exit For
   End If
 Next wb
 If OpenBook Is Nothing Then
   On Error Resume Next
   Set OpenBook = Workbooks.Open(myName)
 End If
End Function

'-------------------------------------------------------------
Function SheetCopyFLG(tws As Worksheet) As Boolean
Dim ws As Worksheet
SheetCopyFLG = True
For Each ws In ThisWorkbook.Worksheets
If tws.Name = ws.Name Then
  If MsgBox(tws.Name & "は存在します。コピーしますか?", _
    vbYesNo + vbExclamation, "SheetCopy") <> vbYes Then
   SheetCopyFLG = False
  End If
  Exit Function
End If
Next ws
End Function
    • good
    • 0
この回答へのお礼

複雑な処理になるにもかかわらず、ご回答ありがとうございました。
前回分と今回分を元に、改良して用いたいと思います。
どうもありがとうございました!

お礼日時:2007/05/28 13:57

順を追って処理を作成していくと、以下のようになるかと思います。


---
Dim bookB As Worksheet, bookC As Worksheet
'対象ブックを開く
Set bookB = Workbooks.Open(ThisWorkbook.Path & "\b.xls")
Set bookC = Workbooks.Open(ThisWorkbook.Path & "\c.xls")
'対象シートをa.xlsにコピー
bookB.Sheets("sheet1").Copy After:=ThisWorkbook.Sheets(1)
bookC.Sheets(Array("sheet1", "sheet2", "sheet3")).Copy After:=ThisWorkbook.Sheets(2)
'シート名変更
With ThisWorkbook
.Sheets(2).Name = "sheet1-b"
.Sheets(3).Name = "sheet1-c"
.Sheets(4).Name = "sheet2-c"
.Sheets(5).Name = "sheet3-c"
End With
'対象ブックを閉じる
bookB.Close
bookC.Close
---
ブック名やシート名、挿入位置等は適宜変更してみてください。
    • good
    • 4
この回答へのお礼

ありがとうございます。
いただいたコードも参考にしてみたいと思います。
どうもありがとうございました!

お礼日時:2007/05/28 14:01

a.xls、b.xls、c.xls を同一ウィンドウで開いた状態にして実行します。


細かい仕様やエラー処理などの調整が必要だと思いますが、、、

Sub Test()
Dim wb As Workbook, ws As Worksheet, s As String
For Each wb In Workbooks
 If Not wb Is ThisWorkbook Then
   s = wb.Name
   If InStr(1, LCase(s), ".xls") > 0 Then
    s = Left(s, Len(s) - 4)
   End If
   For Each ws In wb.Worksheets
    On Error Resume Next
    ws.Name = ws.Name & "-" & s
    ws.Copy after:=ThisWorkbook.Worksheets _
           (ThisWorkbook.Worksheets.Count)
   Next ws
  End If
Next wb
End Sub

この回答への補足

ご回答どうもありがとうございました!!
誠に恐縮なのですが、もう二点、教えていただいてもよろしいでしょうか?

<(1)>
シート名を変更せずにコピーしたい場合、
ws.Name = ws.Name & "-" & s
をコメントにすれば良いのかと思いますが、
その場合、元のブック"a.xls"に同名のシート(例えば"Sheet1")があった場合、自動的に"Sheet1 (2)"として無条件にコピーされるようです。
もし、同名のシートがあった場合、コピーするかどうかをいったんMsgBoxで警告させ、OKボタンを押した場合のみ、"Sheet1 (2)"としてコピーさせるようにしたいです。

<(2)>
同一ウィンドウで各ブックを開いた状態で実行しても、
元となる"a.xls"のみ開いて、他のブックは閉じている状態で実行しても、同じように処理できるようにしたいです。
(この場合、使用する各ブックは、すべて同フォルダ内に存在するとして)

以上、ご教授いただけると幸いです。
よろしくお願い致します。

補足日時:2007/05/25 11:10
    • good
    • 0

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

QEXCEL VBAマクロ作成で、他のEXCELからデータを取り込みたい

メインプログラム(EXCEL VBA)より、
他のフォルダーにあるEXCELの項目の内容を取り込みたいです。
たとえば他のフォルダーのEXCELのRange("A2:A3").ValueをメインプログラムのRange("C2:C3").Valueにセットしたい時です。

・コマンドボタン押したら、どこのEXCELから取り込むかのポップアップ(?)は、表示はできてます。
・作業者が選んだパスとブックもMsgBoxで表示できてるので、もらう相手の場所も取得できてます。

・となると次はOPEN,INPUTですか?
テキストデータの取り込みですと、Inputでそのバッファを定義してるのですが、なんか違うような。。。

よろしくお願いします!

Aベストアンサー

私がやる方法です。

Dim writeSheet As Worksheet ' 自分自身の書き出し先シート
Set writeSheet = ThisWorkbook.Worksheets(1) ' Sheet1 を参照

Dim readBook As Workbook ' 相手ブック
Set readBook = Workbooks.Open(filename) ' 相手ブックを開いて参照
Dim readSheet As WorkSheet ' 相手シート
Set readSheet = readBook.Worksheets("sheetName") ' 相手シートを参照
' または Set readSheet = readBook.Worksheets(sheetIndex)

' 例えば
writeSheet.Cells(1, 1).Value = readSheet.Cells(2, 2).Value ' 相手シートの B2 の値を自分自身の A1 に書き込む

readBook.Close False ' 相手ブックを閉じる
Set readSheet = Nothing
Set readBook = Nothing

私がやる方法です。

Dim writeSheet As Worksheet ' 自分自身の書き出し先シート
Set writeSheet = ThisWorkbook.Worksheets(1) ' Sheet1 を参照

Dim readBook As Workbook ' 相手ブック
Set readBook = Workbooks.Open(filename) ' 相手ブックを開いて参照
Dim readSheet As WorkSheet ' 相手シート
Set readSheet = readBook.Worksheets("sheetName") ' 相手シートを参照
' または Set readSheet = readBook.Worksheets(sheetIndex)

' 例えば
writeSheet.Cells(1, 1).Value = readSheet.Ce...続きを読む

QExcel VBA別ブックのシートをコピーするには

Excel2010のVBAで別ブックのシートをコピーしてくる方法

Excelファイル(C:\test\BOOK2.xls)のシート名が
TESTというシートを自分のExcelファイル(C:\doc\BOOK1.xls)に
コピーするにはどのように記述すればよいのでしょうか。

・コピー先:自分のExcelファイル(C:\doc\BOOK1.xls)
 VBAのコードがあるファイルです
・コピー元:C:\test\BOOK2.xlsのTESTシート
 なお、TESTシートを持つ同じ名前(BOOK2.xls)のファイルが
 別フォルダにもあります
 
Workbooks( )の引数にファイル名(BOOK2.xls)は指定できるのですが、
フルパス名(C:\test\BOOK2.xls)で指定できないので困っています。

Aベストアンサー

http://www016.upp.so-net.ne.jp/cheetah/xlvba/Excel/Worksheet/Worksheet04.html に書いてある方法はどうでしょうか。

Set wb1 = Application.Workbooks.Add
Set wb2 = Application.Workbooks.Add

のところを

Set wb1 = Application.Workbooks.Open(Filename:="ファイル名")
Set wb1 = Application.Workbooks.Open(Filename:="ファイル名")

のように書き換えれば出来ると思います。

参考URL:http://www016.upp.so-net.ne.jp/cheetah/xlvba/Excel/Worksheet/Worksheet04.html

QWorkBooksをオープンさせずにシートにコピーしたい【EXCEL VBA】

よろしくお願いします。
今あるブックにあるシートを別のブックにコピーしたいのですが、今考えているのは

ここから////////
'ブックを開く
Workbooks.Open コピー元のブックのパス
'シートをコピー
Worksheets.Item(コピーするシート名).Copy _
after:=Workbooks(コピー先のブック名).Sheets(1)

'ブックを閉じる
Application.DisplayAlerts = False
Workbooks.Item(コピー元のブック名)Close True
Application.DisplayAlerts = True
ここまで////

なのですが、コピーものとのブックが複数ある時、画面がチラチラしてしまいます。ブックをオープンさせずにシートを他ブックにコピーさせる方法ってないでしょうか。
ご存知の方がいらっしゃいましたら、ご教授お願いします。

Aベストアンサー

画面のチラツキを押さえたいだけなら、画面の更新をやめればいいだけじゃないでしょうか?

ブックを開く前に
Application.ScreenUpdating = False
ブック閉じてから
Application.ScreenUpdating = True

QExcel 2007 マクロ 別ブックのシートをコピーする方法

Excel 2007 マクロ 別ブックのシートをコピーする方法

別ブックのシートをコピーして
アクティブなブックのシートにコピーしたいと思います。

下記マクロを作成しました。

貼り付ける際に、クリップボードに保存するかどうか
聞かれるメッセージが表示されてうまくいきません。

またもっとシンプルな書き方があればアドバイスお願いします。


Sub 取り込み()
Dim wb As Workbook
Set wb = Workbooks.Open("\")
Sheets("Sheet1").Select
Cells.Select
Selection.Copy
ThisWorkbook.Activate
ThisWorkbook.Sheets("特定").Select
ActiveSheet.Cells(1, 1).Select
ActiveSheet.Paste
wb.Close
End Sub

Aベストアンサー

No1 merlionXXです。
さっきのでも大丈夫だとは思いますが、念のため修正しておきます。

Sub 取り込み03()
  Dim wb As Workbook
  Set wb = Workbooks.Open("\") '省略
  wb.Sheets("Sheet1").Cells.Copy ThisWorkbook.Sheets("特定").Cells
  wb.Close (False)
End Sub

QEXCEL VBA で現在開いているブックのファイル名を取得する方法

EXCEL2003 VBAで業務を簡素化するために、現在開いているブックのファイル名を取得する方法が分かりません。
作業手順をマクロを使って処理していますが、オリジナルのワークブックをファイル名を変えて保存し、以後、このワークブックを読み込んで使用しています。
このときのVBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり、以後の業務に使用できません。
常にファイル名を取得出来るVBAをどなたか、教えて下さい。

Aベストアンサー

>現在開いているブックのファイル名
 ちょっと曖昧な表現かなぁという気もいたしますが、VBAが書いてあるブックのブック名は
ThisWorkbook.Name
で、現在 "アクティブにして" 操作対象になっているブックの名前は
ActiveWorkbook.Name
ですね。

 しかし、
>VBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり
というような文脈からすると、
ThisWorkbook.Name
の方ですかね。

Qマクロで別ファイルのシートコピーして、元ファイルに貼り付けを行なうには

VBA初心者です。こんなマクロを作りたいのですが・・・
(1) Aファイルのαシートから操作する。
(2) Bファイルを開いて、βシートの一部をコピー
(3) Bファイルを閉じる(保存なし・各種アラートなし)
(4) Aファイルに再び戻り、αシートに貼り付けする

といったものなのですが、
(2)まではできたのですが、(3)からうまくいかず、勝手に新規ファイルにβシートがコピーされてしまいます。
是非ご教授ください。

Aベストアンサー

A No.1とかぶっちゃいましたが、サービスでコード付ということで投稿させていただきます。
(1) Aファイル(マクロを記述してある)から操作する。
(2) Bファイルを開く
(3) Bファイルのβシートの一部をコピーして、Aファイルのαシートに貼り付けする
(4) Bファイルを閉じる(保存なし・各種アラートなし)
というワークフローにすれば、
(3)は、
Sub test()
Workbooks("Bファイル.xls").Sheets("β").Range("A1:B4").Copy ThisWorkbook.Sheets("α").Range("a1")
End Sub
で実現できます。(複写先範囲は適当にいじって下さい)

QExel VBA 別ブックから該当データを検索し、必要なデータを取得する方法について

部品表というブックがあります
A列に商品名、B列に商品番号が入力してあります。C列のコードは未入力です。
A列     B列     C列      
商品名  商品番号  コード
モータ  U-1325-L  
ホルダ  R-134256

また、コード一覧表という別のブックには、A列に商品番号と、B列にコードが、何千件も入力されています。

やりたいことは
部品表のC列のコード欄に、コード一覧表ブックから商品番号と一致するコードを貼り付けしたいのです。

部品表は、何百種類もありますので、関数ではなく、マクロで処理を希望します。

自分では、部品表の商品番号をコピーして、コード一覧表で検索し、検索結果の右隣のセル(B列のコード)の値を部品表のC列に貼り付ければよいかと思い、書いてみたんですが…

Sub 別ブックから貼り付ける()
  Dim 検索する As Long
Windows("部品表.xls").Activate
検索する = cells(i,2).Value
Windows("コード一覧表.xls").Activate
ActiveWindow.SmallScroll Down:=-3
Selection.AutoFilter Field:=3, Criteria1:="=検索する", Operator:= xlAnd

と、してみたものの、検索しても、その検索結果の隣のセルのコードをどうやって取得すればいいのかが、わかりませんでした。

基本事項は本で学びましたが、呪文のようなコードはよく理解できません。懸命にネットで検索して、訳して理解する努力をしてはいますが。

どうぞよろしくお願いします。

部品表というブックがあります
A列に商品名、B列に商品番号が入力してあります。C列のコードは未入力です。
A列     B列     C列      
商品名  商品番号  コード
モータ  U-1325-L  
ホルダ  R-134256

また、コード一覧表という別のブックには、A列に商品番号と、B列にコードが、何千件も入力されています。

やりたいことは
部品表のC列のコード欄に、コード一覧表ブックから商品番号と一致するコードを貼り付けしたいのです。

部品表は、何百種類もありますので、関数...続きを読む

Aベストアンサー

こんにちは。
とりあえず実用性も踏まえました。
メインの動作はワークシート関数のVLOOKUPをVBA上で使用していますので理解はしやすいかと思います。
また、質問文から察するに「部品表.xls」と「コード一覧表.xls」の両方を開いて処理されていますが「コード一覧表.xls」はプログラム内で開いて閉じているので実行するときは「コード一覧表.xls」は閉じて置いてください。
Option Explicit
Sub Sample()
 Application.ScreenUpdating = False
 Dim I As Long
 Dim xlBook
 Set xlBook = Workbooks.Open("C:\★★\コード一覧表.xls") '★要変更★
 I = 2
 Do While Range("A" & I).Value <> ""
  ThisWorkbook.Worksheets("Sheet1").Range("C" & I).Value = Application.VLookup(ThisWorkbook.Worksheets("Sheet1").Range("B" & I).Value, xlBook.Worksheets("Sheet1").Range("A2:B65535"), 2, 0)
  I = I + 1
 Loop
 xlBook.Close
 Application.ScreenUpdating = True
 MsgBox ("完了")
End Sub

こんにちは。
とりあえず実用性も踏まえました。
メインの動作はワークシート関数のVLOOKUPをVBA上で使用していますので理解はしやすいかと思います。
また、質問文から察するに「部品表.xls」と「コード一覧表.xls」の両方を開いて処理されていますが「コード一覧表.xls」はプログラム内で開いて閉じているので実行するときは「コード一覧表.xls」は閉じて置いてください。
Option Explicit
Sub Sample()
 Application.ScreenUpdating = False
 Dim I As Long
 Dim xlBook
 Set xlBook = Workbooks....続きを読む

QExcel VBAで複数シートをコピーする

Excel VBAで複数のシートを新たらしいブックにコピーする方法が分かりません。

一応、Selectで全てのシートを選択し
コピーする方法は分かるのですが
出来ればSelectなどの画面遷移をプログラム内に含ませたくありません

シートは n件存在します。
ご存知の方がおられましたら
ぜひ、教えて頂けないでしょうか?

Aベストアンサー

すいません、勉強不足でした。
ただ単純に「全てのシートを選択」し「新規ファイルにコピー」という動作であれば、
sheets.Select
sheets.Copy
だけでできました。

Q別のシートから値を取得するとき

Worksheets("シート名").Activate
上記のを行ってから別シートの値を取得するのですが、
この処理を行うと指定したシートへ強制的にとんでしまいます。。。

※イメージ
For ~ To ~
  Worksheets("シートA").Activate
  シートAの値取得
       :
  Worksheets("シートB").Activate
  シートBの値取得
Next

このイメージ処理を行うとものすごい勢いで画面がチカチカします。。。
シートを変えずに他のシートから値を取得する方法はないのでしょうか。
教えてください!

Aベストアンサー

Worksheets("シートA").Range("A1")

みたいな感じでできませんか?

QExcel VBA 複数シートを別ファイルにコピーして保存

Excel VBAはまだ初心者なので、よくわかっていないのですが、複数シートを別ファイルにコピーして保存したいと思っております。

下記は、一番左のシートだけをB1に書かれ値で別ファイルとして保存できるようなものをつくってみました。ここから、左から1番目と2番目だけをコピーして、同じようにファイル名を指定して保存したいと考えていますが、全くうまくいかず・・・。

お手数ですが、どこを修正すべきなのかをおしえていただけますでしょうか。

よろしくお願いいたします。

Sub SheetSave()

Dim xSheet As Worksheet
Dim myFile As String
Dim myName As String

Set xSheet = ActiveSheet

'一番左のファイルのコピー
ThisWorkbook.Worksheets(1).Copy after:=ThisWorkbook.Worksheets(1)

myFile = ThisWorkbook.Path & "\" & xSheet.Range("B1").Value & ".xlsx"
Application.DisplayAlerts = False
ActiveSheet.SaveAs fileName:=myFile
Application.Dialogs(xlDialogSaveAs).Show
Application.DisplayAlerts = True
ActiveWorkbook.Close

End Sub

Excel VBAはまだ初心者なので、よくわかっていないのですが、複数シートを別ファイルにコピーして保存したいと思っております。

下記は、一番左のシートだけをB1に書かれ値で別ファイルとして保存できるようなものをつくってみました。ここから、左から1番目と2番目だけをコピーして、同じようにファイル名を指定して保存したいと考えていますが、全くうまくいかず・・・。

お手数ですが、どこを修正すべきなのかをおしえていただけますでしょうか。

よろしくお願いいたします。

Sub SheetSave()

...続きを読む

Aベストアンサー

シート2枚まとめて1つのブックにコピーということなら

Sub SheetSave2()
  Const N As Long = 2
  Dim myFile As String
  Dim myName As String
  Dim mySh(1 To N) As String
  Dim i As Integer

  myFile = ThisWorkbook.Path & "\" & ActiveSheet.Range("B1").Value & ".xlsx"

  '左から N番目までのシートをコピー
  For i = 1 To N
    mySh(i) = Sheets(i).Name
  Next
  Sheets(mySh).Copy

  Application.DisplayAlerts = False
  ActiveWorkbook.SaveAs Filename:=myFile
  Application.DisplayAlerts = True
  ActiveWorkbook.Close
End Sub

シート2枚まとめて1つのブックにコピーということなら

Sub SheetSave2()
  Const N As Long = 2
  Dim myFile As String
  Dim myName As String
  Dim mySh(1 To N) As String
  Dim i As Integer

  myFile = ThisWorkbook.Path & "\" & ActiveSheet.Range("B1").Value & ".xlsx"

  '左から N番目までのシートをコピー
  For i = 1 To N
    mySh(i) = Sheets(i).Name
  Next
  Sheets(mySh).Copy

  Application.DisplayAlerts = False
  ActiveWorkbook.Sav...続きを読む


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング