エクセルでの縦グループを横グループに並べ替える方法

次のような表があります(Pフォントの影響で列幅がずれています)。

縦に３行分が一つのグループであり、１行分のスペースを空けて
再び３行分のグループが繰り返しあります。
このようなデータグループが縦に500件以上あります。

│ A │ B │ C │ D │ E │ F │ G │ H
1│a1 │ │ │ │ │ │ │
2│a2 │ │ │ │ │ │ │
3│a3 │ │ │ │ │ │ │
4│ │ │ │ │ │ │ │
5│b1 │ │ │ │ │ │ │
6│b2 │ │ │ │ │ │ │
7│b3 │ │ │ │ │ │ │


これを下表のように横に並べ替えたいのです。
件数が多く、ハンドで一つ一つを並べ替えるのは困難なので、
何とか簡単に実現する方法を知りたいのです。

│ A │ B │ C │ D │ E │ F │ G │ H
1│ a1 │ a2 │ a3 │ │ │ │ │
2│ b1 │ b2 │ b3 │ │ │ │ │
3│ │ │ │ │ │ │ │
4│ │ │ │ │ │ │ │
5│ │ │ │ │ │ │ │
6│ │ │ │ │ │ │ │
7│ │ │ │ │ │ │ │

皆様、何とかお知恵をお貸しください。
よろしくお願いいたします。

No.4 ベストアンサー 回答者： tom04 回答日時： 2010/12/07 20:42

No.3です！

たびたびごめんなさい。
質問文をちゃんと読んでいませんでした。
＞縦に３行分が一つのグループであり、１行分のスペースを空けて
再び３行分のグループが繰り返しあります。

とありますので、前回の投稿は無視してください。

Sheet1のA1セルからデータがあり、Sheet2のA1セルから表示させるとします。

Sheet2のA1セルに
=OFFSET(Sheet1!$A$1,(ROW(A1)-1)*4+(COLUMN(A1)-1),,1)
として、C1セルまでコピー！
これを下へオートフィルでコピーすると
希望に近い形にならないでしょうか？

どうも何度も失礼しました。m(__)m

この回答へのお礼

アイディアをいただき有難うございました。

私が目指すものがより簡単に出来上がりました。
本当にに有難うございました。
心からお礼申し上げます。

お礼日時：2010/12/08 09:04

No.5 回答者： mike_g 回答日時： 2010/12/07 23:37

Sheet2!A1: =OFFSET(Sheet1!$A$1,(ROW(A1)-1)*4+COLUMN(A1)-1,)

この回答へのお礼

教えていただき有難うございました。
感謝いたします。

お礼日時：2010/12/08 09:08

No.3 回答者： tom04 回答日時： 2010/12/07 20:25

こんばんは！

無理矢理って感じの一例です。

↓の画像のようにB列を作業用の列としています。
作業列B2セルを
=IF(OR(COUNTBLANK(A1:A3)=3,A2=""),"",COUNTIF($A$2:A2,"")+1)
としてオートフィルで下へずぃ～～～！っとコピー！

そしてD2セルに
=IF(COUNTIF($B$1:$B$1000,ROW(A1))<COLUMN(A1),"",INDEX($A$1:$A$1000,SMALL(IF($B$1:$B$1000=ROW(A1),ROW($A$1:$A$1000)),COLUMN(A1))))
これは配列数式になってしまいますので、
この画面からD2セルにコピー＆ペーストしただけでは正確なデータが表示されません。
D2セルに貼り付け後、F2キーを押す、またはD2セルをダブルクリック、または数式バー内で一度クリックします。
編集可能になりますので、Shift＋Ctrlキーを押しながらEnterキーで確定。

これを列方向と行方向にオートフィルでコピーすると
画像のような感じになります。

以上、参考になれば良いのですが
他に良い方法があればごめんなさいね。m(__)m

No.2 回答者： minosennin 回答日時： 2010/12/07 20:18

そのデータがSheet1にあるものとして

一例ですが、

別SHEETの
A1に　=INDIRECT("Sheet1!A"&INT(ROW()*4-3),TRUE)
B1に　=INDIRECT("Sheet1!A"&INT(ROW()*4-2),TRUE)
C1に　=INDIRECT("Sheet1!A"&INT(ROW()*4-1),TRUE)

３つまとめて下へ必要数ドラッグ

この回答へのお礼

アイディアをいただき有難うございました。

私が目指すものが完璧に出来上がり、本当に助かりました。
まことに有難うございました。
心からお礼申し上げます。

お礼日時：2010/12/08 08:28

No.1 回答者： shornet 回答日時： 2010/12/07 19:59

プログラム組み込めば可能ですが知識なけらば方法が手作業しか

この回答へのお礼

ご助言有難うございました。

お礼日時：2010/12/08 08:19