エクセルマクロ行削除

エクセル2013です。
以下の行削除マクロを作りました。
取得した
最終行が２０行目として
最終列がＺ列として
セル　Z20　の値が
１以上なら問題なく動作するのですが
セル　Z20　の値が　0　だとループして終了しません。
どこを修正しても、思うように動作しません。
どこを修正すれば、いいのでしょうか？
よろしくお願いします。


Sub 行削除()

Dim 最終行
Dim 最終列
Dim 対象行

最終列 = Cells(8, Columns.Count).End(xlToLeft).Column '8行目の最終列を取得
最終行 = Cells(Rows.Count, 1).End(xlUp).Row 'A列の最終行を取得

Application.ScreenUpdating = False '画面切替停止

For 対象行 = 10 To 最終行
If Cells(対象行, 最終列) = 0 Then
Rows(対象行).Delete
最終行 = 最終行 - 1 '削除により最終行が１行減ったので最終行の値を1行減らす
対象行 = 対象行 - 1 '削除により対象行が1行繰り上がったので対象行の値を1行減らす
Else
End If
Next 対象行
Application.ScreenUpdating = True '画面切替停止解除

End Sub

No.1 ベストアンサー 回答者： satoron666 回答日時： 2014/07/28 18:18

Z20??

とりあえず、上手くいかない場合F8で1行ずつ、数値の流れを見ていってください。

対象行が最終行より大きい場合とか　（対象行=10　最終行=8)
特に考えなくていいんでしょうか？

対象行を増やして、最終行までいけば終了とForループを組んでいるのに
Forループのなかで、最終行と対象行をマイナスしてます。
ループするのは当たり前な気がします。

やりたいことはいまいち分かりませんが、
このプログラムの場合、最終行から削除していったほうが良いと思います。
（そうすれば、最終行-1、対象行-1をする必要は無くなる為）

この回答への補足

>とりあえず、上手くいかない場合F8で1行ずつ、
>数値の流れを見ていってください。

はい。それでやって、つまづきました。
実験したデータは
A列からZ列、8行目から20行目まで
すべてのセルに値が有ります。
8行目が各列の先頭データなので、8行目の最終列を取得
でそれがＺ列。
A列の最終行は20行目。
セルZ8からZ20までを上から順に見ていき
値が0だったらその行は行削除です。
マクロを走らせる前のZ列の最終行であるセルZ20の
値が１とか２とかなら、終了したのに
セルZ20の値が0の場合ははまり込んでしまい
F8で調べて1行づつ調べていったら、
Z列で値が有る最後の行20行目（F8でたどり着いた時は、
すでに数行削除されて14行目になっている）
の値が0だから行削除されます。
すると、最終行と対象行の値が思っている物と違い
ループするのがわかりました。
いくら考えても成り立たないので質問しました。
申し訳ありません。

補足日時：2014/07/28 19:37

この回答へのお礼

おもいだしました。
行削除は最終行から上でした。
ありがとうございます。

お礼日時：2014/07/28 19:38

No.3 回答者： High_Score 回答日時： 2014/07/29 20:15

最終行を取得した後、一旦For Nextループが始まると、いくら最終行を変更しても、ループの終着点は変わりません。

対象行は変更可能です。

この回答へのお礼

はい。f8で調べてそれがわかりました。
ありがとうございます。

お礼日時：2014/07/30 21:13

No.2 回答者： tom04 回答日時： 2014/07/28 19:01

こんばんは！

No.1さんが仰っているように行（列）削除・挿入の場合は
最終行・最終列から逆に操作するほうが一般的です。

お示しのコードに手を加えるとすると

Sub 行削除()
Dim 最終行 As Long
Dim 最終列 As Long
Dim 対象行 As Long
最終列 = Cells(8, Columns.Count).End(xlToLeft).Column
最終行 = Cells(Rows.Count, "A").End(xlUp).Row
For 対象行 = 最終行 To 10 Step -1
If Cells(対象行, 最終列) = 0 Then
Rows(対象行).Delete
End If
Next 対象行
End Sub

こんな感じでしょうか。

※　余計なお世話かもしれませんが、データ量が極端に多い場合はループさせるとかなりの時間を要しますので
一気に削除する方法の一例です。
尚、8行目は項目行で空白セルがなく最終列まで項目が入っているとします。
（9行目も何らかのデータが入っているとする）

Sub Sample1()
Dim lastRow As Long, lastCol As Long
lastRow = Cells(Rows.Count, "A").End(xlUp).Row
lastCol = Cells(8, Columns.Count).End(xlToLeft).Column
Range("A8").AutoFilter field:=lastCol, Criteria1:=0
On Error Resume Next '←念のため
Rows(10 & ":" & lastRow).SpecialCells(xlCellTypeVisible).Delete
AutoFilterMode = False
End Sub

これでも同様の結果になると思います。m(_ _)m

この回答へのお礼

ありがとうございます。
no.1の方からのアドバイスで
下からというのを思い出し
自力で作成できました。

お礼日時：2014/07/30 21:14