ここから質問投稿すると、最大10000ポイント当たる!!!! >>

日付ごとのデータがあり、同じ日付の数は日によって違い、10個の時も20個の時もあります。
そのデータを、同じ日付のデータは14個以下に制限し、それ以上は無視して別シートに抽出したいのですが。(エクセル2010)

下記のようなシート1のデータを

     A     B     C
1  11月1日  りんご   A社
2  11月1日  みかん  C社
3  11月1日  とまと   B社


14 11月1日  みかん  D社
15 11月1日  とまと   H社
16 11月2日  ばなな   B社 
17 11月2日  りんご   D社

別シートに下記のように抽出

     A     B     C
1  11月1日  りんご   A社
2  11月1日  みかん  C社
3  11月1日  とまと   B社


14 11月1日  みかん  D社
15 11月2日  ばなな   B社
16 11月2日  りんご   D社

どなたか教えていただける方がいましたらよろしくお願いします。

このQ&Aに関連する最新のQ&A

A 回答 (4件)

1行目に項目名がある場合、空白列(たとえばD2セル)に以下の式を入力し、下方向にオートフィルします。



=IF(COUNTIF($A$2:A2,A2)>14,"","○")

このD列を基準に「データ」「フィルタ」で「○」を選択して、必要データのみ抽出し、このA~C列のデータ範囲を選択して「コピー」して新規シートに貼り付けてください。
    • good
    • 0
この回答へのお礼

ありがとうございます。

他の条件でもフィルターオプションをかけるつもりでしたので
一度に出来てちょうど良かったです。

お世話になりました。

お礼日時:2010/11/27 18:25

データは2行目から下方にあるとします。

D列は作業列でD2セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A2="","",IF(COUNTIF(A$2:A2,A2)<=14,MAX(D$1:D1)+1,""))

上の表がシート1にあるとして別のシートのA2セルには次の式を入力して横方向にオートフィルドラッグしたのちに下方にもオートフィルドラッグします。

=IF(OR(COLUMN(A1)>3,ROW(A1)>MAX(Sheet1!$D:$D)),"",INDEX(Sheet1!$A:$C,MATCH(ROW(A1),Sheet1!$D:$D,0),COLUMN(A1)))

なお、A列を選んでセルの表示形式を日付にします。
    • good
    • 0
この回答へのお礼

ありがとうございます。

一つの方法として参考になりました。

お礼日時:2010/11/27 18:22

こんばんは!


一例です。

↓の画像で左側がSheet1で右側のSheet2に表示するようにしてみました。
Sheet1に作業用の列を設けています。

作業列D2セルに
=IF(OR(A2="",COUNTIF($A$2:A2,A2)>14),"",ROW())
という数式を入れ、フィルハンドルの(+)マークでダブルクリック、またはオートフィルで下へずぃ~~~!っとコピーしておきます。

そして、Sheet2のA2セルに
=IF(COUNT(Sheet1!$D:$D)<ROW(A1),"",INDEX(Sheet1!A:A,SMALL(Sheet1!$D:$D,ROW(A1))))
という数式を入れ、列方向と行方向にオートフィルでコピーすると
画像のような感じになります。

当然、Sheet2のA列の表示形式は「日付」にしておきます。

以上、参考になれば良いのですが・・・m(__)m
「同じ日にちの件数を制限して抽出する」の回答画像3
    • good
    • 0
この回答へのお礼

ありがとうございます。

一つの方法として参考になりました。

お礼日時:2010/11/27 18:23

 例えば、1行目にタイトルがあり、2行目からデータがならんでいるとします。


 14個以下にしたいということは、15個目から下を削除、すなわち、16行目以下を削除すればよいということです。
 日付ごとに別シートになっているようですが、日付ごとのシートの口取紙(インデックス)部分をまとめて選択して、16行目以下を削除すれば、すべてのシートの16行目以下が削除されます。
 別ファイルになってしましますが、(1)口取紙(インデックス)部分を選択する作業と、(2)16行目以下を削除する2作業で完了です。


 口取紙(インデックス)部分とは、シートを選択する際にクリックする下の左部分にある「Sheet1」とか「Sheet2」とか表示してある部分です(名前をしらないので、そう表現しました。ご存知でしたら、逆に教えていただくとありがたいです)。

 複数のシートを一括して選択するには、最初に一番左端の口取紙部分をクリックしてから、一番右端の口取紙部分をSHIFTキーを押しながらクリックすればできます。
 特定のシートのみを選択したい時には、選択したいシートの口取紙部分をCTRLキーを押しながらクリックすればできます(最初の1つ目の口取紙は、CTRLキーなしでクリックしてください。)。 
    • good
    • 0
この回答へのお礼

ありがとうございます。

ただ、シートごとに日付が分かれている訳ではありませんので
ちょっと違うようです。

ちなみに、口取紙部分の名称はたぶん「シート見出し」
だと思います。

お礼日時:2010/11/27 18:19

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!


人気Q&Aランキング