Excel VBA マクロ ある列の最終行迄を参照し、別の列の空白セルに値を入力したいです

大変お世話になっております。
セルF2から、F列に値が入っている最終行までを参照し、セルBV2以下のBV列の”空白セル”に、当日マクロを使用し集計を行った”年月日（登録日）”を入れたいのですが、F列の最終行を取得出来ず、F列に値が入っていない行、BV列のかなり下の行まで登録日が入力されてしまいます…。
それから、出来ましたらBV列の空白セルに”自動で”登録日が入るととても使いやすくなります…。
（ある方法として、別のセルに値を入れると自動で該当の空白セルに、登録年月日＋登録（例えばですが、2023/03/05 登録）が反映される等は可能でしょうか…。現在のコードはマクロの作業後、フィルターで抽出し自身で日にちを入力しなければなりません…。）

コードを訂正いただけるととても有難いです…!
ご回答を心よりお待ちしております。
どうぞ宜しくお願い申し上げます。

Sub TEST()
Dim i As Long
With ActiveSheet
i = 2
Do While .Cells(i, "F").Value <> ""
Columns("BV").SpecialCells(xlCellTypeBlanks).Select
ActiveCell.FormulaR1C1 = "2023/03/ 登録"
i = i + 1
Loop
End With
End Sub

No.2 ベストアンサー 回答者： Qchan1962 回答日時： 2023/03/05 20:21

こんばんは

＞登録年月日＋登録（例えばですが、2023/03/05 登録）が反映される等は可能でしょうか
= Format(Date, "yyyy/mm/dd ") & "登録"
こんな感じになるかと・・・

＞F列の最終行を取得出来ず、F列に値が入っていない行、BV列のかなり下の行まで登録日が入力されてしまいます…。

不思議な気がします・・・
F列の値と言うのは　数式などを使って求めているの？それともVBA？はたまた手入力？

取り敢えずテストサンプルです　テストしてみてください
範囲にSpecialCells(xlCellTypeBlanks)で書き込み
Sub TEST_01()
Dim maxRow As Long
Dim rng As Range
If Cells(Rows.Count, "BV").End(xlUp).Row = 1 Then Exit Sub
maxRow = Cells(Rows.Count, "F").End(xlUp).Row
Set rng = Range("BV2:BV" & maxRow)
rng.SpecialCells(xlCellTypeBlanks).Value = Format(Date, "yyyy/mm/dd ") & "登録"
End Sub

フィルタを使って入力
Sub TEST_02()
Dim maxRow As Long
With ActiveSheet
maxRow = .Cells(Rows.Count, "F").End(xlUp).Row
If .Cells(Rows.Count, "BV").End(xlUp).Row = 1 Then Exit Sub
If .AutoFilterMode Then .AutoFilterMode = False
With .Range("BV2:BV" & maxRow)
.AutoFilter
.AutoFilter Field:=1, Criteria1:="", Operator:=xlAnd
.SpecialCells(xlCellTypeVisible).Value = Format(Date, "yyyy/mm/dd ") & "登録"
.AutoFilter
End With
End With
End Sub

F列入力時（数式の解では発生しません・VBAで入力しているのならイベントではなくBVセルへ直接で良いですね）

Worksheet_Changeイベントを使いF2～F最終行+20行のセルを変更した時にメイン処理が実行されるます（１セル単体が条件）
Fセルの値を消した場合はメインは実行されません（コメントあり）

シートモジュールに
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
Dim inputTable_row: inputTable_row = Cells(Rows.Count, "F").End(xlUp).Row + 20
'実行範囲F2～F最終行+20行の入力（値削除）
If Intersect(Target, Range("F2").Resize(inputTable_row)) Is Nothing Then Exit Sub
If Target = "" Or Target.Offset(, 68).Value <> "" Then
'Target.Offset(, 68).Value = ""　’値を消した時の対処部分
Exit Sub
End If
Application.EnableEvents = False
On Error GoTo myErr
If Target <> "" And Target.Offset(, 68).Value = "" Then
Target.Offset(, 68).Value = Format(Date, "yyyy/mm/dd ") & "登録"
End If
myErr:
Application.EnableEvents = True
End Sub

テストコードは例です　書き方は色々ありますので　もし使う場合は
更にコードなどを参考に調べて理解してください

この回答へのお礼

Qchan1962 様!
お忙しい中、ご回答をしていただきまして本当に有難うございました!
ご提示をくださいましたコードを、今使わせていただきました…!
BV列のセルの下まで入力されてしまうことが簡単に解消されました!
日付の入力も出来ました…!!
全てのコードが素晴らしく、心より感謝申し上げます…!!

>『F列の値と言うのは　数式などを使って求めているの？それともVBA？はたまた手入力』
こちらは、別のExcelファイルのデータをオートフィルターを使い抽出し、コピーをし値貼り付けをしています。Ｆ列の空白セルには、何も入っていないはずなのですが...。
ですが、お陰様でQchan1962 様のコードを使わせていただきまして、助けられました…!!
本当に有難うございます…!

まだマクロの初心者です…。マクロの記録を使用したり、出来ない場合は調べながら作成をしています…。

また質問をさせていただくと思います…。
その際にもどうか宜しくお願い申し上げます…!

この度は本当に有難うございました!
深く感謝申し上げます…!!
大変恐縮ですが、次回以降も是非宜しくお願い申し上げます…!

お礼日時：2023/03/05 22:23

No.1 回答者： もちからぼたもち 回答日時： 2023/03/05 10:03

Cells(Rows.Count, 6).End(xlUp)

do while のかわりにこれでできそうな気がします。

この回答へのお礼

もちからぼたもち様!
この度はご回答をくださいまして本当に有難うございました。
コードの勉強になりました…!
また質問をさせていただきます…!
その折にもどうぞ宜しくお願い申し上げます!
この度は本当に有難うございました!

お礼日時：2023/03/05 22:28