エクセル 表のデータを一列にしたい

表にあるデータを一列したいのですが・・・。
簡単な関数なら理解できます。

　　1　　 2　　　3 ・・・
A 11｜ 22｜ 33
B 44｜ 55｜ 66
C 77｜ 88｜ 99
・
・
・

となっているのを、

11
22
33
44
55
66
77
88
99
・
・
・


としたいんです。
出力先はエクセルでもワードでもメモ帳でもかまいません。
なるべく簡単に出来る方法はないでしょうか？
マクロは使わずに出来るとありがたいです。

No.5 回答者： mu2011 回答日時： 2011/04/23 15:48

エクセルで関数以外の方法は如何でしょうか。

仮に３列の並び替えとしますと、E1に#A1、E2に#B1、E3に#C1としてE1:E3を選択して下方向にコピー、コピー後にその範囲を置換で「#」を「=」に全て置換してみて下さい。

No.4 回答者： CoalTar 回答日時： 2011/04/23 13:35

簡単な関数ってどの程度だろう。

E1セル 3 下へ連番

F1:F3セル 1;2;3
下へコピー

G1セル =INDEX($A:$C,$E1/3,$F1)
下へオートフィル

No.3 回答者： imogasi 回答日時： 2011/04/23 10:31

もう答えは出ていますが

この問題は、算数的な問題なんです。
そのセルが上からの何番目かの行番号は式を入れたセルで＝ＲＯＷ（）で取れます。
Rｏｗ（）番号の行に（上からROW()番目の行に）くるべき元データは、
何行目のデータかを考えると、ｒｏｗ（）/3行目の（元データが３列なので）データです。
正確には　 I NT((ROW()-1)/3)+1です。
そして列的にはその行で左から MOD(ROW()-1,3)+1 番目です。
其れでOFFSET関数を使うとすると
OFFSET関数は起点Ａ１からの隔たりを指定するので＋１の「づらし」が要らなくなり
=OFFSET($A$1,INT((ROW()-1)/3),MOD(ROW()-1,3),1,1)
起点（Ａ１セル）
↓
INT((ROW()-1)/3),→MOD(ROW()-1,3（採ってくるセル）
↑　　　　　　　　　　　↑
行ずらし数　　　　　　列ずらし数
ーー
ＯＦＦＳＥＴ関数はＷＥＢ照会して
http://officetanaka.net/excel/function/function/ …
など読んで勉強のこと。

No.2 回答者： mike_g 回答日時： 2011/04/23 05:06

=OFFSET(Sheet1!A$1,(ROW(A1)-1)/3,MOD(ROW(A1)-1,3))

No.1 ベストアンサー 回答者： keithin 回答日時： 2011/04/23 01:10

シート２のA1に

=INDEX(Sheet1!A:C,INT((ROW(A1)-1)/3)+1,MOD(ROW(A1)-1,3)+1)
と入れてみると，あとは下向けにつるつるっとコピーしてやるだけです。