ユーザーフォームに入力したデータを保持する方法

VBA初心者です。いろいろ調べて徐々に進められていますが、、
こちらもなかなか見つからなかったので質問させていただきます。

現在、ユーザーフォームにテキストボックスをいくつか配置し、
さまざまな計算などをさせて、最終的にエクセルシートに反映させる。
といったことが出来るようにプログラムをしています。

ユーザーフォームのテキストボックスに一度入力したものを、
エクセルシートを閉じるまで残すことはできるでしょうか？

一度、×ボタンで閉じてしまうと、次に呼び出したときには初期の状態になってしまいます。

ユーザーフォームに入力し、エクセルシートで確認、
その後 再度ユーザーフォーム呼び出して修正する
といった作業をするために、一度入力したものが消えないようにしたいです。

よろしくお願いいたします。

No.4 ベストアンサー 回答者： kybo 回答日時： 2012/03/26 14:26

閉じるボタンで閉じるとき、Hideで閉じればいいだけの様な気がします。

UserFormのモジュールに記述します。

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode <> 1 Then
　Cancel = True
　Me.Hide
End If
End Sub

この回答へのお礼

回答して頂いてありがとうございます。
希望している通りの動きになりました。

お礼日時：2012/03/26 17:48

No.3 回答者： M-SOFT#2 回答日時： 2012/03/26 03:19

こんばんは。

シートにデータを保存する方法ですが、ControlSourceプロパティを使うのはどうでしょうか。

このプロパティは、Sheet1!A1　と言うように設定し、設定したセルにValueプロパティの値を保存できます。

この回答へのお礼

回答して頂いてありがとうございました。

お礼日時：2012/03/26 17:50

No.2 回答者： mitarashi 回答日時： 2012/03/25 20:16

#1です。

そういう予感はしたのですが、小出し質問・ついでに質問は避けて下さい。
さて、UserForm_Terminate()の方を書き換えて下さい。
Select Caseで、valueをメンバに持たずエラーになるものや、CommandButtonの様に記録したく無いものを列挙して下さい。

Private Sub UserForm_Terminate()
Dim myControl As Control
Dim destSh As Worksheet, destRange As Range

Set destSh = ThisWorkbook.Worksheets("temp")
destSh.Cells.Clear
Set destRange = destSh.Range("A1")
For Each myControl In Me.Controls
'Debug.Print TypeName(myControl)
Select Case TypeName(myControl)
'valueをメンバに持たずエラーになるものや、記録したくないものを列挙
Case "Frame", "Label", "CommandButton"

Case Else
destRange.Value = myControl.Name
destRange.Offset(0, 1).Value = myControl.Value
Set destRange = destRange.Offset(1, 0)
End Select
Next myControl
End Sub

この回答へのお礼

小出し質問してすいません。
非常に勉強になりました。
ありがとうございました。

お礼日時：2012/03/26 17:45

No.1 回答者： mitarashi 回答日時： 2012/03/25 18:07

「temp」という名前のワークシートに保持する方法です。

ワークシートを閉じても保存されてしまいますが、気に入らなければWorkbook_BeforeCloseででも保存データをクリアして下さい。ご参考まで。
Private Sub UserForm_Initialize()
Dim tempSh As Worksheet, tempRange As Range, myRow As Range

Set tempSh = ThisWorkbook.Worksheets("temp")
Set tempRange = tempSh.Range("A1").CurrentRegion
If tempRange.Cells.Count = 1 Then Exit Sub
For Each myRow In tempRange.Rows
Me.Controls(myRow.Cells(1).Value).Value = myRow.Cells(2).Value
Next myRow
End Sub

Private Sub UserForm_Terminate()
Dim myControl As Control
Dim destSh As Worksheet, destRange As Range

Set destSh = ThisWorkbook.Worksheets("temp")
destSh.Cells.Clear
Set destRange = destSh.Range("A1")
For Each myControl In Me.Controls
If TypeName(myControl) = "TextBox" Then
destRange.Value = myControl.Name
destRange.Offset(0, 1).Value = myControl.Value
Set destRange = destRange.Offset(1, 0)
End If
Next myControl
End Sub

この回答へのお礼

ご回答ありがとうございます。
保存することができました。
すいませんがついでに、チェックボックスや、オプションボタンの情報も残すには
どのようにすればいいのでしょうか？

もし、よろしければご指導ください。

お礼日時：2012/03/25 19:00