エクセルSUMIF関数とOR条件

「X」の条件を満たすデータをの合計を計算したい場合SUMIF関数、「X」および「Y」の条件を満たすデータの合計を計算したい場合は、SUMPRODUCT関数が使えると思いますが、
「X」または「Y」の条件を満たすデータの合計を計算したい場合は、
SUMIF(検索範囲,"X",合計範囲）＋SUMIF(検索範囲,"Y",合計範囲）とやるしかないですか？
それとも、SUMIFを並べなくても、１回で計算できる関数がありますか？
ご存知の方、ご教授下さい。
どうぞよろしくお願いいたします。

No.6 ベストアンサー 回答者： Wendy02 回答日時： 2008/08/09 18:53

こんばんは。

>条件が５個以上になると、さすがに式が長くなりすぎて見苦しいですので

それなら、こんな方法も思いつきます。

=SUMPRODUCT((LEN(SUBSTITUTE("XY",検索範囲,""))<2)*合計範囲)
(注意：大文字小文字の区別があります。）

数式の中の「<2」 の 2 は、検索値　"XY" のことです。
検索値が、5個なら、<5 です。

この回答へのお礼

度々の詳しい解説をありがとうございました。
本当に助かりました。

お礼日時：2008/08/10 21:52

No.5 回答者： Wendy02 回答日時： 2008/08/09 17:48

こんにちは。

>「{}」というカッコは私はエクセルで使った記憶がないのですが、
>これはどういうときに使うものなのでしょうか？

{} は、その中が配列(特別なメモリ上で複数のデータを保有する）になるということです。
ただ、そのまま、配列にしても、それを計算しませんので、SUMPRODUCT という関数が必要になります。

No.4 回答者： dghjty145 回答日時： 2008/08/09 16:12

Ano.1のものです。

＞ちなみに「>=1」は入れなくても同じ結果が出たのですが、

もし、「>=1」をいれないと、

検索範囲="X" と検索範囲="Y"がいずれも真の時、
( (検索範囲="X")+(検索範囲="Y") の値が２になり、
該当する値を２倍してしまいます。

もし、お手持ちのデータにおいて、検索範囲="X" と検索範囲="Y"が同時に成り立つことがなければ、＞＝１はなくともよいです。
たとえば、検索範囲="X" と検索範囲="Y"の検索範囲が同じ場合などは＞＝１はなくともよいです。

この回答へのお礼

度々の詳しい解説をありがとうございました。
本当に助かりました。

お礼日時：2008/08/10 21:52

No.3 回答者： dghjty145 回答日時： 2008/08/09 14:51

Ano1のものです。

=SUMPRODUCT ( ( ( (検索範囲="X")+(検索範囲="Y") )>=1 )*合計範囲）でした。
一番左に（をいれます。

この回答へのお礼

再度のご回答ありがとうございます。
ためしてみたところ、同じ結果が出ました！感動です。
ちなみに「>=1」は入れなくても同じ結果が出たのですが、
これはどういう意味があるのでしょうか？
よろしければお教え下さい。

お礼日時：2008/08/09 15:07

No.2 回答者： Wendy02 回答日時： 2008/08/09 13:34

こんにちは。

>SUMIF(検索範囲,"X",合計範囲）＋SUMIF(検索範囲,"Y",合計範囲）とやるしかないですか？
>それとも、SUMIFを並べなくても、１回で計算できる関数がありますか？

数式をコピペして、中身だけ替えて、「+」を入れるだけですから、以下のような配列数式を使う必要性はあまりないように思います。

=SUMPRODUCT(SUMIF(検索範囲,{"X","Y"},合計範囲))

この回答への補足

たびたび恐れ入ります。
ちなみに「{}」というカッコは私はエクセルで使った記憶がないのですが、
これはどういうときに使うものなのでしょうか？
併せて教えていただけるとうれしいです。

補足日時：2008/08/09 14:31

この回答へのお礼

ご回答ありがとうございます。
早速ためしてみたところ、同じ計算結果が出ました！
確かに、検索条件が２、３個であれば、SUMIFを並べたほうが簡単な気がしますが、
条件が５個以上になると、さすがに式が長くなりすぎて見苦しいですので
大変参考になります。ありがとうございます。

お礼日時：2008/08/09 14:22

No.1 回答者： dghjty145 回答日時： 2008/08/09 13:22

やはりSUMPRODUCT関数で以下のようにすれば良いと思います。

=SUMPRODUCT( ( (検索範囲="X")+(検索範囲="Y") )>=1 )*合計範囲）

この回答へのお礼

ご回答ありがとうございます。
「（」が４個なに対し、「）」が５個あるようですが
もう一個の「（」はどこに入れればよろしいでしょうか？

お礼日時：2008/08/09 14:17