データを抽出して、そのデータの列最上部を示す関数はどうしたら良い？

教えてください。
Excel2003で下記の表があります。
データから５以上を拾い、最初に出現したデータの、列の最上部を示す関数はどうしたら良いでしょうか？

　　　 　　A 　B　 C 　D
ケースa　 2　 4 　6　 8 　→ C
ケースb　 9　 3 　5　 7 　→ A

ケースaでは、５以上は６と８なので、最初に出現した６の列であるCを表示
ケースbでは、５以上は9と５なので、最初に出現した9の列であるAを表示

No.1 ベストアンサー 回答者： mike_g 回答日時： 2017/06/16 21:54

F2: =INDEX(A$1:E$1,MIN(IF(B2:E2>=5,COLUMN(B2:E2),"")))

【お断り】上式は必ず配列数式として入力のこと

この回答へのお礼

早速ご連絡をありがとうございました。
すごいです！できました。
配列数式もこうやって使うんですね！驚きました。

お礼日時：2017/06/17 03:27

No.3 回答者： 銀鱗 回答日時： 2017/06/16 22:05

配列数式を使う。

・・・
A２セルからD３セルにかけて入力があるとします。
空いているA４セルに次の数式を入れる。
　＝A２>=5
そしてA４セルをD４セルまで複製する。
更にA４セルからD４セルをA５セルからD５セルへ複製する。

これは５以上なら「True」、5未満なら「False」が返る数式です。
この中で一番初めに「True」が出てきたセルの場所を返せばよいのですから
MATCH関数で調べればいい。
すると
　＝MATCH(TRUE,A2:D2,0)
さらにこの結果をINDEX関数の列数に指定すればいいので、
　＝INDEX($A$1:$D$1,,MATCH(TRUE,A2:D2,0))
となる。
この数式をコピーして
　＝INDEX($A$1:$D$1,,MATCH(TRUE,A3:D3,0))
とすれば3行目の結果も得られます。
　
空いている行を作業用に使ってのでとても面倒になりました。
ならば、作業用の列でやっていることを連続して行うように書き換え「配列数式」にすればいい。
　=INDEX(A1:D1,,MATCH(TRUE,A2:D2>=5,0))
と、MATCH関数の範囲に対して「True」か「False」かの判定を含めてしまう。
さらにこの数式を入力したら、ShiftキーとCtrlキーを押しながらEnterキーを押して入力を確定する。
すると数式は
　{=INDEX(A1:D1,,MATCH(TRUE,A2:D2>=5,0))}
と中括弧で囲まれる。
これが「配列数式」になっている表示。中括弧をキーボードから入力しても配列数式にはなりません。

正しく表示出来たらA4セルからD5セルの数式を消しておく。

・・・
こんなでしょうか。

この回答へのお礼

回答をありがとうございました。
考え方も丁寧にご記入いただき、大変ありがとうございました。
私にはハードルが高いです。

お礼日時：2017/06/17 03:29

No.2 回答者： tom04 回答日時： 2017/06/16 21:59

こんばんは！

やり方だけ・・・

↓の画像でH2セルに
=INDEX(B1:E1,MIN(IF(OFFSET(B1:E1,MATCH(G2,A1:A100,0)-1,,1)>=5,COLUMN(B1:E1)-1)))

配列数式なので、Ctrl＋Shift＋Enterで確定！
エラー処理はしていません。

これでG2セルのデータを入れ替えるだけで結果が表示されると思います。m(_ _)m