エクセル2003で重複するデータの数量をまとめる

エクセル2003です。縦に連続する同じ名前のデータの数量をまとめて合計したいのですがどうすればよいでしょうか？具体的には
データ ｜数量|
データA　2
データB　4
データA　1
データC　6
データB　3
こういった感じのデータを違うシートに貼り付けるなどして
データA　3
データB　7
データC　6
こういう状態にしたいのです。
アドバイスよろしくおねがいします☆

No.1 ベストアンサー 回答者： keithin 回答日時： 2010/04/14 03:49

方法１

シート２の空セルを選ぶ
データメニューの統合を開始する
シート１のＡＢ列を追加する
左端列にチェックを入れてＯＫする

以上です。


方法２
表範囲を選び，データメニューのピボットテーブルレポートで集計させます。
難しい数式も何も使わずに，一気に集計結果が得られます。


方法３
もし，あなたが「集めるべきデータは　データＡとＢとＣの３種類だ」と確信を持って全てのデータを事前に用意できるなら
シート２にそれらの
データＡ
データＢ
データＣ
を羅列しておき，
=SUMIF(Sheet1!A:A,A1,Sheet2!B:B)
などの関数で，それぞれの集約値を求めることが出来ます。


方法４
べらぼうに面倒くさい数式を使えばデータABCを数式で抽出することも，やれば出来ます。
でもこういったマニアックな式は所詮遊びでしかないので，使わないことをお薦めします。
シート２のA1に
=INDEX(Sheet1!$A:$A,SMALL(IF(ISNUMBER(1/(FREQUENCY(MATCH(Sheet1!$A$1:$A$6,Sheet1!$A$1:$A$6,0),MATCH(Sheet1!$A$1:$A$6,Sheet1!$A$1:$A$6,0)))),INDEX(ROW(Sheet1!$A$1:$A$6),),9999),ROW(A1)))&""
B1に
=IF(A1="","",SUMIF(Sheet1!A:A,A1,Sheet1!B:B))

この回答への補足

うわぁ！すごい！！まさにこれがしたかったんです。方法1でできました！
ついでで申し訳ないんですが
番号｜データ ｜数量|
1001　データA　2
1002 データB　4
1003 データA　1
1004 データC　6
1005 データB　3

というような通し番号がさらに左端にあった場合はどうすればよいのでしょうか？
やはり｜番号｜の列を一旦移動させたりしなければいけないんでしょうか？

補足日時：2010/04/14 04:08

No.3 回答者： tom04 回答日時： 2010/04/14 22:51

こんばんは！

横からお邪魔します。
外しているかもしれませんが・・・

補足に
＞通し番号がさらに左端にあった場合はどうすればよいのでしょうか？

とありますが、「通し番号」という以上は番号の重複はないわけですよね？

一応そういう事だとして・・・

↓の画像のように作業用の列を使っています。
作業列D2セルに
=IF(COUNTIF($B$2:B2,B2)=1,ROW(),"")
という数式を入れ、オートフィルでずぃ～～～！っと下へコピーします。

そして、F2セルに
=IF(COUNT(D:D)<ROW(A1),"",INDEX(B:B,SMALL(D:D,ROW(A1))))

G2セルに
=IF(F2="","",SUMIF(B:B,F2,C:C))

という数式を入れ、F2・G2セルを範囲指定し、G2セルのフィルハンドルで
下へコピーすると画像のような感じになります。

以上、参考になれば良いのですが
的外れなら読み流してくださいね。m(__)m

No.2 回答者： keithin 回答日時： 2010/04/14 09:24

ん？

＞左に番号列　　(←仮にＡ列）

方法１’
シート２の空セルを選ぶ
データメニューの統合を開始する
シート１の「ＢＣ列」を追加する
左端列にチェックを入れてＯＫする

以上です。