データの仕分けについて excel2010

エクセル初心者です。
以下内容についてご教示いただければと思います。

使用しているのはexcel2010です。

運送業務の行先ごとの時間外深夜の集計をを行うにあたり
シート1　に行先ごとの　ｺｰﾄﾞ　時間外　深夜を入力しています

例）ｺｰﾄﾞ番号　1200　行先　東京　時間外　10　　深夜5　
　　　　　　　1000　行先　大阪　時間外 　8　　 深夜3
0800 行先　福岡　時間外 5　　深夜1　
とした場合

シート2に

　　　　　A1　　　B1　　　 C1　　 　D1　　　 　　　E1
A1　　行先ｺｰﾄﾞ　　行先　　 回数　 　時間外小計　 　深夜小計
A2　　1200　　 　東京　　 　2　　　　20　　　　 　 10　
A3　　1200　　 　大阪　　 　2　　　　16　　　　 　　6
A4　　1000　　　 福岡　　 　1　　　 　5　　　 　 　　1
A5　　1000
A6　　0800　

Aの行にコードを入れていって　B～Eの行（自分では入力しない）に自動で　
行先名　回数　時間外小計　深夜小計
がでてくれるようにしたいのですが
どういう関数をいれればよいでしょうか？

良い方法があれば教えていただければと思います。
よろしくお願いします。

No.4 ベストアンサー 回答者： tom04 回答日時： 2017/03/21 21:29

No.2です。

＞行先が40個ほどあるのでできれば自動でと思ってるのです。。

ん？
「行先」はコードによって決まっているのですよね？

前回の方法はSheet2のA列に「コード」を入力すると
最初に出現した行に結果が表示される方法でした。
すなわち「行先」はいくつあっても問題ありません。

もしかして、行を詰めてコード別に表示したい！という意味であれば・・・
↓の画像のように作業用の列を設けてみてはどうでしょうか？

作業列B2セルに
=IF(COUNTIF(A$2:A2,A2)=1,ROW(),"")
という数式を入れこれ以上データは増えない！というくらいまで下へコピーしておきます。

D2セルに
=IFERROR(VLOOKUP(INDEX(A:A,SMALL(B:B,ROW(A1))),Sheet1!A:B,2,0),"")

E2セルに
=IF(D2="","",COUNTIF(A:A,INDEX(A:A,SMALL(B:B,ROW(A1)))))

F2セルに
=IF($D2="","",VLOOKUP($D2,Sheet1!$B:$D,COLUMN(B1),0)*$E2)
という数式を入れ隣りのG2セルまでフィル＆コピー！

最後にD2～G2セルを範囲指定　→　G2セルのフィルハンドルで下へコピーすると
画像のような感じになります。

※　作業列が目障りであれば非表示にするか
遠く離れた列にします。m(_ _)m

この回答へのお礼

ききたいことはまさにこれでした！すごく助かりました。ありがとうございます！！

お礼日時：2017/03/21 21:45

No.3 回答者： yokomaya 回答日時： 2017/03/21 21:22

難しいとか訊いてません。

なぜ、その数字が決まるのか尋ねているんです。

No.2 回答者： tom04 回答日時： 2017/03/21 19:57

こんばんは！

一例です。
↓の画像のような配置だとして、
Sheet2のB2セルに
=IF(COUNTIF(A$2:A2,A2)=1,VLOOKUP(A2,Sheet1!A:B,2,0),"")

C2セルに
=IF(B2="","",COUNTIF(A:A,A2))

D2セルに
=IF($C2="","",VLOOKUP($A2,Sheet1!$A:$D,COLUMN()-1,0)*$C2)
として隣りのE2セルまでフィル＆コピー！

最後にB2～E2セルを範囲指定　→　E2セルのフィルハンドルで下へコピーすると
画像のような感じになります。m(_ _)m

この回答へのお礼

回答ありがとうございます。行先が40個ほどあるのでできれば自動でと思ってるのです。。

お礼日時：2017/03/21 20:52

No.1 回答者： yokomaya 回答日時： 2017/03/21 18:41

C列の数字が自動的に入る仕組みが、よくわかりません。

ほかはＶＬＯＯＫＵＰでいけると思いますけど。

この回答へのお礼

回答ありがとうございます。自動なところはやはり難しいですよね。。

お礼日時：2017/03/21 20:50