エクセルから日付を条件にして抽出したいです

あまりエクセル詳しくありません、下記の様なシートを作成したいのですが分かりやすく教えて頂けますか？参考になるＵＲＬ等ありましたらそれでも良いです。

(シート１)
準備日 商品 　　　　数量　　得意先 出荷日
7/1 　コーヒー10個入 １　　Ａ社 　　　7/2
7/1　　コーヒー10個入　　　2　　C社　　　　7/2
7/2 　紅茶3個入 　　　1　　Ｃ社 　　　7/3
7/1 　紅茶5個入 　　　3　　B社　　　 7/2

と言うシートからシート2に種類別に抽出し合計を出すにはどうすれば良いですか？
更にシート3に出荷日別を条件に行を抽出したいです。

(シート２)
準備日
　7/1←検索条件

　　商品　　　　　　数量
コーヒー10個入　　　３
紅茶5個入　　　　　　3

(シート3)
出荷日
　7/2←検索条件
7/1 　コーヒー10個入 １　　Ａ社 　　　7/2
7/1　　コーヒー10個入　　　2　　C社　　　　7/2
7/1 　紅茶5個入 　　　3　　B社　　　 7/2

No.1 ベストアンサー 回答者： tom04 回答日時： 2017/07/27 21:48

こんばんは！

一例です。
↓の画像のようにSheet1に作業用の列を設けてみました。
作業列G2セルに
=IF(AND(A2=Sheet2!A$2,COUNTIFS(A$2:A2,A2,B$2:B2,B2)=1),ROW(),"")
という数式を入れフィルハンドルで下へこれ以上データはない！というくらいまでコピーしておきます。

Sheet2のA5セルに
=IFERROR(INDEX(Sheet1!B:B,SMALL(Sheet1!G:G,ROW(A1))),"")

B5セルに
=IF(A5="","",SUMIFS(Sheet1!C:C,Sheet1!A:A,A$2,Sheet1!B:B,A5))

という数式を入れA5・B5セルを範囲指定　→　B5セルのフィルハンドルで下へコピー！

Sheet3のA5セルに
=IFERROR(INDEX(Sheet1!A$1:A$1000,SMALL(IF(Sheet1!$E$1:$E$1000=$A$2,ROW($A$1:$A$1000)),ROW(A1))),"")

配列数式なのでCtrl＋Shift＋Enterで確定！　→　G5セルのフィルハンドルで右へE5セルまでコピー！
A5・E5セルの表示形式を「日付」にしておき、
A5～E5セルを範囲指定　→　E5セルのフィルハンドルで下へコピーすると
画像のような感じになります。

※　Sheet1に作業列をもう1列設ければSheet3は配列数式にしなくても対応できます。

※　作業列が目障りであれば、遠く離れた列にするか
非表示にしてください。m(_ _)m

この回答へのお礼

ありがとうございます、助かりました。

お礼日時：2017/07/29 08:07