EXCEL 重複の値のチェックについて

お世話になります。
重複のチェックをしたいのですが、少し変則的な形です。
以下の例の様に、産地の秋田県で品名の王林がダブっているので、Ｆ列にセル色を変える、
などしてチェックできるようにしたいと考えています（Ａ列に対応する中での重複のチェック）。
条件付き書式やマクロなど、方法は問いませんので何卒ご助力のほど宜しくお願い致します。

Ａ列　　　Ｅ列　　Ｆ列
産地　　　品名
青森県　　王林
青森県　　ふじ
青森県　　つがる
青森県　　紅玉
秋田県　　王林　　　□
秋田県　　ふじ
秋田県　　王林　　　□
・　　　　・　

以上、よろしくお願い致します。

No.4 ベストアンサー 回答者： jmuiny 回答日時： 2016/07/19 10:31

色をつけるのであれば

F2以降範囲指定して、条件付き書式
数式
=AND(A2<>"",E2<>"",SUMPRODUCT((A:A=A2)*(E:E=E2))>1)
塗りつぶしの色を設定

範囲が広いので重くなります。
範囲がわかっていたら
=AND(A2<>"",E2<>"",SUMPRODUCT(($A$2:$A$100=A2)*($E$2:$E$100=E2))>1)
のように行を指定した方がいいですね。

F列にメッセージを出すなら、これをIFの式にて文言を入れるといいです。

この回答へのお礼

ご回答ありがとうございました。
このご回答で解決させたいと思いました。
また宜しくお願い致します。

お礼日時：2016/07/19 10:41

No.3 回答者： t_fumiaki 回答日時： 2016/07/19 10:10

No.2おっとっと

降順に並び替えて同じこともします。
（重複の両方へ印つける為）

この回答へのお礼

ご回答ありがとうございました。
訳あって並び替えをさせたくないのですが、
非常に分かりやすいご回答を頂きまして
大変勉強になりました。

お礼日時：2016/07/19 10:40

No.2 回答者： t_fumiaki 回答日時： 2016/07/19 10:07

私はEXCELの範囲で出来る事はEXCELで、出来ない事はVBAを使っています。

この手の処理はEXCELの範囲内で、システマティックに機械的に一機に処理出来ます。

以下を順番に行なって下さい。

①G列に上から連番を振ります（G2=1,G3=G2+1,として以下式コピペ）
　並び替えをするので、元の並びに戻す際に必要）

②G列の式を値にする。
　列を全選択し、コピー⇒形式を指定して貼り付け、で
　値を選択して貼り付ける

③H列に、A列とE列を連結したものを入れる
　H2は =A2 & E2、この式をH3以降へコピペ

④H列を基準に全体を昇順に並び替え

⑤I列に、「上と同じなら○違ってるなら○○」の式を入れる
　I2は　=IF(H2=H1,1,"")、I3以降へコピペ

⑥フィルタをかけ、I列が1のものを表示させる
⑦表示されているF列のセル色を一括で設定する。

並びを元に戻し、追加した列も削除して完成

No.1 回答者： 銀鱗 回答日時： 2016/07/19 09:23

COUNTIF関数を使った重複の確認のやり方はご存知ですか。

=COUNTIF(A$1:A1,A1)
のように入力し、必要な行までコピーするのです。
すると、
2行目には、=COUNTIF(A$1:A2,A2)
3行目には、=COUNTIF(A$1:A3,A3)
と、参照する範囲を1行目からコピーされた行まで拡張されていきます。
そして１以外の結果が返っている行に重複があると判断できるのです。

さて、2項目以上の重複を確認するにはどうするか。
Excel2007から追加された関数にCOUNTIFSがあります。
この関数は2項目以上の条件を満たす場合の積算（カウント）を行えます。

＝COUNTIFS(A$1:A1,A1 , B$1:B1,B1)
のようにして使います。
質問の例では
＝COUNTIFS(A$2:A2,A2 , E$2:E2,E2)
のようになります。

あとはIF関数で
=IF(COUNTIFS(A$2:A2,A2 , E$2:E2,E2)>1,"□","")
のようにしたり、
条件付き書式で式に
=COUNTIFS(A$2:A2,A2 , E$2:E2,E2)>1
と指定して条件が成り立つ場合のセルの色を変えたりしてはいかがでしょう。

この回答へのお礼

銀鱗様
早速のご回答ありがとうございます。
大変申し訳ありません、明記しそびれており心苦しいのですが、
EXCEL2003 を使用しております。この版で対応できますでしょうか。

お礼日時：2016/07/19 09:47