１つのセルの中身をブイルックアップで分けて持ってくる方法。

シート１のＣ列に↓のようなセルがあります。
11/11(土) 3回 福島 7日目
11/12(日) 3回 福島 8日目
11/12(日) 6回 京都 4日目
この中から
日付＝11/11(土)
場所＝福島
以上の部分を
D1=IF(B1="","",VLOOKUP(A1,Sheet1!C:M,8,0))
↑こういうので分けてシート３にもってきたいのですがこのままではセルの中身全部を持ってくることしかできないのでどうすれば日付と場所を分けてそれぞれを持ってくることができるでしょうか？

http://oshiete1.goo.ne.jp/kotaeru.php3?q=2046491
↑ここで質問した内容を改良したいのですが、同じセルの中身から部分的に持ってくる方法がわかりません。
よろしくお願いします。

No.3 ベストアンサー 回答者： ham_kamo 回答日時： 2006/11/14 22:02

No.2です。

下のF1の式を、もうちょっと短く修正してみました。（あまり変わらないかも）
F1=IF(D1="","",MID(D1,FIND("回",D1)+2,FIND(" ",D1,FIND("回",D1)+2)-FIND("回",D1)-2))

この回答へのお礼

回答ありがとうございました。

お礼日時：2006/11/15 06:12

No.2 回答者： ham_kamo 回答日時： 2006/11/14 21:53

ちょっと泥臭い方法ですが、固定長とは限らず、日付、回数、場所、○日目が半角スペースで区切られていると仮定した場合です。

いったん、
D1=IF(B1="","",VLOOKUP(A1,Sheet1!C:M,8,0))
とD1にセルを丸ごと持ってきておいて、

E1=IF(D1="","",LEFT(D1,FIND(")",D1)))
F1=IF(D1="","",MID(D1,FIND(" ",D1,FIND(" ",D1)+1)+1,FIND(" ",D1,FIND(" ",D1,FIND(" ",D1)+1)+1)-FIND(" ",D1,FIND(" ",D1)+1)))

とするとか。もっとスマートな方法がありそうですが、とりあえず。
Ｄ列が邪魔なら非表示にしてください。（Ｄ列を右クリック→「表示しない」を選択）

この回答へのお礼

回答ありがとうございました。教えてもらったので、とりあえずできました。

お礼日時：2006/11/15 06:12

No.1 回答者： papayuka 回答日時： 2006/11/14 21:45

固定長なら取得した値を LEFT とか MID とかで切り分ければ良いと思います。

=IF(B1="","",LEFT(VLOOKUP(A1,Sheet1!C:M,8,0),9))
=IF(B1="","",MID(VLOOKUP(A1,Sheet1!C:M,8,0),13,LEN(A1)))

とか。

この回答へのお礼

回答ありがとうございました。

お礼日時：2006/11/15 06:11