色彩を教える人になるための講座「色彩講師養成講座」の魅力とは>>

エクセルVBAで質問なのですが、別のブックを非表示で開いて処理をし、処理が終わったらそのブックを閉じるマクロを作りたいです。

ネットで方法をたくさん調べたのですが、うまくいきません。
ActiveWindow.Visible = Falseを使うと非表示でブックを開くのですが、次の処理をしようとすると非表示のブックのシートがselectで選択できないのかエラーが出てしまいます。

どなたか良い方法をご存じないでしょうか?


↓今作ろうとしているマクロを参考に書いておきます。

ブックA内に書かれているブックBを非表示で開く

処理(ブックBのシート内の表に記入漏れの空白セルがあればブックAに空白セルの番地を表示させる)

ブックBを非表示のまま閉じる


非表示にせずにブックBを開けばうまく処理が完了するのですが、ActiveWindow.Visible = Falseを入れて非表示でブックBを開くと処理が開始しないという状況です。

質問者からの補足コメント

  • うれしい

    緊急で他の仕事が入ってしまい、このマクロを作る仕事をしばらく中断することになったので私のほうではまだ未解決ではあるのですが、今の仕事が終わってマクロを作る仕事が再開したらご回答してくださった方々が教えてくださった方法を試してみたいと思います。
    なので一度質問を締め切らせていただきますね。
    ご回答くださった方々にはとても感謝しております。ありがとうございました!

      補足日時:2016/06/23 13:42
gooドクター

A 回答 (4件)

こんにちは



>非表示のブックのシートがselectで選択できないのかエラーが出てしまいます。
手作業でも非表示のブックでシートやセルを選択しようとしても無理ですよね?

VBAの記述の方法をSelectやActivateなどを用いないように書き直せば、ご希望のことは実現可能だと思います。

例として、以下では"TestBook"というブックを開き、そのシート1内でA1:C20の範囲の空白セルを探して、メッセージボックスにカンマ区切りで結果を表示します。
(殆ど時間がかかりませんので、非表示にしなくても同じだとは思いますが…)

Sub sample()
 Dim wb As Workbook, c As Range
 Dim str As String

 str = ""
 Set wb = Workbooks.Open(ThisWorkbook.Path & "\TestBook.xlsm")
 Windows(wb.Name).Visible = False

 For Each c In wb.Worksheets(1).Range("A1:C20")
  If c = Empty Then
   If str <> "" Then str = str & " , "
   str = str & c.Address
  End If
 Next c
 wb.Close SaveChanges:=False

 MsgBox str
End Sub

※ わざわざ『非表示』に設定しなくても、現在のウィンドウをアクティブにすることで、新しく開いたウィンドウを(裏側に)隠すこともできますね。
    • good
    • 6
この回答へのお礼

ご回答どうもありがとうございます。
非表示だとselectなどは使えないのですね。
非表示で開いたブック内の表の一部の範囲を選択して、その中から空白セルを探すように作っていたので、書き方を変えなければならないようですね。

わざわざ非表示にしなくても処理できているのだから私ももうこれでいいんじゃないかと思うのですが、上司が非表示にしてほしいと言うものですから^^;
私VBA初心者なのに次々とむずかしいことを要求してくるもので・・・

しばらくちょっと他の仕事をしなくてはならずマクロを作る仕事を中断してしまってfujillinが教えてくださった方法をすぐに試せないのですが、今度試してみます!ありがとうございます^^

お礼日時:2016/06/23 13:18

こんばんは


ブックやシートの選択の仕方を変えてみたらいかがでしょうか?

非表示のブックやそのシートは「select」や「Activate」は出来ません。しかし、
Workbooks("Book2").Worksheets("Sheet1").Range("A1") = 1
のような書き方ならば、非表示のブックやシートを扱えます。
    • good
    • 7
この回答へのお礼

ご回答ありがとうございます!

そのような書き方をすればいいのですね。
マクロの仕事をしばらく中断することになったのですぐに試せないのですが、今度試してみます!
知恵を貸していただきどうもありがとうございます!

お礼日時:2016/06/23 13:36

No.1 fujillinさんの云う通り、SelectやActivateなどを用いないように書き直せるのであれば、非表示にしなくてもあまり気にならないのですが、モスマンさんの書いているマクロは、表示がガチャガチャ動くようなタイプなのですか?もし、そうであれば、まずは、SelectやActivateなどを使わない書き方を学習すべきです。



とは言っても、手っ取り早く解決したいのであれば、画面の更新を抑止すれば、ご希望通りになると思います。
こんな感じです。

Application.ScreenUpdating = False ’画面更新の抑止
ブックのOPEN
処理
ブックClose
Application.ScreenUpdating = True ’画面更新の抑止解除
    • good
    • 5
この回答へのお礼

ご回答ありがとうございます。

他のブックを開いて一部の範囲を選択し、そこから空白セルを見つけたらそのセル番地を自動で記入していくという動きをさせてます。
非表示にしないで動かすとうまくいっていたのですが、非表示にすると動かなくなるものなんですね。
selectなどを使わないものに書き換えようと思っていたのですが、画面更新の抑止というものがあるのですか!
ちょっと試してみたいのですが他の仕事をしなくてはならずマクロを作る仕事をしばらく中断することになったのですぐに試せないのですが、他の閲覧者様たちの参考になるかもしれません。
今度マクロの仕事を再開したときに試してみたいです。
知恵を貸してくださりありがとうございました!

お礼日時:2016/06/23 13:34

>別のブックを非表示で開いて処理をし、処理が終わったらそのブックを閉じるマクロを作りたいです。



本当に非表示する必要があるのか、どこで邪魔になるのか、何か、誤解があるような気がしてなりません。半分/完全ステルスなら、Excelをオートメーション化して、稼働させます。以下は、何か別のことを思いついても、悪用はしないでください。
例えば、これにタイマーをつけて、完全なステルス化するとと、使用者は自覚がないままに、知らない間に、マクロが作業しています。
ADODBでも似たようなことはできるけれども、こちらの方が扱いが楽です。

'//
Sub StelthCehcking()
  Dim xlBook As Object
  Dim xlApp As Object
  Dim Rng As Range
  Dim blkRng As Range
  Dim buf As Variant
  Dim fn As String
  Dim bfn As String
  Dim c As Range
  Dim arBuf, i As Long
  On Error GoTo ErrHandler
  fn = "C:\Temp\BookB.xlsm" '目的のファイル
  bfn = Mid(fn, InStrRev(fn, "\") + 1)
  On Error Resume Next

' ブックを開いているかどうかを調べます
  Set xlBook = GetObject(bfn)
  If xlBook Is Nothing Then
    Set xlApp = CreateObject("Excel.Application")
    Set xlBook = xlApp.Workbooks.Open(fn)
  End If
  On Error GoTo 0
  
  With xlBook
    Set Rng = .Worksheets("Sheet2").Range("A1").CurrentRegion
    On Error Resume Next
    Set blkRng = Rng.SpecialCells(xlCellTypeBlanks) 'ブランクを探す
    On Error GoTo 0
    If Not blkRng Is Nothing Then
      For Each c In blkRng.Cells
        buf = buf & "," & c.Address(0, 0)
      Next c
    End If
    .Close False 'ブックを閉じる
  End With
  If Len(buf) > 1 Then
    arBuf = Split(Mid(buf, 2), ",")
    i = UBound(arBuf)
    'A列に書く
    ThisWorkbook.Worksheets("Sheet1").Range("A1").Resize(i + 1).Value _
    = WorksheetFunction.Transpose(arBuf)
  End If
ErrHandler:
  Set xlBook = Nothing
End Sub
    • good
    • 1
この回答へのお礼

ご回答どうもありがとうございます。

私もわざわざ非表示にする必要があるのか疑問なのですが、上司がそうしてほしいというのでそう作るしかなくて^^;
私VBA初心者なのであまり詳しくもないので、非表示にすることによって何か意味があるのかよくわからないんですが、作れるならなんとか作ろうと思いまして質問させていただきました。

しばらく他の仕事をせねばならずマクロの仕事を中断してしまっているのでWindFallerさんが教えてくださった方法をすぐに試せずまだ未解決なのですが、他の閲覧者様たちの参考になるかもしれません。私もマクロの仕事を再開するときに試してみます。知恵を貸してくださりありがとうございました!

お礼日時:2016/06/23 13:28

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

gooドクター

このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング