【EXCEL-VBA】特定のワークブックのF1にマウスポインターを移動したい

Question

お世話になっております。

「Book1.xlsx」、「Book2.xlsx」、「Book3.xlsx」の3つのワークブックを開く
マクロを作成しました。

ここまでは問題ないのですが、値の取得の関係上、
マウスポインターをSheet1のF1セルに合わせたいと思っています。

とりあえず、以下のマクロで、
最後に開いた「Book3.xlsx」のSheet1のF1に
マウスポインターを合わせてアクティブにしするところまで
出来たのですが、、、、。

2番目に開いた「Book2.xlsx」のF1に
マウスポインターを合わせてアクティブにする方法がわかりません。

すいませんが詳しい方、説明の上手な方、直接、コードで説明できる方、
「Book1.xlsx」、「Book2.xlsx」、「Book3.xlsx」の3つのワークブックを開いて
2番目に開けた「Book2.xlsx」のSheet1のF1セルにマウスポインターを合わせる方法を教えて下さい。
 
お手数ですが、よろしくお願いします。

追記
1)こちらの知識、実力が以下のコードのレベルです。
→なのですいませんがあまり高度なことはわかりません。
→コードは以下のものを流用して頂いても、オリジナルのものでもOKです。

2)変数の練習もかねております。なので、もしお手数でなければ
変数名は日本語にして頂けるとありがたいです。
※不可の場合は慣れた書き方でいいです。

3)便宜上、
「Book1.xlsx」、「Book2.xlsx」、「Book3.xlsx」の3つワークブックは
Cドライブの「A」フォルダーに入っているということでお願いします。
※ファイルパスは「C:\A」です

--------------------------
Sub Macro1()

Workbooks.Open "C:\A\Book1.xlsx"
Workbooks.Open "C:\A\Book2.xlsx"
Workbooks.Open "C:\A\Book3.xlsx"

MsgBox "開きました"

'ポインターをF1に移動する
Sheets("Sheet1").Select
Range("F1").Select

End Sub

tatsu99 · Accepted Answer

No4です。
>変数の宣言についてはSub Macro1()の上に書いても
>問題ないということでしょうか？

問題ありません。Sub Macro1()の上に書くと、そのモジュール内のどのプロシージャ（Macro2,Macro3等）
からでも、参照／設定が可能になります。
つまり、その変数をSub Macro1()以外でも使用したい場合は、Sub Macro1()の上に書きます。

tom04 · Answer

投稿後間違いに気づきました。

No.5のコードの
＞wS.Cells(9 + k, "F") = .Worksheets("Sheet1").Range("F1")
を
＞wS.Cells(10 + k, "F") = .Worksheets("Sheet1").Range("F1")
に変更してください。
そうしないと1行ずれて、F9～F11セルにデータが表示されてしまいます。

何度もごめんなさい。m(_ _)m

tom04 · Answer

No.2・3です。

とりあえず　田中・佐藤・田中　というExcelファイルでの操作にしてみました。
今回も2番目（佐藤Book）はF1セルを選択し上書き保存するようにしています。

Sub Sample3()
    Dim k As Long, myPath As String, fN As String
    Dim wS As Worksheet, myAry As Variant
        myAry = Array("田中", "佐藤", "山田") '←　操作するファイルを増やす場合はここで追加する★//
        Set wS = ThisWorkbook.Worksheets("Sheet1")
        myPath = "C:\A" & "\"
        For k = 0 To UBound(myAry)
            fN = myAry(k) & ".xlsx"
            Workbooks.Open myPath & fN
            With ActiveWorkbook
                wS.Cells(9 + k, "F") = .Worksheets("Sheet1").Range("F1")
                If k = 1 Then   '←　Arrayは「0」からのスタートなので2番目（佐藤Book）は「1」となる。★//
                    .Worksheets("Sheet1").Range("F1").Select
                    .Save
                End If
                    .Close
            End With
        Next k
End Sub

※　ファイル名は「Book田中.xlsx」ではなく、単に「田中.xlsx」のようになっているという前提です。
実際に「Book田中.xlsx」のようになっている場合は
コード内の
＞fN = myAry(k) & ".xlsx"
を
＞fN ="Book" &  myAry(k) & ".xlsx"
に変更してください。m(_ _)m

tatsu99 · Answer

Book1.xlsx,Book2.xlsx,Book2.xlsxを開いて
Book2のsheet1のF1の内容をマクロのあるブックのsheet1のF10へセットするマクロです。
処理が完了後、Book1,2,3を閉じています。

尚、今回は、Book2をActivateしていますが、Book2をActivateにしなくても、コピーは可能です。
一般的には、
Workbooks("Book1").Sheets("Sheet1").Range("A1").value = Workbooks("Book2").Sheets("Sheet2").Range("A1").value
のようにします。
Book2をActivateにすると、そのメリットはセルのコピー時にBook2を書かなくてもよいということだけです。
①    Workbooks("Book2.xlsx").Activate
②    ThisWorkbook.Sheets("sheet1").Range("F10").Value = Worksheets("sheet1").Range("F1").Value
③ 　'ThisWorkbook.Sheets("sheet1").Range("F10").Value = Workbooks("Book2.xlsx").Worksheets("sheet1").Range("F1").Value
①②をコメントにして③のコメントを外してください。Book2をActivateにしなくても③でコピーができることが
確認できます。

Public Const dirname はBook1,2,3が格納してあるフォルダです。（最後に\を付加してください）
-----------------------------------
Option Explicit

Public Const dirname As String = "C:\Users\xxxx\Documents\"
Public Sub TestOpen()
    Workbooks.Open dirname & "Book1.xlsx"
    Workbooks.Open dirname & "Book2.xlsx"
    Workbooks.Open dirname & "Book3.xlsx"
    Workbooks("Book2.xlsx").Activate
    ThisWorkbook.Sheets("sheet1").Range("F10").Value = Worksheets("sheet1").Range("F1").Value
    'ThisWorkbook.Sheets("sheet1").Range("F10").Value = Workbooks("Book2.xlsx").Worksheets("sheet1").Range("F1").Value
    Workbooks("Book1.xlsx").Close
    Workbooks("Book2.xlsx").Close
    Workbooks("Book3.xlsx").Close
End Sub

tom04 · Answer

No.2です。

投稿後にNo.1さんのお礼欄を拝見しました。

＞1個目のワークブックからの値の取得　※Sheet1のF1セル
＞2個目のワークブックからの値の取得　※Sheet1のF1セル
＞3個目のワークブックからの値の取得　※Sheet1のF1セル
＞↓
＞アクティブシートの
＞Sheet1のF10、F11、F12への入力
＞↓
＞開いた「Book1.xlsx」、「Book2.xlsx」、「Book3.xlsx」を閉じる
＞ということにトライしようと思っております。

コードを記載しているBookは「アクティブワークブック」とは言わず、
「This Workbook」となります。
（開いたブックが「アクティブワークブック」になります。）

それはさておいて・・・

Sub Sample2()
    Dim k As Long, myPath As String, fN As String
    Dim wS As Worksheet
        Set wS = ThisWorkbook.Worksheets("Sheet1")
        myPath = "C:\A" & "\"
        For k = 1 To 3
            fN = "Book" & k & ".xlsx"
            Workbooks.Open myPath & fN
            With ActiveWorkbook
                wS.Cells(9 + k, "F") = .Worksheets("Sheet1").Range("F1")
                If k = 2 Then
                    .Worksheets("Sheet1").Range("F1").Select
                    .Save
                End If
                    .Close
            End With
        Next k
End Sub

こんな感じではどうでしょうか？m(_ _)m

tom04 · Answer

こんばんは！

2番目に開いたBookのみSheet1のF1セルをアクティブにしておけばよいのですね？
一例です。
Bookは三つとも開いていないという前提です。

Sub Sample1()
    Dim k As Long, myPath As String, fN As String
    myPath = "C:\A" & "\"
    For k = 1 To 3
        fN = "Book" & k & ".xlsx"
        Workbooks.Open myPath & fN
            If k = 2 Then
                ActiveWorkbook.Worksheets("Sheet1").Activate
                Range("F1").Select
            End If
    Next k
End Sub

※　変数名は「日本語」ではありませんが、
何となく判ってもらえると思います。m(_ _)m

tatsu99 · Answer

＞とりあえず、以下のマクロで、
＞最後に開いた「Book3.xlsx」のSheet1のF1に
＞マウスポインターを合わせてアクティブにしするところまで
＞出来たのですが、、、、。

＞2番目に開いた「Book2.xlsx」のF1に
＞マウスポインターを合わせてアクティブにする方法がわかりません。

「Book3.xlsx」のSheet1のF1及び
「Book2.xlsx」のF1を同時にアクティブにすることは、できないと思いますが、いかがでしょうか。

【EXCEL-VBA】特定のワークブックのF1にマウスポインターを移動したい

No4です。

投稿後間違いに気づきました。

No.2・3です。

Book1.xlsx,Book2.xlsx,Book2.xlsxを開いて

No.2です。

こんばんは！

＞とりあえず、以下のマクロで、

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング