プロが教えるわが家の防犯対策術!

株の取引き手数料の計算をエクセルで簡単に確認したいのですが、取引きしている証券会社の手数料がちょっと細かくて私の乏しい知識では計算式が難しくて表を作成できません。
下の一覧が手数料ですが、これだけの条件を例えばA1のセルに取引き金額を入力するとB1のセルに手数料を表示することは可能でしょうか?
毎日1、2回の取引きをしていますが、いちいち電卓叩いて損益を計算しています。
普段はせいぜい1行目から3行目くらいまでしか使わないんですが、5行目までくらいと小数点以下切り捨てまでの計算をA1、B1のセルだけに表示するにはどのようにしたらいいでしょうか。
よろしくお願いします。
OS : windows7 professional-64bit
Excel2007


    ~ 1,000,000円 1.242% 最低2700円 ×1.08
1,000,001 ~ 2,000,000円 0.9180% + 3,240円 ×1.08  
2,000,001 ~ 3,000,000円 0.8910% + 3,780円 ×1.08
3,000,001 ~ 4,000,000円 0.8424% + 5,238円 ×1.08
4,000,001 ~ 5,000,000円 0.8316% + 5,670円 ×1.08
5,000,001 ~ 10,000,000円 0.7128% + 11,610円 ×1.08
10,000,001 ~ 30,000,000円 0.5724% + 25,650円 ×1.08
30,000,001 ~ 50,000,000円 0.2700% + 116,370円 ×1.08
50,000,001 ~ 0.0864% + 208,170円 ×1.08
小数点以下切り捨て  

このQ&Aに関連する最新のQ&A

A 回答 (3件)

#1です。


取引額がA1に入っているなら
=MAX(2700,ROUNDDOWN((A1*INDEX({1.242,0.918,0.891,0.8424,0.8316,0.7128,0.5724,0.27,0.0864},MATCH(A1,{1,1000001,2000001,3000001,4000001,5000001,10000001,30000001,50000001},1))*0.01+INDEX({0,3240,3780,5238,5670,11610,25650,116370,208170},MATCH(A1,{1,1000001,2000001,3000001,4000001,5000001,10000001,30000001,50000001},1)))*1.08,0))
で手数料は求まりますけど,自分が理解できない式は使わないほうがいいと思う。
    • good
    • 0
この回答へのお礼

F272様、ありがとうございました。
確かに理解できる領域を超えていました。
こういう式で求めるとは思いませんでした。
もう諦めて1行毎に入力していこうと思っていたのですが、
おかげさまで自分にあった管理表ができそうです。
本当にありがとうございました。

お礼日時:2014/12/29 19:07

私には、あなたの書いた表らしきものの意味がわかりません。


取引金額からどのようにして手数料を計算できるのでしょう?

この回答への補足

ご回答ありがとうございます。

これは株を売買した時の証券会社の手数料の一覧表です。

ある証券会社の、公開されている手数料の一覧表です。



例えば取引額が500,000円だとしたら

500,000*0.01242*1.08  手数料が6,706円になります。

1,800,000円でしたら

(1,800,000*0.00918+3,240)*1.08 で21,345円、

2,500,000円でしたら

(2,500,000*0.00891+3,780)*1.08 で28,139円となります。

ネット証券などでしたら手数料がとてもシンプルなので頭に入るんですが、ここまで細かいと表を見て0.00????などと計算しなくてはかかった手数料がわからなくて家計簿にも書けないんです。

おわかりいただけましたらどのようにすればいいのか教えていただけますか?

よろしくお願いします。

補足日時:2014/12/28 21:25
    • good
    • 0

縦に9通りの式を作ります。

1ー9列しよう。
横に、a,b,c,d,e,fまでの列を使います。
aに、0ー1000万円までの式、bに1・242%、cに2700、dに1.08といれFに、Excelの方式で、式を書く。

Fに例えばですが、=((g2×b2)+(3240×d2))と書けば、値は出ます。
g2は取引金額を入れ忘れました。

以下、同じように式を作っておけばいい。小数点切り捨ての場合は、最初のイコールの後に、切り捨て関数を入れる必要があります。

一行目は項目名に使いますから、二列目から式を作ります

この回答への補足

ご回答ありがとうございます。
すいません、1行毎の計算式は大丈夫なんですが、全体を一つにまとめる計算式を答えのセルにどうやってまとめられるかです。
取引き額のセルは大小に関係なく一つのセルだけで、その手数料もひとつのセルだけにできればと思っているんですが。

例えば、G1が取引額、F1が答えだとします。

G1に取引額を500,000円と入力したとします。
そうすると
500,000*0.01242*1.08  F1は6,706円になります。

同じくG1に1,800,000円と入力したとします。
そうすると条件が変わりますから
(1,800,000*0.00918+3,240)*1.08 この時F1のセルに21,345円、

G1に2,500,000円だったら
(2,500,000*0.00891+3,780)*1.08 同じくF1に28,139円、

取引金額が変わると計算する数値が変わってきますので、同じセルで表示するにはIFの関数とか使わないとならないのではと思うんですが、そうしてそれぞれの条件の数式を一つにするとかなり長い関数になってしまうと思います。
関数そのものもわからないんですが、組み合わせた関数が長くなってしまう時のやり方がどうしてもわからないので教えていただけますか。
よろしくお願いします。

補足日時:2014/12/28 21:10
    • good
    • 0

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

Qエクセル関数で手数料計算

エクセル関数で手数料の計算を自動化したいのですが
うまく関数が作れません。
宜しくご教授お願い致します

0円~6000円は手数料1500円
6001円~50000円までは25%
50001円~100000円までは23%
100001円以上は20%です。

よろしくお願い致します

Aベストアンサー

スマートではありませんが、IF関数だけで表現すると下記のような数式になります。

=IF(A1="","",IF(A1<=6000,1500,IF(A1<=50000,A1*0.25,IF(A1<=100000,A1*0.23,IF(A1>100000,A1*0.2)))))

ご参考まで。

Q自分のEXCELに株価を自動的に取り込みたい!

パソコンを使って趣味の株取引をしています
EXCELでプログラムを作り売買を決めていますが、対象は30銘柄です

その銘柄の時価を手入力でセルにインプットしています
この手入力が大変煩わしいのです

株価が変わった時、もしくは一定時間ごとに私のシートの指定したセルに株価を自動的に入力してくれるプログラム、またはサービスはありませんか?


目的】時価入力が頻繁で大変だから自動化したいのです  シート内のセルではなくファイルの中に書き込んでおいてくれても結構です

Aベストアンサー

http://oshiete.goo.ne.jp/qa/5677546.html

Q株価関連情報を取得できるAPIを知りたい

株価関連の、自分用のソフトウエアを作りたいと思っています。
そこで、株価関連情報を取得できるAPIを知りたいです。

速報性はあまり気にしません。20分ディレイとか、1日ディレイとかでもいいです。

自分なりに探してみたのですが、現時点で使えるAPIはほとんど無いように思いましたので、細かいことは言いません。
xmlとか、CSVとか、rssとか、それなりにシステム的に処理できる形で
何らかの株価関連情報を取得できるAPIをご存知でしたら、何でも良いので教えて下さい!!

Aベストアンサー

楽天RSS http://marketspeed.jp/feature/rss/index.html
岡三RSS http://www.okasan-online.co.jp/ont/function/okasan_rss/
↑この2つはリアルタイムに株価を取得するものです。

株価データダウンロードサイト http://k-db.com/site/default.aspx
↑これは日足相当のデーターをCSVでダウンロードできるサイトです。

あるいは、普通のWebサイトの情報を、自分でHTMLを解析して情報を取得したりします。これはいわゆるスクレイピングと呼ばれるやりかたです。

Qexcelの関数振込手数料について

イロイロ考えてもわからないので、みなさん助けてください。
現在 下のような関数を使って値を出しているのですが、金額によってずれるので、
このようなときは、どう対処すればよいか教えてください!
振込する際に銀行の手数料を引いて振り込んでいます。
当社指定銀行だと、105円その他の銀行だと 30000円未満315 以上だと525円です。
他銀行の場合Y4に1と入力して判断させています。

F(OR(AH4="",AH4=0),"",IF($Y$4=1,IF(AH4>30000,2,1)*210)+105) ・・・AI4に此方の関数
振込手数料を計算する式なのですが、通常は問題ないのですが、
AHの金額が30525円に以下の時実際の振込額と変わってきます。

      Y         AH       AI       AJ

3    銀行識別     支払額    手数料    振込額

4      1        30458      525      29933

5

振り込むとき29933円なので手数料は、315えん・・・て事ですよね。
そこで、 (AH4>30000,2,1をAJに変えれば良いと考えたのですが、
うまく動きませんでした、
で (AH4>30000,2,1を(AH4>30525,2,1に 変えれば良いと考えましたが、
違う気がします・・・・・
どなたか 教えてください・・・・お願いします。

イロイロ考えてもわからないので、みなさん助けてください。
現在 下のような関数を使って値を出しているのですが、金額によってずれるので、
このようなときは、どう対処すればよいか教えてください!
振込する際に銀行の手数料を引いて振り込んでいます。
当社指定銀行だと、105円その他の銀行だと 30000円未満315 以上だと525円です。
他銀行の場合Y4に1と入力して判断させています。

F(OR(AH4="",AH4=0),"",IF($Y$4=1,IF(AH4>30000,2,1)*210)+105) ・・・AI4に此方の関数
振込手数料を計算する式...続きを読む

Aベストアンサー

#7,9,11です

>当社指定銀行だと、105円その他の銀行だと 30000円未満315 以上だと525円です。
どうも、これが会社の決め事のようですね。
つまり、支払額が
30,000円未満 :手数料315円
30,000円以上:手数料 525円
なんて、会社本位な。。。と思ってしまいます。
少なくとも、支払額30,314円までは315円の手数料ですみそうだし。
指定銀行なら安く済むことを考えると、一律で手間賃を引いて。。。
深読みしすぎですねm(_ _)m

AI4セルに
>IF(OR(AH4="",AH4=0),"",IF($Y$4=1,IF(AH4>30000,2,1)*210)+105)
ではなく、検証のための相対参照と30,000円以上の修正を盛り込み
=IF(OR(AH4="",AH4=0),"",IF(Y4=1,IF(AH4>=30000,2,1)*210)+105)
下へオートフィル

AJ4セル =AH4-AI4
AK4セル =IF(Y4=1,AI4-IF(AJ4<30000,315,525),0)

添付図参照 AJ9セルとAJ10セルでは振込額が逆転します(働くと損の最大)

#7,9,11です

>当社指定銀行だと、105円その他の銀行だと 30000円未満315 以上だと525円です。
どうも、これが会社の決め事のようですね。
つまり、支払額が
30,000円未満 :手数料315円
30,000円以上:手数料 525円
なんて、会社本位な。。。と思ってしまいます。
少なくとも、支払額30,314円までは315円の手数料ですみそうだし。
指定銀行なら安く済むことを考えると、一律で手間賃を引いて。。。
深読みしすぎですねm(_ _)m

AI4セルに
>IF(OR(AH4="",AH4=0),"",IF($Y$4=1,IF(AH4>30000,2,1)*210)+...続きを読む

Qエクセル関数を教えて下さい(段階的な手数料)

株の売買手数料をエクセルで簡単に計算したいんです。
以下の、手数料をエクセルの計算式で表すとどうなります
でしょうか。

10万円まで 145円/1回
20万円まで 194円/1回
50万円まで 358円/1回
100万円まで 639円/1回
150万円まで 764円/1回
3,000万円まで 1,209円/1回


IF関数とAND関数を使ってみましたが、どうしても
うまく動いてくれません。スゴ腕の方、宜しくお願いいたします!

Aベストアンサー

手数料の表をシート上に作った方が良いと思います。
添付の図ではA3:B10までが手数料の表になっています(30000001円以上の時の手数料の記載が無かったのでとりあえず9999円にしてあります)。

A1セルに売買金額が入っているとして、B1セルに↓で、手数料が出ます。
=LOOKUP(A1,A4:B10,B4:B10)

Q株価の計算方法を教えて下さい!!

今日現在の売り株価を計算しろと、上司から指示受けましたが、計算方法も、株自体もよくわかっていません(ToT)
どなたさまか、教えてくださいいいいい!!

まず、佐田建設というとこの株を11,000株
持っています。
NIKKEINETの株価を調べてみましたら、
何がなんだかわかりません。。。
きっと簡単な数式なんでしょうけど・・・
「始値193」「高値193」「安値184」
「現在値188」「前日日-4」
「売買高1,843,000」とか書いてあります。
このURLですhttp://company.nikkei.co.jp/index.cfm?scode=1826

どなたかあああああ世間知らずの大馬鹿な私に
愛の手を。。。(ToT)/~~~
お願い申し上げます

Aベストアンサー

評価額(本日の場終了後の仮売り株価)は終値ベースで出しましょう

したがって
本日の終値188円×11,000株=206万8千円
となります

Qエクセルで重複しているデータの抽出のしかたを教えてください。

エクセルで重複しているデータを抽出したいのですが・・。なにぶん初心者なもので簡単な方法があればよいのですが・・。
A列に日付 B列に企業名このデータが300件ほどあります。

 Å列      B列
1月 1日    AAAA社
1月 4日   BBBB社
1月 8日   CCCC社
2月 1日   BBBB社
2月20日    DDDD社
3月 2日   AAAA社

と、あるとしてB列の企業名が重複しているものを抽出したいのですが・・・。この場合 AAAA社とBBBB社ですが。
これを簡単に抽出する方法はないでしょうか?
教えてください お願いいたします。

Aベストアンサー

企業名がセルB2からセルB300まで入力されていると仮定します。
セルC2に IF(COUNTIF($B$2:B2,B2)>1,"*","") を入力し、セルC300までコピーして下さい。すると重複したデータの二番目以降に "*" のマークが付きます。
(注) 数式を下のセルまでコピーするため、COUNTIF($B$2 は絶対参照にして下さい。

Qエクセルで振込み手数料を自動的に引いた金額を表示してくれる関数を教えて下さい。

仕事でわからなくて困っております。
毎月、業者から届いている請求書の請求金額を一覧表にして上司に提出しております。
今までは金額そのままの記載すれば良かったのですが 
今度から請求金額から振り込み手数料を引いた金額を振り込むことになったそうで、
今までの請求金額そのままの表と、振込み手数料を引いた金額もあわせて一覧表にするようにと言われました。

振り込み金額は相手先の銀行が同じ銀行か他行であるかと、振込み金額が3万円以上か3万円未満かで違ってしまいます。
銀行が同行の場合(仮にAタイプとして) 3万円未満では105円
                    3万円以上では315円
銀行が他行で (仮にBタイプとして)3万円未満では420円
                 3万円以上では630円

この条件で自動的に振込手数料を引いた金額が出せる関数、あるいは方法をご存知の方 ぜひ教えて下さい。

まず考えたのは、業者さんとその振込口座の表を作れば、VLOOKUPを使ってその業者さんの名前を入力すると自動的にAかBか表示できるかなと思って
それでもしそこがAだったら そして金額が3万円未満だったら105円になるという数字が出せれば 請求金額のセルからその105のセルをマイナスするというので作れるのかなと一人で考えておりましたが
Aだったら そして金額が3万円未満だったらという関数がわからなです。 
そしてこの考え方でよいのかも わかりません。

どうぞよろしくお願いいたします。

仕事でわからなくて困っております。
毎月、業者から届いている請求書の請求金額を一覧表にして上司に提出しております。
今までは金額そのままの記載すれば良かったのですが 
今度から請求金額から振り込み手数料を引いた金額を振り込むことになったそうで、
今までの請求金額そのままの表と、振込み手数料を引いた金額もあわせて一覧表にするようにと言われました。

振り込み金額は相手先の銀行が同じ銀行か他行であるかと、振込み金額が3万円以上か3万円未満かで違ってしまいます。
銀行が同行の場合...続きを読む

Aベストアンサー

>Aだったら そして金額が3万円未満だったらという関数がわからなです。

そもそものこのご質問に回答しますと、
条件1かつ条件2を満たす場合のIF関数
IF(AND(条件1、条件2),両条件を満たす時の処理,それ以外の処理)

あなたの考えた方法でもいいと思いますよ。自分で理解しながら表を作成したら後からのメンテも楽です。
振り込まれる口座(あなた側)を「あいう銀行」とします。

A列;相手方の銀行名
B列;金額
C列:振込手数料

C2セル:
=IF(AND(A2="あいう銀行",B2<30000),105,IF(AND(A2="あいう銀行",B2>=30000),315,IF(AND(A2<>"あいう銀行",B2<30000),420,630)))

ちなみに:
IF関数のネスト(入れ子)というやつです。
テストの点数が80点以上なら合格、50点以上なら追試、49点以下なら落第
として
IF(A1>=80,"合格",IF(A1>=50,"追試","落第"))

まず一つ目の条件(80点以上か)を判定し、満たしてれば「合格」。
満たしてない場合に、次のIF文の判定に行きます。
50点以上なら「追試」
その条件も満たしてなければ最後の「落第」になります。

上に示したあなたのケースでは、
同行かつ3万円未満なら、105円。それを満たさない場合、
同行かつ3万円以上なら、315円。それを満たさない場合、
他行かつ3万円未満なら、420円。それを満たさない場合、
630円。

という流れになっています。
ご参考まで。

>Aだったら そして金額が3万円未満だったらという関数がわからなです。

そもそものこのご質問に回答しますと、
条件1かつ条件2を満たす場合のIF関数
IF(AND(条件1、条件2),両条件を満たす時の処理,それ以外の処理)

あなたの考えた方法でもいいと思いますよ。自分で理解しながら表を作成したら後からのメンテも楽です。
振り込まれる口座(あなた側)を「あいう銀行」とします。

A列;相手方の銀行名
B列;金額
C列:振込手数料

C2セル:
=IF(AND(A2="あいう銀行",B2<30000),105,...続きを読む

Qエクセル 計算式 手数料計算

こんにちは。
質問させていただきます。

エクセルを使い、手数料の算出をしたいです。
条件は以下の通りです。

セルAが
(1)50以下の場合
その数に対し7.5%

(2)50以上1,000以下の場合
50までに対し7.5%
50を引いた残りの数に対し4%
両方の合計

(3)1,000以上の場合
50までに対し7.5%
50を引いた残りの数に対し4%
さらに1,000引いた数に対し2%
これらの合計

【例】
(1)45
45×0.075=3.375

(2)150
50×0.075+(150-50)×0.04=7.75

(3)1200
50×0.075+(1200-50)×0.04+(1200-50-1,000)×0.02=52.75

これを一本の式にまとめたいです。

よろしくお願います。

Aベストアンサー

>(3)1,000以上の場合
>50に対し7.5%
>元の数から1000を引いた残りの数に対し2%
>1000から50を引いた950に対し4%
>これらの合計

 それでしたら、

=IF(ISNUMBER($A1),MIN($A1,50)*0.075+(MIN($A1,1000)-50)*0.04*($A1>=50)+($A1-1000)*0.02*($A1>=1000),"")

 或いは

=IF(ISNUMBER($A1),$A1*LOOKUP($A1,{0,50,1000;7.5,4,2})/100+LOOKUP($A1,{0,50,1000;0,1.75,21.75}),"")

になります。
 尤も、条件を当てはめる範囲を「(1)50以下、(2)50を超えて1000以下、(3)1000を超えて」とした場合の関数である、

=IF(ISNUMBER($A1),MIN($A1,50)*0.075+(MIN($A1,1000)-50)*0.04*($A1>50)+($A1-1000)*0.02*($A1>1000),"")

でも同じ結果となりますが・・・
 それから、A列内でセルの切り取り、挿入、削除、等のセルの位置関係がずれる様な編集作業を行っても、正しい結果が出る様にする場合には、「$A1」の部分を「INDEX($A:$A,ROW())」に置き換えて、次の様にします。

=IF(ISNUMBER(INDEX($A:$A,ROW())),MIN(INDEX($A:$A,ROW()),50)*0.075+(MIN(INDEX($A:$A,ROW()),1000)-50)*0.04*(INDEX($A:$A,ROW())>50)+(INDEX($A:$A,ROW())-1000)*0.02*(INDEX($A:$A,ROW())>1000),"")

 或いは

=IF(ISNUMBER(INDEX($A:$A,ROW())),INDEX($A:$A,ROW())*LOOKUP(INDEX($A:$A,ROW()),{0,50,1000;7.5,4,2})/100+LOOKUP(INDEX($A:$A,ROW()),{0,50,1000;0,1.75,21.75}),"")

>(3)1,000以上の場合
>50に対し7.5%
>元の数から1000を引いた残りの数に対し2%
>1000から50を引いた950に対し4%
>これらの合計

 それでしたら、

=IF(ISNUMBER($A1),MIN($A1,50)*0.075+(MIN($A1,1000)-50)*0.04*($A1>=50)+($A1-1000)*0.02*($A1>=1000),"")

 或いは

=IF(ISNUMBER($A1),$A1*LOOKUP($A1,{0,50,1000;7.5,4,2})/100+LOOKUP($A1,{0,50,1000;0,1.75,21.75}),"")

になります。
 尤も、条件を当てはめる範囲を「(1)50以下、(2)50を超えて1000以下、(3)1000を超えて」とした場合の関数である、

=...続きを読む


人気Q&Aランキング