エクセル２列に入っているデータのカブリを探したい

Ａ列２文字、Ｂ列２文字の熟語が入っているときに
他の列に、入れ替わってかぶっていることを見つける方法はありますか。
エクセルのバージョンは2003です。

データ例

Ａ　　Ｂ
算数　国語
松本　佐藤
桑田　竹内
年月　金曜
国語　算数
斉藤　米山
金曜　年月
杉本　長谷
吉岡　西川
・　　・　　
・　　・　　
・　　・　　
・　　・　　

というようなデータがたくさんあるときに
１行目の算数　国語と５行目の国語　算数
４行目の年月　金曜と７行目の金曜　年月を
「カブリ」と考えて
見つけたいと思っています
ひとつひとつ検索する以外で簡単な方法はありますか。

他の列に印がつくとか、見つかる方法は問いません
よろしくお願いいたします。

No.5 回答者： mu2011 回答日時： 2011/04/28 09:59

NO3です。

「カブリ」についてもう少し補足した方が良いと思う。
仮に２列のデータが入れ替わっている行を抽出という事ならば次の方法は如何でしょうか。

A1:B100範囲とすると、範囲を選択→書式→条件付き書式設定→「数式がを選択」、数式欄に=SUMPRODUCT((CONCATENATE($A$1:$A$100,$B$1:$B$100)=$B1&$A1)*1)→書式→パターンタブで赤を選択→ＯＫ

又は、C1に=if(SUMPRODUCT((CONCATENATE($A$1:$A$100,$B$1:$B$100)=$B1&$A1)*1),"カブリ","")として下方向にコピー

この回答へのお礼

ありがとうございます、できました！

皆さんありがたいのですが、500以上のデータがあったことで
さらに便利な「どことカブッているか」のアイディアまでくださった
１さんにBAを、と思います。

１さんが素早くきちんとご回答くださっていたのに
最初に勘違いしたせいでみなさんのお手をわずらわせすみません。
でも「色」や「別の行は使わない」方法がよい場合にはこちらを
使わせていただきたいと思います、ありがとうございました。

お礼日時：2011/04/28 10:41

No.4 回答者： KURUMITO 回答日時： 2011/04/27 20:44

C1セルに次の式を入力し下方にオートフィルドラッグします。

=IF(COUNTA(A1:B1)<>2,"",SUMPRODUCT((A$1:A$100=B1)*(B$1:B$100=A1)))

カブリが有れば1が表示されます。

この回答へのお礼

ありがとうございます、できました！

皆さんありがたいのですが、500以上のデータがあったことで
さらに便利な「どことカブッているか」のアイディアまでくださった
１さんにBAを、と思います。

１さんが素早くきちんとご回答くださっていたのに
最初に勘違いしたせいでみなさんのお手をわずらわせすみません。
でも「別の行は使わない」方法がよい場合にはこちらを
使わせていただきたいと思います、ありがとうございました。

お礼日時：2011/04/28 10:41

No.3 回答者： mu2011 回答日時： 2011/04/27 18:05

かぶっているセルに色付けする方法は如何でしょうか。

（１）Ａ列を選択→書式→条件付き書式設定→「数式がを選択」、数式欄に=COUNTIF(B:B,A1)→書式→パターンタブで赤を選択→ＯＫ
（２）Ｂ列を選択→書式→条件付き書式設定→「数式がを選択」、数式欄に=COUNTIF(A:A,B1)→書式→パターンタブで赤を選択→ＯＫ

この回答へのお礼

ありがとうございます
色が着くのは印と同じぐらい助かりますが

見つける対象としてはひとつ下の方と同じことなので
私の希望とは少し違いました
説明が下手ですみません

お礼日時：2011/04/28 09:24

No.2 回答者： kmetu 回答日時： 2011/04/27 17:55

たとえばC列に

=COUNTIF(A:A,B1)

として必要なだけ下にフィルしておけばB列と同じものがA列にあればその数を表示します

また

=IF(COUNTIF(A:A,B1)>0,"カブリ","")

としておけけばカブリという文字が表示されます。

A列を基準にした場合は

=COUNTIF(B:B,A1)

この回答へのお礼

ご回答ありがとうございます

この場合、
算数　国語
国語　算数

の「算数」を見つけることはできますが

算数　国語
理科　算数

の場合も見つけてしまうのではないですか？

また
算数　国語
国語　算数
理科　社会
算数　国語

となっていた場合の
最初の　算数　は見つけないのでは？

残念ながら少し違うように思いました

お礼日時：2011/04/28 09:23

No.1 ベストアンサー 回答者： keithin 回答日時： 2011/04/27 17:54

D1に

=A1&B1
E1に
=B1&A1
をそれぞれ入れてリストの下端までコピーしておき，現在の並びリストと「入れ替わり」を是正したリストを用意します

C1に
=IF(COUNTIF(E:E,D1),"×","")
または
=IF(COUNTIF(E:E,D1),MATCH(D1,E:E,0),"")
のように数式を入れると，印が現れます。後者の式は自分の入れ替わりが何行目にあるかを示します。

この回答へのお礼

ありがとうございます。
お返事に少し時間がかかりすみません。
最初私が行を少し勘違いしていて、思ったような結果がでていませんでしたが
もう一度試したところ、うまくいきました。

このような結果を望んでいました！
すばらしいです、ありがとうございます。

お礼日時：2011/04/28 10:36