エクセル2010 特定の用語を含むものにフラグ

よろしくお願いします。
エクセル2010で特定の用語を含むものにフラグを立てていきたいです、

たとえば

　　B列　　　　　　　　　　　　　C列

○○株式会社　　　　　　　　　1
△△医療法人 2
NPO×× 3
社会医療法人○◆◆ 4
株式会社☆☆　　　　　　　　　1
医療法人×××　　　　　　　２


というように、株式会社を含む項目には横のセルで1を
医療法人を含む項目には２を
といった感じです。
if文か何かを使って簡単にできないでしょうか？

株式会社という用語が頭にあっても後にあってもフラグは1となるようにしたいのです。
データが多いため、式をコピーすることで簡単にフラグができるようにしたいです。

アイデアを教えてください。
よろしくお願いします。


　

No.2 ベストアンサー 回答者： JazzCorp 回答日時： 2013/01/14 17:52

空白文字無視、、、

Ｃ２：
=IF(LEN(SUBSTITUTE(TRIM($B7)," ",""))=LEN(SUBSTITUTE(SUBSTITUTE(TRIM($B7)," ",""),"株式会社","")),IF(LEN(SUBSTITUTE(TRIM($B7)," ",""))=LEN(SUBSTITUTE(SUBSTITUTE(TRIM($B7)," ",""),"医療法人","")),"",2),1)
以下、コピー

この回答へのお礼

回答ありがとうございます。

お礼日時：2013/02/16 23:22

No.4 回答者： keithin 回答日時： 2013/01/14 18:02

Ｃ列を列選択

セルの書式設定の表示形式のユーザー定義で
#
と設定しておきます

Ｃ１に
=IF(ISNUMBER(FIND("株式会社",A1)),1) + IF(ISNUMBER(FIND("医療法人",A1)),2)
以下コピー
のように。

必要に応じてどんどん＋で、つなげていけば何パターンでも出来ます。

この回答へのお礼

回答ありがとうございます。
参考になります。

お礼日時：2013/02/16 23:13

No.3 回答者： tsubuyuki 回答日時： 2013/01/14 18:02

> 株式会社を含む項目には横のセルで1を

> 医療法人を含む項目には２を


ＩＦ関数単体ではワイルドカードを受け付けてくれませんので、

ＣＯＵＮＴＩＦを使ってあいまい検索するなら
　Ｃ１セル：=IF(COUNTIF(B1,"*株式会社*")>0,1,IF(COUNTIF(B1,"*医療法人*")>0,2,""))

ＦＩＮＤ関数も意外と使えます。
　Ｃ１セル：=IF(ISERROR(FIND("株式会社",B1))=FALSE,1,IF(ISERROR(FIND("医療法人",B1))=FALSE,2,""))

まぁ、この二択ならＣＯＵＮＴＩＦをオススメします。



ちなみにこのままだと「社会医療法人」にも「２」が立ちます。
それは困る、と言うのであれば、「探す順番」を組み替えてやってくださいませ。

ヒント：ＩＦを重ねると「前から順に」考えていきます。

この回答へのお礼

回答ありがとうございます。

お礼日時：2013/02/16 23:21

No.1 回答者： JazzCorp 回答日時： 2013/01/14 17:37

Ｃ２：

=IF(LEN($B2)=LEN(SUBSTITUTE($B2,"株式会社","")),IF(LEN($B2)=LEN(SUBSTITUTE($B2,"医療法人","")),"",2),1)
以下、コピー