エクセルVBAの構文。 どこが間違っているのでしょうか？

以下の２つは同じ意味だと思うのですが、test2はエラーになります。どうしてなのでしょうか？

Sub test1()
ActiveSheet.Shapes.AddShape(msoShapeRectangle, 300#, 100#, 140#, 80#).Select
Selection.Formula = "$A$1"
End Sub

Sub test2()
With ActiveSheet.Shapes.AddShape(msoShapeRectangle, 300#, 100#, 140#, 80#)
.Formula = "$A$1"
End With
End Sub

No.3 ベストアンサー 回答者： taisuke555 回答日時： 2004/07/28 21:18

ActiveSheet.Shapes.AddShape(msoShapeRectangle, 300#, 100#, 140#, 80#).DrawingObject.Formula = "$A$1"

って書いたらできたけど、だめかな？

この回答へのお礼

ありがとうございます！！

ダメじゃないです。これでいいんです！
ありがとうございました。

お礼日時：2004/07/29 10:41

No.4 回答者： ja7awu 回答日時： 2004/07/29 00:17

そうですね。

　taisuke555さんの方法で良いと思います。

ただ、他に色など設定するプロパティがあるのであれば、オブジェクト変数にセットした方が
いいかと思います。

Sub test1()
Dim Shp As Shape
Set Shp = ActiveSheet.Shapes.AddShape(msoShapeRectangle, 300, 100, 140, 80)
With Shp.DrawingObject
　　.Formula = "$A$1"
　　.Font.ColorIndex = 3
End With
End Sub

DrawingObjectは、隠しオブジェクトでヘルプには記載無く、メンバーにも出てこないと思います。

With Shp.DrawingObject の代わりに　With Rectangles(Shp.Name)　としてもいいと思います。

Rectangles も同じく隠しオブジェクトになっていますが・・・。

この回答へのお礼

ありがとうございます。

こんな感じでできました。

Sub Macro5()
With ActiveSheet.Shapes.AddShape(msoShapeRectangle, 300#, 100#, 140#, 80#)
With .DrawingObject
.Formula = "$A$1"
.Font.Name = "Century Gothic"
.Font.FontStyle = "太字"
.Font.Size = 72
.Font.ColorIndex = 1
End With
.TextFrame.AutoSize = True
.Fill.Visible = msoFalse
.Line.Visible = msoTrue
.Name = "CD"
End With
End Sub

お礼日時：2004/07/29 10:43

No.2 回答者： ja7awu 回答日時： 2004/07/28 17:59

出来ないような気がしますが、もし、画面が変化するのがイヤなだけであれば、

最初に　Application.ScreenUpdating = False を入れて、Shapeの設定が終わったら
希望するセルをアクティブにしてから　ScreenUpdating = True　にする　というのは
ダメなのでしょうか。

この回答へのお礼

ありがとうございます。
実際にselectしたくないのです。

お礼日時：2004/07/29 10:40

No.1 回答者： ja7awu 回答日時： 2004/07/28 11:22

Shapeオブジェクトに対して、その数式バーに "=$A$1" を設定するのに、

そのオブジェクトを 《Select》 していないから　と思います。

後のコードですと、このコードを実行する前にアクディブであるセルが、そのまま維持
され、Shapeオブジェクトが、アクティブになることはありません。

この回答へのお礼

さっそくありがとうございます。
オブジェクトを 《Select》 せずにその数式バーに "=$A$1" を設定することは出来ないのでしょうか？

お礼日時：2004/07/28 13:02