エクセルの計算式VLOOKUPを再度教えてください！

Question

再度,質問いたします、わかりましたら、教えてください。
エクセルの計算式でE1のセルに次の計算式があった時に
＝VLOOKUP(B1,$F$1:$G$10,2,FALSE)この式は、成り立っています。
「この時にもう1つ条件をつけて、A1のセルの値(20種類の値が、ある時）に対して範囲を変えることはできますか。たとえばA1セルが50という値のときは、$F$1:$G$10の範囲ですが、A1セルが130と言う値のときの範囲は$F$11:$G$15、A1が201のときの範囲は$F$16:$G$25を指定のように範囲を変えられますか？FとＧに範囲が２０種類タテにあります。H1からＨ10のセルは50という値、H11からH15のセルは130という値,Ｈ16からH25のセルは201と言う値があります。AからE列は1から1000のセルがあってE列は計算式をコピーします。」わかりましたら、計算式を書いてお教えください。

Yosha · Accepted Answer

E1セルに次式を入れ、下方にドラッグしてください。

=VLOOKUP(B1,INDIRECT("F"&MATCH(A1,$H$1:$H$25,1)-COUNTIF($H$1:$H$25,A1)+1&":"&"G"&MATCH(A1,$H$1:$H$25,1)),2)

この式が成立するためには、以下の条件が必要です。

1.　Ｈ列に入っている数値の各グループは、例に出されているように、それぞれ１塊りであり、昇順になっていること。
2.　Ｃ列、Ｄ列にはどんなデータが入っているか説明がないため、無視しています。

式を見てお分かりとは思いますが、一応説明しておきます。

MATCH(A1,$H$1:$H$25,1)　：　昇順に並んでいる数値のうち、Ａ１セルの条件に合った値の入っているセルの最大の行番を返します。

COUNTIF($H$1:$H$25,A1)　：　Ａ１セルの条件に合致したセルの合計です。　MATCH関数は、検索値が昇順に並んでいるとき、最後の引数(照合の型)を“-1”に設定した場合、中間のデータ領域ではエラーとなりますので、この関数を使って各データの始まりの行を算出しています。　

INDIRECT("F"&MATCH(A1,$H$1:$H$25,1)-COUNTIF($H$1:$H$25,A1)+1&":"&"G"&MATCH(A1,$H$1:$H$25,1))　：　()内は文字列なのでこのままではうまくいきません。INDIRECT関数を使って、セル参照形式の文字列をセル参照する式に変換しています。

VLOOKUP(…　：　説明省略

いろいろデータを入れチェックはしてあります。(exel2007)　たぶんＯＫだと思います。試してみてください。

ASIMOV · Answer

＞A1の値は２０種類あるのですが

それなら、DGET という関数があります
事前にちょっと準備が必要ですが、DGET の方が簡単だと思います

F列、G列、H列にはそれぞれ名前が付いていると思いますが、
各列の1列目にその名前を入れます
仮に「F]、「G]、「H」とします
A1="H"
B1="F"
と入れます（検索条件を示す）
A2 に50 とか 130 を入れ、B2 に当初 B1 に入れていた値を入れます
あとは
E1=DGET(F1:H1000,"B",A1:B2)
で、どうでしょうか

ただし、検索条件に合うデーターが複数あるとエラーになります

ASIMOV · Answer

A1の値は50,130,201の3種類だけでしょうか
それなら

=IF(A1=50,VLOOKUP(B1,$F$1:$G$10,2,FALSE),IF(A1=130,VLOOKUP(B1,$F$11:$G$15,2,FALSE),IF(A1=201,VLOOKUP(B1,$F$16:$G$25,2,FALSE),"")))

で、出来ると思います

もし、A1の値が3種以外に増えたり減ったりするのでしたら、式を根本的に見直した方が良いです

あと、E列とH列はこの式とどういう関係があるのでしょうか？

エクセルの計算式VLOOKUPを再度教えてください！

E1セルに次式を入れ、下方にドラッグしてください。

＞A1の値は２０種類あるのですが

A1の値は50,130,201の3種類だけでしょうか

この回答への補足

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング