エクセルで、(A1)に日付を入れ、(A2)に期限を入れ、(A3)に(A2)の期限のさらに1ヶ月前にアラートを表示する、というような設定は可能でしょうか。

具体的なイメージとしては、(A1)2011年7月30日、(A2)1ヶ月、とすると、(A3)では2011年6月1日になるとアラートが表示される(表示は、「○」とか「!」で構いません。)、という感じにできたらと思ってます。

ご教示頂けると幸いです。よろしくお願いいたします。

このQ&Aに関連する最新のQ&A

A 回答 (6件)

 ANo.1です。


 申し訳御座いません、質問内容を勘違いしておりました。
 アラートが表示される最初の日が、2011年6月1日ではなく、2011年5月31日ならば多少楽だったのですが、A1で指定した日付の、A2で指定した期間だけ前の日、の翌日の、更に1ヶ月前の日以降になると、アラートを表示させると考えれば宜しいのですね?
 Excelには、関数の中に関数を入れ子にして使う事が出来る限界があり、Excelのバージョンが、Excel2007よりも前のバージョンである場合には、7重の関数までにしか出来ませんので、もし、質問者様が御使用されているExcelのバージョンが、Excel2007よりも前のバージョンである場合には、一旦、別のセル(例えばA4セル)に期限日を表示させてから、A4セルに表示されている日付の翌日の、更に1ヶ月前の日以降になると、アラートを表示させる様にした方が良いと思います。

 まず、A4セルに次の関数を入力して下さい。

=IF(AND(ISNUMBER(A$1),OR(ISNUMBER(FIND("年",A$2)),ISNUMBER(FIND("月",A$2)),ISNUMBER(FIND("日",A$2)))),DATE(YEAR(A$1)-IF(ISNUMBER(FIND("年",A$2)),LEFT(A$2,FIND("年",A$2)-1)+0,0),MONTH(A$1)-IF(ISNUMBER(FIND("月",A$2)),SUBSTITUTE(MID("年"&A$2,FIND("月",A$2)-2+ISNUMBER(MID(A$2,FIND("月",A$2)-1,1)+0),2),"年",)+0,0),DAY(A$1)-IF(ISNUMBER(FIND("日",A$2)),MID(A$2,IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))+1,LEN(A$2)-IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))-1)+0,0)))

 次に、A3セルには、次の関数を入力して下さい。

=IF(ISNUMBER(A$4),IF(TODAY()<DATE(YEAR(A$4+1),MONTH(A$4+1)-1,DAY(A$4+1)),"","○"),"")

 後は、A1セルに日付、A2セルに期限を入力しますと、A4セルに期限日が表示され、期限日の1ヶ月前の日を過ぎると(期限日の丁度1ヶ月前の日は含まず)、A3セルに「○」が表示されます。
 尚、上記の関数では、A2セルに入力する期限が、「1ヶ月」や「2ヶ月」だけではなく、「1年」や「4月」、「5か月」、「11ヵ月」、「03カ月」、「2年12箇月」、「1年3月10日」、「1230日」等々にも対応しています。(但し、「2/10/20」の様に、「年」、「月」、「日」の何れの文字も含まれていない場合には対応していません)

 それから、もし、質問者様が御使用されているExcelのバージョンが、Excel2007以降のバージョンである場合には、関数を入れ子に出来る限界が、64重にもなりますから、A3セルの関数と、A4セルの関数を一纏めにして、A4セルは使用せずに、A3セルだけでアラートを表示させる事も可能です。
 その場合のA3セルの関数は、次の様なものとなります。

=IF(AND(ISNUMBER(A$1),OR(ISNUMBER(FIND("年",A$2)),ISNUMBER(FIND("月",A$2)),ISNUMBER(FIND("日",A$2)))),IF(TODAY()<DATE(YEAR(DATE(YEAR(A$1)-IF(ISNUMBER(FIND("年",A$2)),LEFT(A$2,FIND("年",A$2)-1)+0,0),MONTH(A$1)-IF(ISNUMBER(FIND("月",A$2)),SUBSTITUTE(MID("年"&A$2,FIND("月",A$2)-2+ISNUMBER(MID(A$2,FIND("月",A$2)-1,1)+0),2),"年",)+0,0),DAY(A$1)-IF(ISNUMBER(FIND("日",A$2)),MID(A$2,IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))+1,LEN(A$2)-IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))-1)+0,0))+1),MONTH(DATE(YEAR(A$1)-IF(ISNUMBER(FIND("年",A$2)),LEFT(A$2,FIND("年",A$2)-1)+0,0),MONTH(A$1)-IF(ISNUMBER(FIND("月",A$2)),SUBSTITUTE(MID("年"&A$2,FIND("月",A$2)-2+ISNUMBER(MID(A$2,FIND("月",A$2)-1,1)+0),2),"年",)+0,0),DAY(A$1)-IF(ISNUMBER(FIND("日",A$2)),MID(A$2,IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))+1,LEN(A$2)-IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))-1)+0,0))+1)-1,DAY(DATE(YEAR(A$1)-IF(ISNUMBER(FIND("年",A$2)),LEFT(A$2,FIND("年",A$2)-1)+0,0),MONTH(A$1)-IF(ISNUMBER(FIND("月",A$2)),SUBSTITUTE(MID("年"&A$2,FIND("月",A$2)-2+ISNUMBER(MID(A$2,FIND("月",A$2)-1,1)+0),2),"年",)+0,0),DAY(A$1)-IF(ISNUMBER(FIND("日",A$2)),MID(A$2,IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))+1,LEN(A$2)-IF(ISNUMBER(FIND("月",A$2)),FIND("月",A$2),IF(ISNUMBER(FIND("年",A$2)),FIND("年",A$2),0))-1)+0,0))+1)),"","○"),"")
    • good
    • 0
この回答へのお礼

すごいっ!確かにできました!ありがとうございました。

お礼日時:2011/07/20 21:19

No.4です!


たびたびごめんなさい。

投稿した後で数式の間違いに気づきました。
せっかくA2セルに数値を入力するようにしているのに、それを利用していませんでした。

=IF(COUNTBLANK(A1:A2),"",IF(TODAY()>=EDATE(A1,-A2),"!",""))

に訂正してみてください。

何度も失礼しました。m(_ _)m
    • good
    • 0
この回答へのお礼

とんでもないです。こちらも非常に参考になりました。ありがとうございます!

お礼日時:2011/07/20 21:20

こんばんは!


横からお邪魔します。

こういうコトですかね?
A2セルには月数(単に数値のみ)を入力します。

A3セルを
=IF(COUNTBLANK(A1:A2),"",IF(TODAY()>=EDATE(A1,-1),"!",""))

としてみてはどうでしょうか?

尚、EDATE関数を使用するにあたって当方使用のExcel2003以前のバージョンでは
メニュー → ツール → アドイン → 「分析ツール」にチェックを入れておく必要があります。

的外れならごめんなさいね。m(_ _)m
    • good
    • 0
この回答へのお礼

ありがとうございます!参考になりました。

お礼日時:2011/07/20 21:21

ご質問の意味がよくわかりませんがA3セルには次の式を入力してはどうでしょう。



=IF(A2="","",IF(TODAY()>=DATE(YEAR(A2),MONTH(A2)-1,DAY(A2)),"○",""))
    • good
    • 0

エクセルには Today()関数というのがあります。


仮に A4セルに =today() と入れてみてください。
今日の日付が出ます。明日、ファイルと開くと明日の日付です。
1月前の日付ですが A5セルに =DATE(YEAR(A1),MONTH(A1)-A2,DAY(A1))
となります。
アラートのセルですが
=IF(A4>A5,"○","")
となります。この式を一つにまとめると
=IF(TODAY()>DATE(YEAR(A1),MONTH(A1)-A2,DAY(A1)),"○","")
A1,A2セルが未入力の場合を考慮すると
=IF(OR(A1="",A2=""),"",IF(TODAY()>DATE(YEAR(A1),MONTH(A1)-A2,DAY(A1)),"○",""))
とかになります。
式の組み立てを理解して自分ものにしてください。
    • good
    • 0
この回答へのお礼

わかりやすい解説、ありがとうございます。教わるだけではだめですね、勉強いたします!

お礼日時:2011/07/20 21:22

 A3セルに次の関数を入力されると良いと思います。



=IF(ISNUMBER(A2),IF(A1>DATE(YEAR(A2),MONTH(A2)+1,DAY(A2)),"","○"),"")

この回答への補足

早速ご回答頂きありがとうございます!
そして、ごめんなさい。こちらの質問が、わかり難かったみたいです。

(A1)2011年7月30日、(A2)1ヶ月、と入れておけば、2011年6月1日以降は(A3)上で自動でアラートがずっと表示される、という感じにできたらと思ってます。(A2)は、具体的な日付でもかまいません。

kagakusukiさんからご教示頂いた方法を試したところ、(A1)に2011年10月30日、(A2)に1ヶ月前の日付である2011年10月1日、と入れたら、本日(2011/7/19)の時点でアラートが出てしまいました。この場合は、2011年9月1日にアラートが表示されるようにしたいです・・。

操作が間違っていればご指摘頂ければと存じます。
わがままを言ってすみません、よろしくお願いいたします。

補足日時:2011/07/19 18:01
    • good
    • 0

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

Qエクセル プルダウンの作り方

お世話になります。
エクセルでプルダウンの作り方を教えていただけませんでしょうか?
住所を▼のボタンでクリックしたら【北海道,青森,秋田,岩手・・・】などの選択ができるようにしたいのです。
宜しくお願いします。

Aベストアンサー

メニューから「データ」、「入力規則」、「設定」で「入力値の種類」を「リスト」を選択します。
そうすると「元の値」という表示がでますので、そこで前もって作っておいたリストの範囲を指定します。
多くないのでしたら、そのままそこにカンマで区切って入力しても出来ます。

Q=LARGE(INDEX((($A$1:$A$10)<>"")/ROW($A$1:$A$10),),ROW(A1)) とは

エクセル2000です。
A列(A1~A10)に飛び飛びに文字列が表示されているとき、
仮にC1に
=LARGE(INDEX((($A$1:$A$10)<>"")/ROW($A$1:$A$10),),ROW(A1)) と入れてフィルドラッグすると、C列にA列のうち文字が表示されたセルの行番号の逆数を取得できるようです。
これはどのような理屈によるものでしょうか?
LARGEやINDEXなど組み合わされた関数それぞれの意味は理解しているはずなのに、先ほどから式とにらめっこしていますが何故こうなるのかわかりません。
ご教示いただければ幸いに存知ます。

Aベストアンサー

今日はとてもとても暇なので。。。(^^;;;

>(1)=LARGE(($A$1:$A$10<>"")/ROW($A$1:$A$10),ROW(A1))
    をCSEしてみましたが、配列にならず
>(2)=LARGE(($A$1:$A$10<>"")/ROW($A$1:$A$10),ROW($A$1:$A$10))
    で成功しました。

どちらでも上手くいくのですがちょと気をつけないといけないところがあります。

例えばこれらの式を、E1~E10にセットするものとして説明します。

(1)ではLargeの第2引数がA1と相対参照、かつ、ひとつのセルだけ設定されていることに気づくと思います。
ということは、この式は、E1~E10を範囲選択してから入力するのではなくて、
E1だけを選択し、配列数式にして入力後、E10までフィルドラッグしなければいけないことになります。

(2)では、A1:A10と10個のセルを指定していますので
E1~E10を選択後、配列数式で入力することになります。

●それから(2)の入力方法であれば、全てが相対参照であってもOKです。

E1~E10を選択後、

{=LARGE((A1:A10<>"")/ROW(A1:A10),ROW(A1:A10))}

---------------------------------------------------
どうもスーパーエクスパートさんは
「配列」という言葉に苦手意識が働くようですねぃ。(^^;;;
以上です。
 

 

今日はとてもとても暇なので。。。(^^;;;

>(1)=LARGE(($A$1:$A$10<>"")/ROW($A$1:$A$10),ROW(A1))
    をCSEしてみましたが、配列にならず
>(2)=LARGE(($A$1:$A$10<>"")/ROW($A$1:$A$10),ROW($A$1:$A$10))
    で成功しました。

どちらでも上手くいくのですがちょと気をつけないといけないところがあります。

例えばこれらの式を、E1~E10にセットするものとして説明します。

(1)ではLargeの第2引数がA1と相対参照、かつ、ひとつのセルだけ設定されていることに気づく...続きを読む

Qエクセルでプルダウンメニューの作り方

  エクセルの画面で、よく三角形を逆さまにした形をクリックするといくつかメニューが出てき、どれかを選べるようになっていますが、その作り方を教えてください。
 会社で人事を担当していますが、三角形(プルダウンボタン)をクリックすると社員氏名一覧が表示され、そこから選択できるようにしたいのです。
 しばらく自力でいろいろやってみましたが、さっぱり見当がつかず、どうやればいいのか分かりませんでした。よろしくお願いします。

Aベストアンサー

こんばんは!
当方使用のExcel2003での一例です!

↓の画像のようにSheet2に名簿表を作成しておきます。
画像ではSheet2のA2セル以降を範囲指定 → 名前ボックスに仮に「名簿」と入力しOK
これで範囲指定したセルが「名簿」と名前定義されましたので、

Sheet1のリスト表示させたいセルを範囲指定 → メニュー → データ → 入力規則
→ リスト → 「元の値」の欄に
=名簿
としてOK

これでSheet1のセルをアクティブにすると右側に下向き▼が表示されますので、そこをクリック!
これで希望に近い形にならないでしょうか?
Excel2007の場合は↓のURLが参考になるかもしれません。

http://www.eurus.dti.ne.jp/~yoneyama/Excel2007/excel2007-ny_kis2.html

尚、同一Sheetに「名簿表」を作成する場合は名前定義する必要はなくて
「元の値」の右側の四角をクリックし、リスト表示したいセルをそのまま範囲指定すればOKです。

以上、お役に立てば良いのですが・・・m(_ _)m

こんばんは!
当方使用のExcel2003での一例です!

↓の画像のようにSheet2に名簿表を作成しておきます。
画像ではSheet2のA2セル以降を範囲指定 → 名前ボックスに仮に「名簿」と入力しOK
これで範囲指定したセルが「名簿」と名前定義されましたので、

Sheet1のリスト表示させたいセルを範囲指定 → メニュー → データ → 入力規則
→ リスト → 「元の値」の欄に
=名簿
としてOK

これでSheet1のセルをアクティブにすると右側に下向き▼が表示されますので、そこをクリック!
これで希望に近い形にならない...続きを読む

QA1 B1 A2 B2 A3 B3 の順に入力ができるようにしたい。

A1 B1 A2 B2 A3 B3 の順に入力ができるようにしたい。

A1 B1
A2 B2
A3 B3

の入力をするときに、
A1 B1 A2 B2 A3 B3 の順に入力ができるようにしたい。
ENTERを押すたびに、
A1の次はB1入力でき、
B1の次はA2入力できるように設定したい。

どうすればいいですか?
よろしくお願いします。

Aベストアンサー

> A1 B1 A2 B2 A3 B3 の順に入力ができるようにしたい。


次のように操作してみて下さい。


1) 「Ctrl」キーを押しながら「A1」「B1」「A2」「B2」「A3」「B3」の順にクリックして、最後にもう一度「A1」をクリックします。
2) 「A1」~「B3」が選択された状態で、「数式バー」の左端にある「名前ボックス」をクリックして、例えば、「入力セル」などと分かりやすい名前を付けます。


使い方:
1) 「名前ボックス」の▼を押して、プルダウンで表示される名前を付けた「入力セル」をクリックします。
2) 「A1」~「B3」が選択されます。
3) アクティブになっている「A1」に入力した後「Enter」キーを押すと、押すたびに、アクティブセルが、「B1」「A2」「B2」「A3」「B3」の順に移動します。

Qエクセル(Excel) 納品書の作り方【画像修正版

昨日http://oshiete.goo.ne.jp/qa/7348426.htmlで質問させていただき、詳しくご回答いただき少し進んだのですが、状況が変わったので改めて質問させていただきます。

■エクセル(Excel)で納品書の作成をしています。
シート1に納品書、シート2に商品マスタ(一覧)を作っていて、シート2の一覧を反映させて
納品書に番号を打ち込むだけで、商品名・単価までが出るシステムを作りたいのですが、
昨日のご回答の中の「VLOOKUP」?を入れて、自分なりにマス目の数字を変えてやってみたのですが
反映されずN/?のようなエラーになってしまいます。

※画像が見にくかったのでシート<CENTER></CENTER>だけにしました。

1、上記のように、シート2との関連付けの係数を、写真の場合の数字で教えてください。

2、合計と、合計から20%を引いた数値を割り出す関数も、写真の数字で御願いします。

宜しくご教授お願い致します。

Aベストアンサー

こんばんは!
前回投稿した者です。

当方もかなり古い(人間も古い!なぁ~んちゃって!)Excel2003を使用しています。
↓の画像のようにSheet2にデータを作成しておきます。

#N/A というエラーは、「検索値」がない!ということですので
お示しの画像のB列にSheet2のA列にないデータを入力するとそういったエラーが表示されます。

画像のセル配置ですと
C4セルに
=IF($B4="","",VLOOKUP($B4,Sheet2!$A:$C,COLUMN(B1),0))
(「$」マークの位置に気を付けてください)
という数式を入れD4セルまでオートフィルでコピー!
そのまま最後の24行目までコピーしておきます。

F4セルには
=IF(COUNTBLANK(B4:E4),"",D4*E4)
という数式を入れ、F24までオートフィルでコピー!

これでB列に商品番号を入力すればSheet2のデータが反映され、
E列に数量を入力でF列に金額が表示されると思います。

最後に合計金額のF26セルは
=IF(COUNT(F4:F24),SUM(F4:F24),"")
手数料のF27セルは
=IF(F26="","",F26*0.2)

これで何とか形にならないでしょうか?

※ 振込金額の欄は不明ですので手を付けていません。

参考になりますかね?m(_ _)m

こんばんは!
前回投稿した者です。

当方もかなり古い(人間も古い!なぁ~んちゃって!)Excel2003を使用しています。
↓の画像のようにSheet2にデータを作成しておきます。

#N/A というエラーは、「検索値」がない!ということですので
お示しの画像のB列にSheet2のA列にないデータを入力するとそういったエラーが表示されます。

画像のセル配置ですと
C4セルに
=IF($B4="","",VLOOKUP($B4,Sheet2!$A:$C,COLUMN(B1),0))
(「$」マークの位置に気を付けてください)
という数式を入れD4セルまでオートフィルで...続きを読む

Q=SUM(ROUND(A1,0),ROUND(A3,0),ROUND(A10,0))をもっと簡単に

エクセル200です。
A1、A3、A10の各セルにある数値を四捨五入してから合計するのに
=SUM(ROUND(A1,0),ROUND(A3,0),ROUND(A10,0))
でできるのはもちろん存じておりますが、もっと簡単に書く方法はないでしょうか?

A2、A4からA9までのセルが空白であれば
=SUMPRODUCT(ROUND(A1:A10,0)*1)
A2、A4からA9までのセルが文字列であれば
{=SUM(IF(ISNUMBER(A1:A10),ROUND(A1:A10,0),""))}(配列数式)
でできるのですが、数値であるために使えません。

上記のA1、A3、A10はあくまで一例で、実際は同一列ではありますがもっとセル数が多いのです。そのため簡単に書ける方法を探しています。
よい方法があればご教示くださいませ。

Aベストアンサー

雨の鹿児島から、おはようさんです。

これが簡単かどうかは別として、、、

=SUMPRODUCT((ROW(A1:A10)={1,3,10})*ROUND(A1:A10,0))
 
以上です。
 

Qエクセル(Excel) 納品書の作り方【改めて】

昨日http://oshiete.goo.ne.jp/qa/7348426.htmlで質問させていただき、詳しくご回答いただき少し進んだのですが、状況が変わったので改めて質問させていただきます。

■エクセル(Excel)で納品書の作成をしています。
シート1に納品書、シート2に商品マスタ(一覧)を作っていて、シート2の一覧を反映させて
納品書に番号を打ち込むだけで、商品名・単価までが出るシステムを作りたいのですが、
昨日のご回答の中の「VLOOKUP」?を入れて、自分なりにマス目の数字を変えてやってみたのですが
反映されずN/?のようなエラーになってしまいます。

※画像が貼り付けてあります。商品名は1番以外伏せさせていただいています。
くっつけてありますが、左側がシート1・右側がシート2です。

1、上記のように、シート2との関連付けの係数を、写真の場合の数字で教えてください。

2、合計と、合計から20%を引いた数値を割り出す関数も、写真の数字で御願いします。

宜しくご教授お願い致します。

Aベストアンサー

画像がいまいちよく見えないのですが、納品書の項目は左から、No、商品番号、商品名、単価、数量、金額でいいのでしょうか(名前は多少違っていても意味があっていればもんだいないです)

でしたら、
C1セルに=IF(ISBLANK(B2),"",VLOOKUP(B2,Sheet2!$A$2:$C$200,2,FALSE))
D1セルに=IF(ISBLANK(B2),"",VLOOKUP(B2,Sheet2!$A$2:$C$200,3,FALSE))
E1セルは空白で
F1セルに=IF(D2="","",D2*E2)
といれて、C1からF1までをコピーしてその下の行にタテに貼り付ければ出来ますよ。
おそらくエラーが出たのは、コピーしたときにVLOOKUP関数の最初のセルの指定がずれてしまっているのでは無いかと思いますよ。     

Qエクセル Aの日付以降の規則的な日付を表示

よろしくお願い致します。

a1のセルにある日付から2ヶ月後以降3年未満の「年」と「月」を表示したいのです。

つまり、34ヶ月分の「年月」をag3~ag14、aj3~aj14、am3~am12に表示したいです。
a1が09/07/10であればag3に09/09ag4に09/10・・・という具合です。

表示するセルが断続的なのですが、自働で表示することは可能でしょうか。

またa1を基準にして
今度はag30~ag34に

3年分の7月と12月を表示したいです。

つまり、a1が09/07/10であればag30に09/07ag31に09/12、ag32に10/07
という具合です。

こんなことって可能でしょうか?

Aベストアンサー

セルag3
=TEXT(DATE(YEAR($A$1),MONTH($A$1)+ROW()-1,1),"yy/mm")
~ag14までコピー

セルaj3
=TEXT(DATE(YEAR($A$1)+1,MONTH($A$1)+ROW()-1,1),"yy/mm")
~aj14までコピー

セルam3
=TEXT(DATE(YEAR($A$1)+2,MONTH($A$1)+ROW()-1,1),"yy/mm")
~am12までコピー

セルag30
=TEXT(DATE(YEAR($A$1),7,1),"yy/mm")

セルag31
=TEXT(DATE(YEAR($A$1),12,1),"yy/mm")

セルag32
=TEXT(DATE(YEAR($A$1)+1,7,1),"yy/mm")

セルag33
=TEXT(DATE(YEAR($A$1)+1,12,1),"yy/mm")

セルag34
=TEXT(DATE(YEAR($A$1)+2,7,1),"yy/mm")

参考まで

Qエクセル2007でプルダウンで選んだものに反応

Excel2007でプルダウンで選んだものに反応して隣のセルが自動入力される方法(エクセル2007)
A1をプルダウンで「猫」「犬」から選べるようにし、「猫」を選んだ場合B1に自動に「111」が、「犬」を選んだ場合B1に自動に「222」と入力されるようにしたいです。
ご教授の程、宜しくお願いします。

Aベストアンサー

VLOOKUP関数での方法です。
(1)別シートに入力文字列と対応コード表を作成。(仮にSheet2のA:B列範囲で順不同)
(2)B1に=IF(COUNTIF(Sheet2!A:A,A1),VLOOKUP(A1,Sheet2!A:B,2FALSE),"")を設定
   入力文字列が存在しない場合は空白としています。

Qエクセルで A1+B1=C1、A2+B2=C2と順番に答えCを出し、数

エクセルで A1+B1=C1、A2+B2=C2と順番に答えCを出し、数字が少ない順番に並べるには、どのようにすれば良いのでしょうか。検索しましたが、検索方法もわからず悩んでおります(以前 一度教えて貰いましたが、思い出せません)。書式並びにフリーのテンプレートがありましたら教えて下さい。出来ればそれを保存して、1つ1つ見比べたいとも思っています。不純なドウキでして競馬の結果を並べてデータにしたいのですが。

Aベストアンサー

 まず、C1セルに次の数式を入力して下さい。

=IF(COUNT($A1:$B1)=2,$A1+$B1,"")

 次に、D1セルに次の数式を入力して下さい。

=IF(ROW(D1)>COUNT($C:$C),"",SMALL($C:$C,ROW(D1)))

 そして、C1~D1の範囲をコピーして、同じ列の2行目以下に貼り付けると良いと思います。


人気Q&Aランキング

おすすめ情報