プロが教える店舗&オフィスのセキュリティ対策術

エクセルを利用して、火曜日と金曜日の日付だけを抜き出したいのです。

A列には、本日から平成22年3月31日までの日付を入力しています。
このうち、火曜日と金曜日の日付だけを抜き出したいのです。

どのようにすると良いのでしょうか

よろしくお願いします。

A 回答 (5件)

B列に曜日を表示し、オートフィルタで「火曜」と「金曜」を抽出する。



B2に =CHOOSE(WEEKDAY(A2,1),"日","月","火","水","木","金","土")
下方にオートフィル

A列及びB列にオートフィルタ → B列で「火」と「金」を抽出

オートフィルタ  
http://www.eurus.dti.ne.jp/~yoneyama/Excel/filte …
「EXCEL 火曜日と金曜日だけを抜き出し」の回答画像5
    • good
    • 1
この回答へのお礼

このような関数もあるのですね。

ありがとうございました。

お礼日時:2009/05/26 18:36

    A   B   C    D


1  date     date
2  H21.05.26   H21.05.26 TRUE
3  H21.05.27   H21.05.29
4  H21.05.28   H21.06.02
… …………   …………
88 H21.08.20   H22.03.23
89 H21.08.21   H22.03.26
90 H21.08.22   H22.03.30
91 H21.08.23
92 H21.08.24
… …………
309 H22.03.29
310 H22.03.30
311 H22.03.31

セル D1 は空白のままにし、セル D2 に式 =OR(MOD(A2,7)=3,MOD(A2,7)=6) を入力した後で次の[フィルタオプションの設定]を実行すれば、C列にズラズラーっと火、金曜日が抽出されます。一発で!!
[抽出先]    “指定した範囲”
[リスト範囲]  $A$1:$A$311
[検索条件範囲] $D$1:$D$2
[抽出範囲]   $C$1
    • good
    • 1
この回答へのお礼

すごいですね。

もう、理解できないのですが、抽出できました。

ありがとうごさいました

お礼日時:2009/05/26 18:34

No2 merlionXXです。


火曜と金曜なら、さっきの式よりも
=IF(MOD(WEEKDAY(A1),3)=0,A1,"")
の方が簡単ですね。
    • good
    • 4
この回答へのお礼

カッコイイ式です。

ありがとうございました。

お礼日時:2009/05/26 18:24

A1から日付があるとして、B列があいていたらB1に



=IF(OR(TEXT(A1,"aaa")="火",TEXT(A1,"aaa")="金"),A1,"")

式を入れたら、B1セルの右下の角にカーソルをあわせて+型になったらダブルクリックしてください。
次にB列の書式を日付にして下さい。
    • good
    • 1
この回答へのお礼

ありがとうございました。

ひとつの式になっていてきれいですね。

お礼日時:2009/05/26 18:24

A1から日付が入っているとして、適当な列の1行目に↓を入れ下までコピー。


=IF(OR(WEEKDAY(A1)=3,WEEKDAY(A1)=6),A1,"")

WEEKDAY関数で曜日が取得できますよ。
#日=1、月=2、火=3…、土=7
    • good
    • 1
この回答へのお礼

WEEKDAY関数で曜日が取得できるとは知りませんでした。

ありがとうございました。

ちなみに、=TEXT(A1,"aaa")で全部の日付の曜日を出してから
火曜日と金曜日を抜き出そうとしていましたが、
こちらのほうが合理的ですね。

ありがとうございました。

お礼日時:2009/05/26 18:22

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています