エクセルVBA　御教示下さい。

Question

一括で、不要な行の行全体を削除したいと考えています。
そのため、削除したい行には列Zに関数で２以上の数字を表示さています。
この列Zに数字の２以上が入っている行は全て削除するマクロをご教示ください。
なお、データは行A３からZ列までの１２００行ほどあります。
どなたか、よろしくお願いいたします。

tsubuyuki · Accepted Answer

＃２さん、どうやら、Ｚ列がキーのようです。
更にいうと、データは３行目以降の様子です。

Sub 行の削除()
Dim gyou As Long
For gyou = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row To 3 Step -1
If Range("Z" & gyou).Value >= 2 Then
Range("Z" & gyou).EntireRow.Delete
End If
Next gyou
End Sub

ところで、１２００行あるとそれなりに時間がかかりそうですね。
（と言っても数秒でしょうけど。体感で５～７秒くらいかな。）

なので、私からの提案はオートフィルタを使って。
２行目が「項目行」で、３行目以降にデータがあるとして

Sub Sample()
Dim myRng As Range, myRow As Long
　　　　If ActiveSheet.AutoFilterMode = True Then Range("A3").AutoFilter
　　　　Set myRng = Range("A3").CurrentRegion
　　　　myRow = myRng.Rows.Count + 1
　　　　myRng.AutoFilter Field:=26, Criteria1:=">=2"
　　　　　　　　On Error Resume Next
　　　　　　　　Rows("3:" & myRow).SpecialCells(xlCellTypeVisible).Delete
　　　　　　　　On Error GoTo 0
　　　　myRng.AutoFilter
End Sub

こんな感じで。
（エラー処理が手抜きですけど（笑）。）

手動でフィルタをかけて、それを削除、としても一瞬ですから、
マクロを使わなくても結果（所要時間）はそんなに変わらないですけどね。

tsubuyuki · Answer

ＶＢＡはわからん！な場合のために、手動で一気にやる方法も。
・・・と言っても、フィルタをかけるだけですが。

やはり前提として「２行目には“項目名行”がある」としています。
（無い場合は、３行目にダミーで“項目名行”を作ってやるとやりやすいです。）
そんなこんなで、Ａ３セルにフォーカスを置き（選択した状態で）

（２００７以降の場合）
リボンのデータタブ⇒フィルタ　を選択。
各項目名のセルに▼がつくので、Ｚ列の▼をクリックしてプルダウン。
数値フィルタ⇒指定の値以上　を選択し、ダイアログ内で「２以上」と設定し、ＯＫ。

（２００３以前の場合）
データメニュー⇒フィルタ⇒オートフィルタ　を選択
各項目名のセルに▼がつくので、Ｚ列の▼をクリックしてプルダウン。
「オプション」を選択し、「２以上」と設定してＯＫ。

（ここから共通）
フィルタがかかったら「項目名行の１行下に表示されている行」を選択。
Ｃｔｒｌ＋Ｓｈｉｆｔ＋（キーボードの）↓キーで、表示されている行を全選択。
反転している中で右クリック⇒削除　で行削除。
（または「Ｃｔｒｌ＋テンキーボードの－（マイナスボタン）」でも行削除できます。）
上記と同様のやりかたでフィルタを解除。

以上で、「Ｚ列が２以上」の行だけを削除することが出来ます。
＃３での回答は、コレをマクロに書いてみただけです。

参考までに。

以下、私信で申し訳ありませんが・・

＃５さん。
いえ、私も「２行目に“項目名行”が無い」可能性は視野外でした。
そうすると、「３行目にダミー行を入れ、最後に消す」手法が有効ですね。
「なるほど」な感覚です。

tom04 · Answer

No.4です。

投稿後に気づきました。
No.3さんの後者のやり方とほぼ同じやり方になっていました。

なおかつエラー処理をしていませんので、Z列に「2以上」のデータがない場合は
マクロが止まってしまいます。
どこか最初の方に
＞On Error Resume Next
の1行を追加してもらえれば問題ないと思いますが・・・

それらを考慮すると
No.3さんの方が良いですね！

どうも失礼しました。m（_ _）m

tom04 · Answer

こんにちは！
1200行だというコトですので、ループさせてもさほど時間はかからないと思いますが、
一気に削除する方法です。

Sub 行削除()
    Dim endRow As Long
    Rows(3).Insert
    Range("Z3") = "ダミー"
    endRow = ActiveSheet.UsedRange.Rows.Count
    Range("Z3").AutoFilter field:=1, Criteria1:=">=2"
    Rows(3 & ":" & endRow).SpecialCells(xlCellTypeVisible).Delete shift:=xlUp
    Rows(3).Delete
    ActiveSheet.AutoFilterMode = False
End Sub

こんな感じではどうでしょうか？m（_ _）m

okormazd · Answer

#1さん、連続してるとまずいから、下からね。

Sub 行の削除()
Dim gyou As Long
For gyou = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
If Range("a" & gyou).Value >= 2 Then
Range("a" & gyou).EntireRow.Delete
End If
Next gyou
End Sub

KURUMITO · Answer

例えば次のようなマクロにします。

Sub 行の削除()
Dim gyou As Long
For gyou = 1 To ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
If Range("Z" & gyou).Value >= 2 Then
Range("Z" & gyou).EntireRow.Delete
End If
Next gyou
End Sub

エクセルVBA 御教示下さい。

＃２さん、どうやら、Ｚ列がキーのようです。

ＶＢＡはわからん！な場合のために、手動で一気にやる方法も。

No.4です。

こんにちは！

#1さん、連続してるとまずいから、下からね。

例えば次のようなマクロにします。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

エクセルVBA　御教示下さい。