限定された期間に祝祭日及び土日を除いたスケジュール

WINDOWS XP EXCELL ２００３です。

例えば

３月２１日～４月２０日　　(B２～B２３　※　2011年３月～４月です)で、

土日及び祝祭日を除いた日付を参照図のようにしたいのですが可能でしょうか。
もしも可能ならば　「B２」　にどんな数式を適用すればいいかご指導いただけませんか。

注　１　C列は　「祝日」という名のシートです。
　　２　B６　～　B１７　は非表示です。

No.4 ベストアンサー 回答者： keithin 回答日時： 2011/02/24 21:21

もう少し工夫を追加して，期日を超えた日付は表示しないようにします。

A1には月の１日を記入します。
アドインの分析ツールは必ずチェックします。

B2:
=IF(WORKDAY($A$1+19,ROW(B1),祝日!$A$1:$A$20)>EOMONTH($A$1,0)+20,"",WORKDAY($A$1+19,ROW(B1),祝日!$A$1:$A$20))
以下沢山コピー

数式を入れたセル範囲は右クリックしてセルの書式設定の表示形式のユーザー定義を選び
mm/dd(aaa)
と設定しておきます。

この回答へのお礼

ご回答誠にありがとう御座います。
最終の日時も決まり誠にありがとう御座いました。
今後ともご指導賜りますようによろしく御願いします。

お礼日時：2011/02/24 22:27

No.3 回答者： tom04 回答日時： 2011/02/24 20:55

No.2です！

たびたびごめんなさい。

投稿した後で言葉足らずだったと気づきました。

画像では祝日データが「祝日Sheet」のA1～A20にあるとちゃんと載っていましたので、
B2セルに入れる数式を以下のように訂正してください。

=IF($A$1="","",TEXT(WORKDAY(DATE(YEAR($A$1),MONTH($A$1),21)-1,ROW(A1),祝日!$A$1:$A$20),"mm/dd(aaa)"))

尚、「祝日Sheet」のA1～A20セルを範囲指定　→　名前ボックスに　祝日　と入力しOK
これで「祝日Sheet」のA1～A20セルが「祝日」と名前定義されますので、
この操作のあとであれば前回の数式でOKだと思います。

何度も失礼しました。m(__)m

この回答へのお礼

久し振りにお世話になります。
いつも丁寧にご回答下さいまして誠にありがとう御座います。

今後ともご指導の程よろしく御願いします。

お礼日時：2011/02/24 22:25

No.2 回答者： tom04 回答日時： 2011/02/24 20:40

こんばんは！

一例です。

メニュー　→　ツール　→　アドイン　→　「分析ツール」にチェックを入れ

B2セルに
=IF($A$1="","",TEXT(WORKDAY(DATE(YEAR($A$1),MONTH($A$1),21)-1,ROW(A1),祝日),"mm/dd(aaa)"))
という数式を入れオートフィルで下へコピーではどうでしょうか？

尚、祝日データは名前定義してあるものとします。m(__)m

No.1 回答者： mshr1962 回答日時： 2011/02/24 20:37

「ツール」「アドイン」で「分析ツール」をチェック

B2=WORKDAY(DATE(YEAR($A$1),MONTH($A$1),20),1,祝日!$A$1:$A$21)
B3=IF(WORKDAY(B2,1,祝日!$A$1:$A$21)>DATE(YEAR($A$1),MONTH($A$1)+1,20),"",WORKDAY(B2,1,祝日!$A$1:$A$21))
B3を下方にコピー

この回答へのお礼

早速ご回答いただき誠にありがとうございます。

こんな数式はまだまだ小生には無理です。
これからも勉学に励みたいです。

特に最終日が決まっているのは感激でした。
今後ともよろしく御願いします。

お礼日時：2011/02/24 22:07