3営業日後を取得と行データの消去

エクセル2013

D列に入力があると同行のA列に日付(時間)が入力されるように設定してあります。
(B列にはユーザー名)
その時、A列の日付を基準に、E列に 3営業日後の日付を入力させるには
どのようなマクロを組んだら宜しいでしょうか？

また、入力済行のD列を消去（空白）した場合、該当行に入力されている全データを消去するには
どうしたら宜しいでしょうか？(行削除ではありません)

下記、既マクロが現在、組まれているものです。
宜しくお願い致します。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Rng As Range
Dim TgRng As Range
Set TgRng = Intersect(Range("D:D"), Target)
If Not TgRng Is Nothing Then
Application.EnableEvents = False
For Each Rng In TgRng
Rng.Offset(, -3).Value = Now
Rng.Offset(, -2).Value = LoginName
Next
Application.EnableEvents = True
End If
Set TgRng = Nothing
End Sub

No.1 回答者： tom04 回答日時： 2014/10/18 21:38

こんばんは！

そのままワークシート関数を使用すれば良いと思います。
E列の表示形式はあらかじめ「日付」で設定しておいてください。

＞Rng.Offset(, -2).Value = LoginName
で変数「LoginName」が定義が設定されていませんので、↓のコードでは入れていません。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Rng As Range
Dim TgRng As Range
Set TgRng = Intersect(Range("D:D"), Target)
If Not TgRng Is Nothing Then
Application.EnableEvents = False
For Each Rng In TgRng
If Rng <> "" Then
Rng.Offset(, -3).Value = Now
'▼WORKDAY関数をそのまま使用
Rng.Offset(, 1) = WorksheetFunction.WorkDay(Rng.Offset(, -3), 3)
Else
Rng.EntireRow.ClearContents
End If
Next Rng
Application.EnableEvents = True
End If
Set TgRng = Nothing
End Sub

こんな感じでよいのでしょうか？m(_ _)m

この回答への補足

早速の回答、ありがとうございます。
3営業日後の日付ですが、祝日や会社規定の休業日等も考慮するためには
どのようにしたら宜しいでしょうか？

補足日時：2014/10/18 22:23

No.2 ベストアンサー 回答者： tom04 回答日時： 2014/10/18 23:01

No.1です。

＞祝日や会社規定の休業日等も考慮するためには・・・
Workday関数にそのまま「休日」のデータが使用できます。
ただし、あらかじめ祝日（休日）のデータを作成しておく必要があります。

仮にSheet2のA1～A20に祝日・会社規定の休日のシリアル値データを作成した場合は
↓のコードとなります。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Rng As Range
Dim TgRng As Range
'▼myRngという変数を追加
Dim myRng As Range
'▼Sheet2のA列以降の祝日（会社規定の休日）の表を作成しておく
'仮にA1～A20セルに休日のシリアル値がある場合
Set myRng = Worksheets("Sheet2").Range("A1:A20")
Set TgRng = Intersect(Range("D:D"), Target)
If Not TgRng Is Nothing Then
Application.EnableEvents = False
For Each Rng In TgRng
If Rng <> "" Then
Rng.Offset(, -3).Value = Now
'▼WORKDAY関数の最後に myRng を追加
Rng.Offset(, 1) = WorksheetFunction.WorkDay(Rng.Offset(, -3), 3, myRng)
Else
Rng.EntireRow.ClearContents
End If
Next Rng
Application.EnableEvents = True
End If
Set TgRng = Nothing
End Sub

※　上記コード内の「myRng」は実状に合わせてください。

※　実は前回投稿後、気になっていたのですが。
＞3営業日後の日付
とは「土日を除く3営業日」となりますので、仮に御社が土日も営業している場合は
別の方法を考える必要があります。m(_ _)m

この回答へのお礼

完璧です。

弊社は土日完全休日です。
ご心配いただきありがとうございました。

お礼日時：2014/10/18 23:28