外部TXTデータでFlashを作りたいです。。

Action Scriptでxmlデータを使用して画像を表示させ方と、その画像（クリック時別ページに飛ばす）にリンク張り方を教えてください。

ここに＜http://movie.geocities.jp/hothotsteal/action.swf＞に
Action Scriptで作成した物があります。

########################################
var star:Array = new Array();
var s_num:Number = 8;
var length:Number = s_num * 100;

for (i = 1; i <= s_num; i++)
{
_root.attachMovie("star","star" + i,i);
star[i] = eval("star" + i);
star[i]._x = 250 - 100 * (s_num - i);
star[i]._y = 80;
}

_root.onEnterFrame = function()
{
for (i = 1; i <= s_num; i++)
{
if (_root.star[i]._x < -120)
{
_root.star[i]._x += length;
}
else if (_root.star[i]._x > 620)
{
_root.star[i]._x -= length;
}
_root.star[i]._x += (250 - _root._xmouse) / 10;

star[i].onRollOver = rollov;
star[i].onRollOut = rollou;
}
};

function rollov()
{
this._alpha = 50;
}
function rollou()
{
this._alpha = 100;
}
##################################

「商品画像」というところを外部TXTで読み込んで、別画像表示、リンクの設定をしたいです。

画像は複数ありまして、画像１つ１つを個別のページに飛ばしたいのです。

どなたか救いの手を差し伸べていただけないでしょうか？

No.1 ベストアンサー 回答者： BlurFiltan 回答日時： 2010/12/14 18:24

◎ファイルの構造例

　任意のフォルダ
　　├○○.html (○○.swf を表示)
　　├○○.swf
　　├URL.xml
　　│
　　├AA.html (○○.htmlからジャンプ)
　　├BB.html ( 〃 )
　　├ ～略～
　　├HH.html ( 〃 )
　　└img (フォルダ)
　　　　├A.jpg (ボタン画像)
　　　　├B.jpg ( 〃 )
　　　　├ ～略～
　　　　└H.jpg ( 〃 )



◎「URL.xml」内データ例

<?xml version="1.0" encoding="Shift-JIS"?>
<URLData>
<URLNode image="./img/A.jpg" link="AA.html" />
<URLNode image="./img/B.jpg" link="BB.html" />
<URLNode image="./img/C.jpg" link="CC.html" />
<URLNode image="./img/D.jpg" link="DD.html" />
<URLNode image="./img/E.jpg" link="EE.html" />
<URLNode image="./img/F.jpg" link="FF.html" />
<URLNode image="./img/G.jpg" link="GG.html" />
<URLNode image="./img/H.jpg" link="HH.html" />
</URLData>



◎スクリプト例

＝＝＝＝＝＝＝
var star:Array = new Array();
var s_num:Number = 8;
var len:Number = s_num * 100;

System.useCodepage = true;

var my_xml:XML = new XML();
my_xml.ignoreWhite = true;

var my_node:XMLNode;

my_xml.onLoad = function():Void
{
my_node = my_xml.firstChild;
makeStar();
};

my_xml.load("url.xml");

function makeStar():Void
{
//
for (var i:Number = 0; i < s_num; i++)
{
_root.createEmptyMovieClip("star" + i, i);
star[i] = _root["star" + i];
star[i].createEmptyMovieClip("loader", 0);
star[i]._x = 250 - 100 * (s_num - i);
star[i]._y = 80;
star[i]._link = my_node.childNodes[i].attributes.link;
star[i].loader.loadMovie(my_node.childNodes[i].attributes.image, star[i]);
star[i].onRollOver = rollov;
star[i].onRollOut = rollou;
star[i].onRelease = releas;
}
//
_root.onEnterFrame = function():Void
{
for (var i:Number = 0; i < s_num; i++)
{
if (star[i]._x < -120)
{
star[i]._x += len;
}
else if (star[i]._x > 620)
{
star[i]._x -= len;
}
star[i]._x += (250 - _root._xmouse) / 10;
}
};
}

function rollov():Void
{
this._alpha = 50;
}

function rollou():Void
{
this._alpha = 100;
}

function releas():Void
{
getURL(this._link, "_blank");
}
＝＝＝＝＝＝＝


・スクリプト：ActionScript 2.0
・再生：Flash Player 6 以上

※回答字数制限のためコメント行など省略
　

この回答へのお礼

本当に本当にありがとうございました。。

すぐに出来ました。。

神様のようなお方です。

ご迷惑おかけしました。

うれしすぎてなんて言っていいかわかりません。。

ありがとうございました。

お礼日時：2010/12/14 21:44