A2セルの値が「100021_りんご01青森県」からInStrで「りんご」を抽出したい。セルの値が

Question

A2セルの値が「100021_りんご01青森県」からInStrで「りんご」を抽出したい。
セルの値が「100021_りんご01青森県」のような並びで「_」より右「01」より左の「りんご」を切り出したい。
下記コードで「_」より右は切り出せますがこのコードを代えて切り出すことは可能でしょうか？ご指南のほどよろしくお願いいたします。
・・・・・・・・・・・・・・
Dim N As Long
Set cel = wbk.Worksheets("Sheet3").Cells(2, 1)
N = InStr(cel, "_")
cel.Offset(-1, 1) = Mid(cel, N + 1)

tatsumaru77 · Accepted Answer

以下のようにしてください。
Dim N As Long
Dim P As Long
Dim cel As Range
Set cel = wbk.Worksheets("Sheet3").Cells(2, 1)
N = InStr(cel, "_")
P = InStr(cel, "01")
cel.Offset(-1, 1) = Mid(cel, N + 1, P - N - 1)

KenKen_SP · Answer

InStr を使った方法だと。

１．InStr はパターンマッチができない
２．01の部分が可変（数字ではある？）

の条件下だとアンダーバー以降を1文字毎にチェックすることになります。
速攻で書いたので冗長かもしれませんが、こんな感じ。

Sub sampleProc1()

Dim word　　　As String
　　Dim pos_start As Long
　　Dim pos_end　 As Long
　　
　　word = "100021_りんご01青森県"
　　
　　'アンダーバーの位置検索
　　pos_start = InStr(1, word, "_")
　　'見つからない--> アンマッチ
　　If pos_start > 0 Then
　　　　'アンダーバーの1文字後が抜き出し位置
　　　　pos_start = pos_start + 1
　　　　'上記位置から1文字ずつ数字かチェックする
　　　　'LIKE演算子が使える
　　　　Dim i As Long
　　　　For i = pos_start To Len(word)
　　　　　　If Mid$(word, i, 1) Like "[0-9]" Then
　　　　　　　　'数字が見つかったらループを抜ける
　　　　　　　　pos_end = i
　　　　　　　　Exit For
　　　　　　End If
　　　　Next
　　End If
　　
　　If pos_start > 0 And pos_end > 0 Then
　　　　'抜き出し
　　　　MsgBox Mid$(word, pos_start, pos_end - pos_start)
　　Else
　　　　MsgBox "一致しません"
　　End If

End Sub

初心者ですが何か。 · Answer

ちょっと遅かったですかね。
質問文の内容しか記載してませんけど。

Sub test()
Dim MyReg As Object
Dim cel As Range

Set cel = Worksheets("Sheet3").Cells(2, 1) 'テスト用にＢｏｏｋは切り離し

Set MyReg = CreateObject("VBScript.RegExp")
MyReg.Pattern = "_(\D+?)\d"

If MyReg.test(cel.Value) Then MsgBox MyReg.Execute(cel.Value)(0).SubMatches(0)

Set MyReg = Nothing
Set cel = Nothing
End Sub

KenKen_SP · Answer

こんにちは。

本末転倒かもしれませんが、正規表現使った方が早いし柔軟かなぁ。
RegExp VBA で検索してみて。

Sub sampleProc()

Dim reg As Object 'RegExp
　　Set reg = CreateObject("VBScript.RegExp")
　　
　　With reg
　　　　.Global = False
　　　　.IgnoreCase = False
　　　　.Pattern = "(^\d+_)(\D+)(\d+)(.+$)" '<--正規表現パターン
　　End With
　　
　　Dim mc As Object　'MatchCollection
　　Set mc = reg.Execute("100021_りんご01青森県")
　　
　　If mc.Count > 0 Then
　　　　MsgBox mc(0).SubMatches(0) '1番目()にマッチ 100021_
　　　　MsgBox mc(0).SubMatches(1) '2番目()にマッチ りんご
　　　　MsgBox mc(0).SubMatches(2) '3番目()にマッチ 01
　　　　MsgBox mc(0).SubMatches(3) '4番目()にマッチ 青森県
　　Else
　　　　MsgBox "一致しません"
　　End If
　　
End Sub

めぐみん_ · Answer

_ は常に存在するのでしょうけど、 01 は常に同じなのでしょうか？

A2セルの値が「100021_りんご01青森県」からInStrで「りんご」を抽出したい。 セルの値が

以下のようにしてください。

InStr を使った方法だと。

ちょっと遅かったですかね。

こんにちは。

_ は常に存在するのでしょうけど、 01 は常に同じなのでしょうか？

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

A2セルの値が「100021_りんご01青森県」からInStrで「りんご」を抽出したい。セルの値が